port to agda/2.6.0.1 and agda-stdlib/1.1
[~helmut/bidiragda.git] / BFF.agda
1 module BFF where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Level using () renaming (zero to ℓ₀)
6 import Category.Monad
7 import Category.Functor
8 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
9 import Data.Maybe.Categorical
10 open Category.Monad.RawMonad {Level.zero} Data.Maybe.Categorical.monad using (_>>=_)
11 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.Categorical.functor using (_<$>_)
12 open import Data.List using (List ; [] ; _∷_ ; map ; length)
13 open import Data.Vec using (Vec ; toList ; fromList ; allFin) renaming (lookup to lookupV ; map to mapV ; [] to []V ; _∷_ to _∷V_)
14 open import Function using (_∘_ ; flip)
15 open import Relation.Binary using (Setoid ; DecSetoid ; module DecSetoid)
16
17 open import FinMap
18 open import Generic using (sequenceV ; ≡-to-Π)
19 open import Structures using (Shaped ; module Shaped)
20 open import Instances using (VecShaped)
21 import CheckInsert
22 open import GetTypes using (VecVec-to-PartialVecVec ; PartialVecVec-to-PartialShapeShape)
23
24 module PartialShapeBFF (A : DecSetoid ℓ₀ ℓ₀) where
25   open GetTypes.PartialShapeShape public using (Get ; module Get)
26   open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
27   open CheckInsert A
28
29   assoc : {n m : ℕ} → Vec (Fin n) m → Vec Carrier m → Maybe (FinMapMaybe n Carrier)
30   assoc []V       []V       = just empty
31   assoc (i ∷V is) (b ∷V bs) = (assoc is bs) >>= (checkInsert i b)
32
33   enumerate : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → (s : S) → C (Fin (Shaped.arity ShapeT s)) s
34   enumerate ShapeT s = fill s (allFin (arity s))
35     where open Shaped ShapeT
36
37   denumerate : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {α : Set} {s : S} → (c : C α s) → Fin (Shaped.arity ShapeT s) → α
38   denumerate ShapeT c = lookupV (Shaped.content ShapeT c)
39
40   bff : (G : Get) → {i : Get.I G} → (j : Get.I G) → Get.SourceContainer G Carrier (Get.gl₁ G i) → Get.ViewContainer G Carrier (Get.gl₂ G j) → Maybe (Get.SourceContainer G (Maybe Carrier) (Get.gl₁ G j))
41   bff G {i} j s v = let s′ = enumerate SourceShapeT (gl₁ i)
42                         t′ = get s′
43                         g  = fromFunc (denumerate SourceShapeT s)
44                         g′ = delete-many (Shaped.content ViewShapeT t′) g
45                         t  = enumerate SourceShapeT (gl₁ j)
46                         h  = assoc (Shaped.content ViewShapeT (get t)) (Shaped.content ViewShapeT v)
47                         h′ = (flip union (reshape g′ (Shaped.arity SourceShapeT (gl₁ j)))) <$> h
48                     in ((λ f → fmapS f t) ∘ flip lookupM) <$> h′
49     where open Get G
50
51   sbff : (G : Get) → {i : Get.I G} → (j : Get.I G) → Get.SourceContainer G Carrier (Get.gl₁ G i) → Get.ViewContainer G Carrier (Get.gl₂ G j) → Maybe (Get.SourceContainer G Carrier (Get.gl₁ G j))
52   sbff G j s v = bff G j s v >>= Shaped.sequence (Get.SourceShapeT G)
53
54 module PartialVecBFF (A : DecSetoid ℓ₀ ℓ₀) where
55   open GetTypes.PartialVecVec public using (Get)
56   open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
57   open CheckInsert A
58
59   open PartialShapeBFF A public using (assoc)
60
61   enumerate : {n : ℕ} → Vec Carrier n → Vec (Fin n) n
62   enumerate {n} _ = PartialShapeBFF.enumerate A VecShaped n
63
64   enumeratel : (n : ℕ) → Vec (Fin n) n
65   enumeratel = PartialShapeBFF.enumerate A VecShaped
66
67   denumerate : {n : ℕ} → Vec Carrier n → Fin n → Carrier
68   denumerate = PartialShapeBFF.denumerate A VecShaped
69
70   bff : (G : Get) → {i : Get.I G} → (j : Get.I G) → Vec Carrier (Get.gl₁ G i) → Vec Carrier (Get.gl₂ G j) → Maybe (Vec (Maybe Carrier) (Get.gl₁ G j))
71   bff G j s v = PartialShapeBFF.bff A (PartialVecVec-to-PartialShapeShape G) j s v
72
73   sbff : (G : Get) → {i : Get.I G} → (j : Get.I G) → Vec Carrier (Get.gl₁ G i) → Vec Carrier (Get.gl₂ G j) → Maybe (Vec Carrier (Get.gl₁ G j))
74   sbff  G j s v = PartialShapeBFF.sbff A (PartialVecVec-to-PartialShapeShape G) j s v
75
76 module VecBFF (A : DecSetoid ℓ₀ ℓ₀) where
77   open GetTypes.VecVec public using (Get)
78   open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
79   open CheckInsert A
80
81   open PartialVecBFF A public using (assoc ; enumerate ; denumerate)
82
83   bff : (G : Get) → {n : ℕ} → (m : ℕ) → Vec Carrier n → Vec Carrier (Get.getlen G m) → Maybe (Vec (Maybe Carrier) m)
84   bff G = PartialVecBFF.bff A (VecVec-to-PartialVecVec G)
85
86   sbff : (G : Get) → {n : ℕ} → (m : ℕ) → Vec Carrier n → Vec Carrier (Get.getlen G m) → Maybe (Vec Carrier m)
87   sbff G = PartialVecBFF.sbff A (VecVec-to-PartialVecVec G)