now parameterize BFF
[~helmut/bidiragda.git] / BFF.agda
1 module BFF where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
6 open import Data.List using (List ; [] ; _∷_ ; map ; length)
7 open import Data.Vec using (Vec ; toList ; fromList ; tabulate ; allFin) renaming (lookup to lookupV ; map to mapV ; [] to []V ; _∷_ to _∷V_)
8 open import Function using (id ; _∘_ ; flip)
9 open import Relation.Binary.Core using (Decidable ; _≡_)
10
11 open import FinMap
12 open import CheckInsert
13 import FreeTheorems
14
15 _>>=_ : {A B : Set} → Maybe A → (A → Maybe B) → Maybe B
16 _>>=_ = flip (flip maybe′ nothing)
17
18 fmap : {A B : Set} → (A → B) → Maybe A → Maybe B
19 fmap f = maybe′ (λ a → just (f a)) nothing
20
21 module ListBFF (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
22   open FreeTheorems.ListList public using (get-type)
23
24   assoc : {n : ℕ} → List (Fin n) → List Carrier → Maybe (FinMapMaybe n Carrier)
25   assoc []       []       = just empty
26   assoc (i ∷ is) (b ∷ bs) = (assoc is bs) >>= (checkInsert deq i b)
27   assoc _        _        = nothing
28
29   enumerate : (l : List Carrier) → List (Fin (length l))
30   enumerate l = toList (tabulate id)
31
32   denumerate : (l : List Carrier) → Fin (length l) → Carrier
33   denumerate l = flip lookupV (fromList l)
34
35   bff : get-type → (List Carrier → List Carrier → Maybe (List Carrier))
36   bff get s v = let s′ = enumerate s
37                     g  = fromFunc (denumerate s)
38                     h  = assoc (get s′) v
39                     h′ = fmap (flip union g) h
40                 in fmap (flip map s′ ∘ flip lookup) h′
41
42 module VecBFF (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
43   open FreeTheorems.VecVec public using (get-type)
44
45   assoc : {n m : ℕ} → Vec (Fin n) m → Vec Carrier m → Maybe (FinMapMaybe n Carrier)
46   assoc []V       []V       = just empty
47   assoc (i ∷V is) (b ∷V bs) = (assoc is bs) >>= (checkInsert deq i b)
48
49   enumerate : {n : ℕ} → Vec Carrier n → Vec (Fin n) n
50   enumerate _ = tabulate id
51
52   denumerate : {n : ℕ} → Vec Carrier n → Fin n → Carrier
53   denumerate = flip lookupV
54
55   bff : {getlen : ℕ → ℕ} → (get-type getlen) → ({n : ℕ} → Vec Carrier n → Vec Carrier (getlen n) → Maybe (Vec Carrier n))
56   bff get s v = let s′ = enumerate s
57                     g  = fromFunc (denumerate s)
58                     h  = assoc (get s′) v
59                     h′ = fmap (flip union g) h
60                 in fmap (flip mapV s′ ∘ flip lookupV) h′