ced6ebfaf632b8111bb7092004517e87b3457092
[~helmut/bidiragda.git] / BFF.agda
1 module BFF where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Level using () renaming (zero to ℓ₀)
6 import Category.Monad
7 import Category.Functor
8 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
9 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
10 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
11 open import Data.List using (List ; [] ; _∷_ ; map ; length)
12 open import Data.Vec using (Vec ; toList ; fromList ; tabulate ; allFin) renaming (lookup to lookupV ; map to mapV ; [] to []V ; _∷_ to _∷V_)
13 open import Function using (id ; _∘_ ; flip)
14 open import Relation.Binary using (Setoid ; DecSetoid ; module DecSetoid)
15
16 open import FinMap
17 open import Generic using (mapMV ; ≡-to-Π)
18 import CheckInsert
19 open import GetTypes using (VecVec-to-PartialVecVec)
20
21 module PartialVecBFF (A : DecSetoid ℓ₀ ℓ₀) where
22   open GetTypes.PartialVecVec public using (Get)
23   open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
24   open CheckInsert A
25
26   assoc : {n m : ℕ} → Vec (Fin n) m → Vec Carrier m → Maybe (FinMapMaybe n Carrier)
27   assoc []V       []V       = just empty
28   assoc (i ∷V is) (b ∷V bs) = (assoc is bs) >>= (checkInsert i b)
29
30   enumerate : {n : ℕ} → Vec Carrier n → Vec (Fin n) n
31   enumerate _ = tabulate id
32
33   denumerate : {n : ℕ} → Vec Carrier n → Fin n → Carrier
34   denumerate = flip lookupV
35
36
37   bff : (G : Get) → ({i : Get.|I| G} → Vec Carrier (Get.|gl₁| G i) → Vec Carrier (Get.|gl₂| G i) → Maybe (Vec Carrier (Get.|gl₁| G i)))
38   bff G s v = let   s′ = enumerate s
39                     t′ = Get.get G s′
40                     g  = fromFunc (denumerate s)
41                     g′ = delete-many t′ g
42                     h  = assoc t′ v
43                     h′ = (flip union g′) <$> h
44                 in h′ >>= flip mapMV s′ ∘ flip lookupV
45
46 module VecBFF (A : DecSetoid ℓ₀ ℓ₀) where
47   open GetTypes.VecVec public using (Get)
48   open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
49   open CheckInsert A
50
51   open PartialVecBFF A public using (assoc ; enumerate ; denumerate)
52
53   bff : (G : Get) → ({n : ℕ} → Vec Carrier n → Vec Carrier (Get.getlen G n) → Maybe (Vec Carrier n))
54   bff G = PartialVecBFF.bff A (VecVec-to-PartialVecVec G)