update bff implementation to use delete
[~helmut/bidiragda.git] / BFF.agda
1 module BFF where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 import Level
6 import Category.Monad
7 import Category.Functor
8 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
9 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
10 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
11 open import Data.List using (List ; [] ; _∷_ ; map ; length)
12 open import Data.Vec using (Vec ; toList ; fromList ; tabulate ; allFin) renaming (lookup to lookupV ; map to mapV ; [] to []V ; _∷_ to _∷V_)
13 open import Function using (id ; _∘_ ; flip)
14 open import Relation.Binary.Core using (Decidable ; _≡_)
15
16 open import FinMap
17 open import Generic using (mapMV)
18 import CheckInsert
19 import FreeTheorems
20
21 module VecBFF (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
22   open FreeTheorems.VecVec public using (get-type)
23   open CheckInsert Carrier deq
24
25   assoc : {n m : ℕ} → Vec (Fin n) m → Vec Carrier m → Maybe (FinMapMaybe n Carrier)
26   assoc []V       []V       = just empty
27   assoc (i ∷V is) (b ∷V bs) = (assoc is bs) >>= (checkInsert i b)
28
29   enumerate : {n : ℕ} → Vec Carrier n → Vec (Fin n) n
30   enumerate _ = tabulate id
31
32   denumerate : {n : ℕ} → Vec Carrier n → Fin n → Carrier
33   denumerate = flip lookupV
34
35   bff : {getlen : ℕ → ℕ} → (get-type getlen) → ({n : ℕ} → Vec Carrier n → Vec Carrier (getlen n) → Maybe (Vec Carrier n))
36   bff get s v = let s′ = enumerate s
37                     t′ = get s′
38                     g  = partialize (fromFunc (denumerate s))
39                     g′ = delete-many t′ g
40                     h  = assoc t′ v
41                     h′ = (flip union g′) <$> h
42                 in h′ >>= flip mapMV s′ ∘ flip lookupV