get rid of the ListBFF implementation
[~helmut/bidiragda.git] / BFF.agda
1 module BFF where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 import Level
6 import Category.Monad
7 import Category.Functor
8 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
9 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
10 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
11 open import Data.List using (List ; [] ; _∷_ ; map ; length)
12 open import Data.Vec using (Vec ; toList ; fromList ; tabulate ; allFin) renaming (lookup to lookupV ; map to mapV ; [] to []V ; _∷_ to _∷V_)
13 open import Function using (id ; _∘_ ; flip)
14 open import Relation.Binary.Core using (Decidable ; _≡_)
15
16 open import FinMap
17 import CheckInsert
18 import FreeTheorems
19
20 module VecBFF (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
21   open FreeTheorems.VecVec public using (get-type)
22   open CheckInsert Carrier deq
23
24   assoc : {n m : ℕ} → Vec (Fin n) m → Vec Carrier m → Maybe (FinMapMaybe n Carrier)
25   assoc []V       []V       = just empty
26   assoc (i ∷V is) (b ∷V bs) = (assoc is bs) >>= (checkInsert i b)
27
28   enumerate : {n : ℕ} → Vec Carrier n → Vec (Fin n) n
29   enumerate _ = tabulate id
30
31   denumerate : {n : ℕ} → Vec Carrier n → Fin n → Carrier
32   denumerate = flip lookupV
33
34   bff : {getlen : ℕ → ℕ} → (get-type getlen) → ({n : ℕ} → Vec Carrier n → Vec Carrier (getlen n) → Maybe (Vec Carrier n))
35   bff get s v = let s′ = enumerate s
36                     g  = fromFunc (denumerate s)
37                     h  = assoc (get s′) v
38                     h′ = (flip union g) <$> h
39                 in (flip mapV s′ ∘ flip lookupV) <$> h′