move all postulates to one module
[~helmut/bidiragda.git] / BFF.agda
1 module BFF where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
6 open import Data.List using (List ; [] ; _∷_ ; map ; length)
7 open import Data.Vec using (Vec ; toList ; fromList ; tabulate ; allFin) renaming (lookup to lookupV ; map to mapV ; [] to []V ; _∷_ to _∷V_)
8 open import Function using (id ; _∘_ ; flip)
9
10 open import FinMap
11 open import CheckInsert
12 import FreeTheorems
13
14 _>>=_ : {A B : Set} → Maybe A → (A → Maybe B) → Maybe B
15 _>>=_ = flip (flip maybe′ nothing)
16
17 fmap : {A B : Set} → (A → B) → Maybe A → Maybe B
18 fmap f = maybe′ (λ a → just (f a)) nothing
19
20 module ListBFF where
21   open FreeTheorems.ListList public using (get-type)
22
23   assoc : {A : Set} {n : ℕ} → EqInst A → List (Fin n) → List A → Maybe (FinMapMaybe n A)
24   assoc _  []       []       = just empty
25   assoc eq (i ∷ is) (b ∷ bs) = (assoc eq is bs) >>= (checkInsert eq i b)
26   assoc _  _        _        = nothing
27
28   enumerate : {A : Set} → (l : List A) → List (Fin (length l))
29   enumerate l = toList (tabulate id)
30
31   denumerate : {A : Set} (l : List A) → Fin (length l) → A
32   denumerate l = flip lookupV (fromList l)
33
34   bff : get-type → ({B : Set} → EqInst B → List B → List B → Maybe (List B))
35   bff get eq s v = let s′ = enumerate s
36                        g  = fromFunc (denumerate s)
37                        h  = assoc eq (get s′) v
38                        h′ = fmap (flip union g) h
39                    in fmap (flip map s′ ∘ flip lookup) h′
40
41 module VecBFF where
42   open FreeTheorems.VecVec public using (get-type)
43
44   assoc : {A : Set} {n m : ℕ} → EqInst A → Vec (Fin n) m → Vec A m → Maybe (FinMapMaybe n A)
45   assoc _  []V       []V       = just empty
46   assoc eq (i ∷V is) (b ∷V bs) = (assoc eq is bs) >>= (checkInsert eq i b)
47
48   enumerate : {A : Set} {n : ℕ} → Vec A n → Vec (Fin n) n
49   enumerate _ = tabulate id
50
51   denumerate : {A : Set} {n : ℕ} → Vec A n → Fin n → A
52   denumerate = flip lookupV
53
54   bff : {getlen : ℕ → ℕ} → (get-type getlen) → ({B : Set} {n : ℕ} → EqInst B → Vec B n → Vec B (getlen n) → Maybe (Vec B n))
55   bff get eq s v = let s′ = enumerate s
56                        g  = fromFunc (denumerate s)
57                        h  = assoc eq (get s′) v
58                        h′ = fmap (flip union g) h
59                    in fmap (flip mapV s′ ∘ flip lookupV) h′