generalize BFF and theorem-2 to arbitrary Setoids
[~helmut/bidiragda.git] / BFF.agda
1 module BFF where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Level using () renaming (zero to ℓ₀)
6 import Category.Monad
7 import Category.Functor
8 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
9 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
10 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
11 open import Data.List using (List ; [] ; _∷_ ; map ; length)
12 open import Data.Vec using (Vec ; toList ; fromList ; tabulate ; allFin) renaming (lookup to lookupV ; map to mapV ; [] to []V ; _∷_ to _∷V_)
13 open import Function using (id ; _∘_ ; flip)
14 open import Relation.Binary using (DecSetoid ; module DecSetoid)
15
16 open import FinMap
17 import CheckInsert
18 import FreeTheorems
19
20 module VecBFF (A : DecSetoid ℓ₀ ℓ₀) where
21   open FreeTheorems.VecVec public using (get-type)
22   open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
23   open CheckInsert A
24
25   assoc : {n m : ℕ} → Vec (Fin n) m → Vec Carrier m → Maybe (FinMapMaybe n Carrier)
26   assoc []V       []V       = just empty
27   assoc (i ∷V is) (b ∷V bs) = (assoc is bs) >>= (checkInsert i b)
28
29   enumerate : {n : ℕ} → Vec Carrier n → Vec (Fin n) n
30   enumerate _ = tabulate id
31
32   denumerate : {n : ℕ} → Vec Carrier n → Fin n → Carrier
33   denumerate = flip lookupV
34
35   bff : {getlen : ℕ → ℕ} → (get-type getlen) → ({n : ℕ} → Vec Carrier n → Vec Carrier (getlen n) → Maybe (Vec Carrier n))
36   bff get s v = let s′ = enumerate s
37                     g  = fromFunc (denumerate s)
38                     h  = assoc (get s′) v
39                     h′ = (flip union g) <$> h
40                 in (flip mapV s′ ∘ flip lookupV) <$> h′