Merge branch 'modparam'
[~helmut/bidiragda.git] / BFF.agda
1 module BFF where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
6 open import Data.List using (List ; [] ; _∷_ ; map ; length)
7 open import Data.Vec using (Vec ; toList ; fromList ; tabulate ; allFin) renaming (lookup to lookupV ; map to mapV ; [] to []V ; _∷_ to _∷V_)
8 open import Function using (id ; _∘_ ; flip)
9 open import Relation.Binary.Core using (Decidable ; _≡_)
10
11 open import FinMap
12 import CheckInsert
13 import FreeTheorems
14
15 _>>=_ : {A B : Set} → Maybe A → (A → Maybe B) → Maybe B
16 _>>=_ = flip (flip maybe′ nothing)
17
18 fmap : {A B : Set} → (A → B) → Maybe A → Maybe B
19 fmap f = maybe′ (λ a → just (f a)) nothing
20
21 module ListBFF (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
22   open FreeTheorems.ListList public using (get-type)
23   open CheckInsert Carrier deq
24
25   assoc : {n : ℕ} → List (Fin n) → List Carrier → Maybe (FinMapMaybe n Carrier)
26   assoc []       []       = just empty
27   assoc (i ∷ is) (b ∷ bs) = (assoc is bs) >>= (checkInsert i b)
28   assoc _        _        = nothing
29
30   enumerate : (l : List Carrier) → List (Fin (length l))
31   enumerate l = toList (tabulate id)
32
33   denumerate : (l : List Carrier) → Fin (length l) → Carrier
34   denumerate l = flip lookupV (fromList l)
35
36   bff : get-type → (List Carrier → List Carrier → Maybe (List Carrier))
37   bff get s v = let s′ = enumerate s
38                     g  = fromFunc (denumerate s)
39                     h  = assoc (get s′) v
40                     h′ = fmap (flip union g) h
41                 in fmap (flip map s′ ∘ flip lookup) h′
42
43 module VecBFF (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
44   open FreeTheorems.VecVec public using (get-type)
45   open CheckInsert Carrier deq
46
47   assoc : {n m : ℕ} → Vec (Fin n) m → Vec Carrier m → Maybe (FinMapMaybe n Carrier)
48   assoc []V       []V       = just empty
49   assoc (i ∷V is) (b ∷V bs) = (assoc is bs) >>= (checkInsert i b)
50
51   enumerate : {n : ℕ} → Vec Carrier n → Vec (Fin n) n
52   enumerate _ = tabulate id
53
54   denumerate : {n : ℕ} → Vec Carrier n → Fin n → Carrier
55   denumerate = flip lookupV
56
57   bff : {getlen : ℕ → ℕ} → (get-type getlen) → ({n : ℕ} → Vec Carrier n → Vec Carrier (getlen n) → Maybe (Vec Carrier n))
58   bff get s v = let s′ = enumerate s
59                     g  = fromFunc (denumerate s)
60                     h  = assoc (get s′) v
61                     h′ = fmap (flip union g) h
62                 in fmap (flip mapV s′ ∘ flip lookupV) h′