add bffplug and bffinv functions and examples
[~helmut/bidiragda.git] / BFFPlug.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module BFFPlug (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ ; _≟_ ; _+_ ; _∸_ ; zero ; suc ; ⌈_/2⌉)
7 open import Data.Nat.Properties using (m+n∸n≡m)
8 open import Data.Maybe using (Maybe ; just ; nothing)
9 open import Data.Vec using (Vec)
10 open import Data.Product using (∃ ; _,_)
11 open import Relation.Binary using (module DecSetoid)
12 open import Relation.Binary.PropositionalEquality using (refl ; cong ; subst ; sym ; module ≡-Reasoning) renaming (setoid to PropEq)
13 open import Relation.Nullary using (yes ; no)
14 open import Function using (flip ; id ; _∘_)
15 open import Function.Equality using (_⟶_)
16 open import Function.LeftInverse using (_RightInverseOf_)
17
18 import BFF
19 import GetTypes
20 import Examples
21
22 open DecSetoid A using (Carrier)
23 open GetTypes.VecVec public using (Get)
24 open BFF.VecBFF A public
25
26 bffplug : (G : Get) → (ℕ → ℕ → Maybe ℕ) → {n m : ℕ} → Vec Carrier n → Vec Carrier m → Maybe (∃ λ l → Vec Carrier l)
27 bffplug G sput {n} {m} s v with sput n m
28 ...                        | nothing = nothing
29 ...                        | just l with Get.getlen G l ≟ m
30 ...                                 | no getlenl≢m  = nothing
31 bffplug G sput {n}     s v | just l | yes refl with bff G l s v
32 ...                                            | nothing = nothing
33 ...                                            | just s′ = just (l , s′)
34
35 as-Π : {A B : Set} → (f : A → B) → PropEq A ⟶ PropEq B
36 as-Π f = record { _⟨$⟩_ = f; cong = cong f }
37
38 _SimpleRightInvOf_ : (ℕ → ℕ) → (ℕ → ℕ) → Set
39 f SimpleRightInvOf g = as-Π f RightInverseOf as-Π g
40
41 bffinv : (G : Get) → (nelteg : ℕ → ℕ) → nelteg SimpleRightInvOf Get.getlen G → {n m : ℕ} → Vec Carrier n → Vec Carrier m → Maybe (Vec Carrier (nelteg m))
42 bffinv G nelteg inv {n} {m} s v = bff G (nelteg m) s (subst (Vec Carrier) (sym (inv m)) v)
43
44 module InvExamples where
45   open Examples using (reverse' ; drop' ; sieve')
46   
47   reverse-put : {n m : ℕ} → Vec Carrier n → Vec Carrier m → Maybe (Vec Carrier m)
48   reverse-put = bffinv reverse' id (λ _ → refl)
49
50   drop-put : (k : ℕ) → {n m : ℕ} → Vec Carrier n → Vec Carrier m → Maybe (Vec Carrier (m + k))
51   drop-put k = bffinv (drop' k) (flip _+_ k) (flip m+n∸n≡m k)
52
53   double : ℕ → ℕ
54   double zero    = zero
55   double (suc n) = suc (suc (double n))
56
57   sieve-inv-len : double SimpleRightInvOf ⌈_/2⌉
58   sieve-inv-len zero          = refl
59   sieve-inv-len (suc zero)    = refl
60   sieve-inv-len (suc (suc x)) = cong (suc ∘ suc) (sieve-inv-len x)
61
62   sieve-put : {n m : ℕ} → Vec Carrier n → Vec Carrier m → Maybe (Vec Carrier (double m))
63   sieve-put = bffinv sieve' double sieve-inv-len