lemma-map-lookupM-assoc is even simpler
[~helmut/bidiragda.git] / Bidir.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Bidir (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
9 open import Data.List using (List)
10 open import Data.List.Any using (here ; there)
11 open import Data.List.All using (All)
12 open Data.List.Any.Membership-≡ using (_∉_)
13 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; fromList ; map ; tabulate) renaming (lookup to lookupVec)
14 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
15 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
16 open import Data.Empty using (⊥-elim)
17 open import Function using (id ; _∘_ ; flip)
18 open import Relation.Nullary using (yes ; no)
19 open import Relation.Binary.Core using (refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; _≗_ ; trans ; cong₂)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 import FreeTheorems
24 open FreeTheorems.VecVec using (get-type ; free-theorem)
25 open import FinMap
26 import CheckInsert
27 open CheckInsert Carrier deq
28 open import BFF using (_>>=_ ; fmap)
29 open BFF.VecBFF Carrier deq using (assoc ; enumerate ; denumerate ; bff)
30
31 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
32 lemma-1 f []        = refl
33 lemma-1 f (i ∷ is′) = begin
34   assoc is′ (map f is′) >>= checkInsert i (f i)
35     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
36   checkInsert i (f i) (restrict f (toList is′))
37     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
38   just (restrict f (toList (i ∷ is′))) ∎
39
40 lemma-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
41 lemma-lookupM-assoc i is x xs h    p with assoc is xs
42 lemma-lookupM-assoc i is x xs h    () | nothing
43 lemma-lookupM-assoc i is x xs h    p | just h' with checkInsert i x h' | insertionresult i x h'
44 lemma-lookupM-assoc i is x xs .h refl | just h | ._ | same pl = pl
45 lemma-lookupM-assoc i is x xs ._ refl | just h' | ._ | new _ = lemma-lookupM-insert i x h'
46 lemma-lookupM-assoc i is x xs h () | just h' | ._ | wrong _ _ _
47
48 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
49 lemma-∉-lookupM-assoc i []         []         .empty refl i∉is = lemma-lookupM-empty i
50 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
51 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
52 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = begin
53   lookupM i h
54     ≡⟨ sym (lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' h ph) ⟩
55   lookupM i h'
56     ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
57   nothing ∎
58
59 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
60 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
61
62 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
63 lemma-assoc-domain []         []         h ph = Data.List.All.[]
64 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
65 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
66 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
67 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') .h refl | just h | [ ph' ] | ._ | _ | same pl = All._∷_ (x' , pl) (lemma-assoc-domain is' xs' h ph')
68 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ._ refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
69   (x' , lemma-lookupM-insert i' x' h')
70   (Data.List.All.map
71     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' (insert i' x' h') (proj₂ p) cI≡)
72     (lemma-assoc-domain is' xs' h' ph'))
73 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
74
75 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → (h' : FinMapMaybe m Carrier) → checkInsert i x h' ≡ just h → {n : ℕ} → (js : Vec (Fin m) n) → (toList js) in-domain-of h' → map (flip lookupM h) js ≡ map (flip lookupM h') js
76 lemma-map-lookupM-assoc i x h h' ph [] pj = refl
77 lemma-map-lookupM-assoc i x h h' ph (j ∷ js) (All._∷_ (x' , pl) pj) = cong₂ _∷_
78   (trans (lemma-lookupM-checkInsert j i x' x h' h pl ph) (sym pl))
79   (lemma-map-lookupM-assoc i x h h' ph js pj)
80
81 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → map (flip lookupM h) is ≡ map just v
82 lemma-2 []       []       h p = refl
83 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
84 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
85 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
86   lookupM i h ∷ map (flip lookupM h) is
87     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc i is x xs h (begin
88       assoc (i ∷ is) (x ∷ xs)
89         ≡⟨ cong (flip _>>=_ (checkInsert i x)) ir ⟩
90       checkInsert i x h'
91         ≡⟨ p ⟩
92       just h ∎) ) ⟩
93   just x ∷ map (flip lookupM h) is
94     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h h' p is (lemma-assoc-domain is xs h' ir)) ⟩
95   just x ∷ map (flip lookupM h') is
96     ≡⟨ cong (_∷_ (just x)) (lemma-2 is xs h' ir) ⟩
97   just x ∷ map just xs ∎
98
99 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
100 lemma-map-denumerate-enumerate []       = refl
101 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
102   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
103     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
104   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
105     ≡⟨ refl ⟩
106   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
107     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
108   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
109     ≡⟨ refl ⟩
110   map (denumerate as) (enumerate as)
111     ≡⟨ lemma-map-denumerate-enumerate as ⟩
112   as ∎)
113
114 theorem-1 : {getlen : ℕ → ℕ} → (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → bff get s (get s) ≡ just s
115 theorem-1 get s = begin
116   bff get s (get s)
117     ≡⟨ cong (bff get s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
118   bff get s (get (map (denumerate s) (enumerate s)))
119     ≡⟨ cong (bff get s) (free-theorem get (denumerate s) (enumerate s)) ⟩
120   bff get s (map (denumerate s) (get (enumerate s)))
121     ≡⟨ refl ⟩
122   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
123     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
124   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
125     ≡⟨ refl ⟩
126   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (fromFunc (denumerate s)))
127     ≡⟨ cong (h′↦r ∘ just) (lemma-union-restrict (denumerate s) (toList (get (enumerate s)))) ⟩
128   (h′↦r ∘ just) (fromFunc (denumerate s))
129     ≡⟨ refl ⟩
130   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
131     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
132   just (map (denumerate s) (enumerate s))
133     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
134   just s ∎
135     where h↦h′ = fmap (flip union (fromFunc (denumerate s)))
136           h′↦r = fmap (flip map (enumerate s) ∘ flip lookupVec)
137
138 lemma-fmap-just : {A B : Set} {f : A → B} {b : B} {ma : Maybe A} → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
139 lemma-fmap-just {ma = just x}  fmap-f-ma≡just-b = x , refl
140 lemma-fmap-just {ma = nothing} ()
141
142 ∷-injective : {A : Set} {n : ℕ} {x y : A} {xs ys : Vec A n} → (x ∷ xs) ≡ (y ∷ ys) → x ≡ y × xs ≡ ys
143 ∷-injective refl = refl , refl
144
145 map-just-injective : {A : Set} {n : ℕ} {xs ys : Vec A n} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
146 map-just-injective {xs = []}      {ys = []}       p  = refl
147 map-just-injective {xs = x ∷ xs'} {ys = y ∷ ys'}  p with ∷-injective p
148 map-just-injective {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (map-just-injective p')
149
150 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
151 lemma-union-not-used h h' []        p = refl
152 lemma-union-not-used h h' (i ∷ is') (All._∷_ (x , px) p') = cong₂ _∷_ (begin
153       just (lookup i (union h h'))
154         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
155       just (maybe′ id (lookup i h') (lookupM i h))
156         ≡⟨ cong just (cong (maybe′ id (lookup i h')) px) ⟩
157       just (maybe′ id (lookup i h') (just x))
158         ≡⟨ sym px ⟩
159       lookupM i h ∎)
160   (lemma-union-not-used h h' is' p')
161
162 theorem-2 : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (v : Vec Carrier (getlen m)) → (s u : Vec Carrier m) → bff get s v ≡ just u → get u ≡ v
163 theorem-2 get v s u p with lemma-fmap-just (proj₂ (lemma-fmap-just p))
164 theorem-2 get v s u p | h , ph = begin
165   get u
166     ≡⟨ just-injective (begin
167       fmap get (just u)
168         ≡⟨ cong (fmap get) (sym p) ⟩
169       fmap get (bff get s v)
170         ≡⟨ cong (fmap get ∘ fmap h′↦r ∘ fmap h↦h′) ph ⟩
171       fmap get (fmap h′↦r (fmap h↦h′ (just h))) ∎) ⟩
172   get (map (flip lookup (h↦h′ h)) s′)
173     ≡⟨ free-theorem get (flip lookup (h↦h′ h)) s′ ⟩
174   map (flip lookup (h↦h′ h)) (get s′)
175      ≡⟨ map-just-injective (begin
176        map just (map (flip lookup (union h g)) (get s′))
177          ≡⟨ lemma-union-not-used h g (get s′) (lemma-assoc-domain (get s′) v h ph) ⟩
178        map (flip lookupM h) (get s′)
179          ≡⟨ lemma-2 (get s′) v h ph ⟩
180        map just v
181          ∎) ⟩
182   v ∎
183     where s′   = enumerate s
184           g    = fromFunc (denumerate s)
185           h↦h′ = flip union g
186           h′↦r = flip map s′ ∘ flip lookupVec