Example: show that PairVec is Shaped
[~helmut/bidiragda.git] / Bidir.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module Bidir (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin)
8 import Level
9 import Category.Monad
10 import Category.Functor
11 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′ ; drop-just) renaming (setoid to MaybeSetoid ; Eq to MaybeEq)
12 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
13 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
14 open import Data.List using (List)
15 open import Data.List.All using (All)
16 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; map ; allFin) renaming (lookup to lookupVec)
17 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
18 open import Data.Vec.Properties using (lookup∘tabulate ; map-cong ; map-∘ ; map-lookup-allFin)
19 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
20 open import Function using (id ; _∘_ ; flip)
21 open import Relation.Binary.Core using (refl ; _≡_)
22 open import Relation.Binary.Indexed using (_at_) renaming (Setoid to ISetoid)
23 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; trans ; cong₂ ; decSetoid ; module ≡-Reasoning) renaming (setoid to EqSetoid)
24 open import Relation.Binary using (Setoid ; module Setoid ; module DecSetoid)
25 import Relation.Binary.EqReasoning as EqR
26
27 open import Structures using (Functor ; IsFunctor ; Shaped ; module Shaped)
28 open import Instances using (MaybeFunctor)
29 import GetTypes
30 open GetTypes.PartialShapeVec using (Get ; module Get)
31 open import Generic using (mapMV ; mapMV-cong ; mapMV-purity ; sequenceV ; VecISetoid ; just-injective)
32 open import FinMap
33 import CheckInsert
34 open CheckInsert A
35 import BFF
36 open BFF.PartialShapeBFF A using (assoc ; enumerate ; denumerate ; bff)
37 open Setoid using () renaming (_≈_ to _∋_≈_)
38 open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
39
40 module SetoidReasoning where
41  infix 1 begin⟨_⟩_
42  infixr 2 _≈⟨_⟩_ _≡⟨_⟩_
43  infix 2 _∎
44  begin⟨_⟩_ : (X : Setoid ℓ₀ ℓ₀) → {x y : Setoid.Carrier X} → EqR._IsRelatedTo_ X x y → X ∋ x ≈ y
45  begin⟨_⟩_ X p = EqR.begin_ X p
46  _∎ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → EqR._IsRelatedTo_ X x x
47  _∎ {X} = EqR._∎ X
48  _≈⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → X ∋ x ≈ y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
49  _≈⟨_⟩_ {X} = EqR._≈⟨_⟩_ X
50
51  _≡⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → x ≡ y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
52  _≡⟨_⟩_ {X} = EqR._≡⟨_⟩_ X
53
54 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
55 lemma-1 f []        = refl
56 lemma-1 f (i ∷ is′) = begin
57   (assoc is′ (map f is′) >>= checkInsert i (f i))
58     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
59   checkInsert i (f i) (restrict f (toList is′))
60     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
61   just (restrict f (toList (i ∷ is′))) ∎
62   where open ≡-Reasoning
63
64 lemma-lookupM-checkInserted : {n : ℕ} → (i : Fin n) → (x : Carrier) → (h h' : FinMapMaybe n Carrier) → checkInsert i x h ≡ just h' → MaybeSetoid A.setoid ∋ lookupM i h' ≈ just x
65 lemma-lookupM-checkInserted i x h h' p with checkInsert i x h | insertionresult i x h
66 lemma-lookupM-checkInserted i x h .h refl | ._ | same x' x≈x' pl = begin
67   lookupM i h
68     ≡⟨ pl ⟩
69   just x'
70     ≈⟨ MaybeEq.just (Setoid.sym A.setoid x≈x') ⟩
71   just x ∎
72   where open EqR (MaybeSetoid A.setoid)
73 lemma-lookupM-checkInserted i x h ._ refl | ._ | new _ = Setoid.reflexive (MaybeSetoid A.setoid) (lemma-lookupM-insert i x h)
74 lemma-lookupM-checkInserted i x h h' () | ._ | wrong _ _ _
75
76 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
77 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
78
79 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
80 lemma-assoc-domain []         []         h ph = Data.List.All.[]
81 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
82 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
83 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
84 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') .h refl | just h | [ ph' ] | ._ | _ | same x _ pl = All._∷_ (x , pl) (lemma-assoc-domain is' xs' h ph')
85 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ._ refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
86   (x' , lemma-lookupM-insert i' x' h')
87   (Data.List.All.map
88     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' (insert i' x' h') (proj₂ p) cI≡)
89     (lemma-assoc-domain is' xs' h' ph'))
90 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
91
92 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → (h' : FinMapMaybe m Carrier) → checkInsert i x h' ≡ just h → {n : ℕ} → (js : Vec (Fin m) n) → (toList js) in-domain-of h' → map (flip lookupM h) js ≡ map (flip lookupM h') js
93 lemma-map-lookupM-assoc i x h h' ph [] pj = refl
94 lemma-map-lookupM-assoc i x h h' ph (j ∷ js) (Data.List.All._∷_ (x' , pl) pj) = cong₂ _∷_
95   (trans (lemma-lookupM-checkInsert j i x' x h' h pl ph) (sym pl))
96   (lemma-map-lookupM-assoc i x h h' ph js pj)
97
98 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → VecISetoid (MaybeSetoid A.setoid) at _ ∋ map (flip lookupM h) is ≈ map just v
99 lemma-2 []       []       h p = ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))
100 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
101 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
102 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
103   lookupM i h ∷ map (flip lookupM h) is
104     ≈⟨ VecEq._∷-cong_ (lemma-lookupM-checkInserted i x h' h p) (ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))) ⟩
105   just x ∷ map (flip lookupM h) is
106     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h h' p is (lemma-assoc-domain is xs h' ir)) ⟩
107   just x ∷ map (flip lookupM h') is
108     ≈⟨ VecEq._∷-cong_ (Setoid.refl (MaybeSetoid A.setoid)) (lemma-2 is xs h' ir) ⟩
109   just x ∷ map just xs ∎
110   where open EqR (VecISetoid (MaybeSetoid A.setoid) at _)
111
112 lemma-fmap-denumerate-enumerate : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {α : Set} {s : S} → (c : C α s) → Shaped.fmap ShapeT (denumerate ShapeT c) (enumerate ShapeT s) ≡ c
113 lemma-fmap-denumerate-enumerate {S} {C} ShapeT {s = s} c = begin
114   fmap (denumerate ShapeT c) (fill s (allFin (arity s)))
115     ≡⟨ fill-fmap (denumerate ShapeT c) s (allFin (arity s)) ⟩
116   fill s (map (flip lookupVec (content c)) (allFin (arity s)))
117     ≡⟨ cong (fill s) (map-lookup-allFin (content c)) ⟩
118   fill s (content c)
119     ≡⟨ content-fill c ⟩
120   c ∎
121   where open ≡-Reasoning
122         open Shaped ShapeT
123
124
125 theorem-1 : (G : Get) → {i : Get.|I| G} → (s : Get.Container G Carrier (Get.|gl₁| G i)) → bff G i s (Get.get G s) ≡ just (Get.fmap G just s)
126 theorem-1 G {i} s = begin
127   bff G i s (get s)
128     ≡⟨ cong (bff G i s ∘ get) (sym (lemma-fmap-denumerate-enumerate ShapeT s)) ⟩
129   bff G i s (get (fmap f t))
130     ≡⟨ cong (bff G i s) (free-theorem f t) ⟩
131   bff G i s (map f (get t))
132     ≡⟨ refl ⟩
133   h′↦r <$> (h↦h′ <$> (assoc (get t) (map f (get t))))
134     ≡⟨ cong (_<$>_ h′↦r ∘ _<$>_ h↦h′) (lemma-1 f (get t)) ⟩
135   (Maybe.just ∘ h′↦r ∘ h↦h′) (restrict f (toList (get t)))
136     ≡⟨ cong just (begin
137       h′↦r (union (restrict f (toList (get t))) (reshape g′ (arity (|gl₁| i))))
138         ≡⟨ cong (h′↦r ∘ union (restrict f (toList (get t)))) (lemma-reshape-id g′) ⟩
139       h′↦r (union (restrict f (toList (get t))) g′)
140         ≡⟨ cong h′↦r (lemma-disjoint-union f (get t)) ⟩
141       h′↦r (fromFunc f)
142         ≡⟨ refl ⟩
143       fmap (flip lookupM (fromFunc f)) t
144         ≡⟨ IsFunctor.cong (isFunctor (|gl₁| i)) (lemma-lookupM-fromFunc f) t ⟩
145       fmap (Maybe.just ∘ f) t
146         ≡⟨ IsFunctor.composition (isFunctor (|gl₁| i)) just f t ⟩
147       fmap just (fmap f t)
148         ≡⟨ cong (fmap just) (lemma-fmap-denumerate-enumerate ShapeT s) ⟩
149       fmap just s ∎) ⟩ _ ∎
150     where open ≡-Reasoning
151           open Get G
152           t    = enumerate ShapeT (|gl₁| i)
153           f    = denumerate ShapeT s
154           g′   = delete-many (get t) (fromFunc f)
155           h↦h′ = flip union (reshape g′ (arity (|gl₁| i)))
156           h′↦r = (λ f′ → fmap f′ t) ∘ flip lookupM
157
158
159 lemma-<$>-just : {A B : Set} {f : A → B} {b : B} (ma : Maybe A) → f <$> ma ≡ just b → ∃ λ a → ma ≡ just a
160 lemma-<$>-just (just x) f<$>ma≡just-b = x , refl
161 lemma-<$>-just nothing  ()
162
163 lemma-union-not-used : {m n n' : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMapMaybe n' A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map (flip lookupM (union h (reshape h' n))) is ≡ map (flip lookupM h) is
164 lemma-union-not-used         h h' []        p = refl
165 lemma-union-not-used {n = n} h h' (i ∷ is') (Data.List.All._∷_ (x , px) p') = cong₂ _∷_ (begin
166       lookupM i (union h (reshape h' n))
167         ≡⟨ lookup∘tabulate (λ j → maybe′ just (lookupM j (reshape h' n)) (lookupM j h)) i ⟩
168       maybe′ just (lookupM i (reshape h' n)) (lookupM i h)
169         ≡⟨ cong (maybe′ just (lookupM i (reshape h' n))) px ⟩
170       maybe′ just (lookupM i (reshape h' n)) (just x)
171         ≡⟨ sym px ⟩
172       lookupM i h ∎)
173   (lemma-union-not-used h h' is' p')
174   where open ≡-Reasoning
175
176 lemma->>=-just : {A B : Set} (ma : Maybe A) {f : A → Maybe B} {b : B} → (ma >>= f) ≡ just b → ∃ λ a → ma ≡ just a
177 lemma->>=-just (just a) p = a , refl
178 lemma->>=-just nothing  ()
179
180 lemma-just-sequenceV : {A : Set} {n : ℕ} → (v : Vec A n) → sequenceV (map just v) ≡ just v
181 lemma-just-sequenceV []       = refl
182 lemma-just-sequenceV (x ∷ xs) = cong (_<$>_ (_∷_ x)) (lemma-just-sequenceV xs)
183
184 lemma-just-sequence : (G : Get) → {A : Set} {i : Get.|I| G} → (c : Get.Container G A (Get.|gl₁| G i)) → Get.sequence G (Get.fmap G just c) ≡ just c
185 lemma-just-sequence G {i = i} c = begin
186   fill (|gl₁| i) <$> sequenceV (content (fmap just c))
187     ≡⟨ cong (_<$>_ (fill (|gl₁| i)) ∘ sequenceV) (fmap-content just c) ⟩
188   fill (|gl₁| i) <$> sequenceV (map just (content c))
189     ≡⟨ cong (_<$>_ (fill (|gl₁| i))) (lemma-just-sequenceV (content c)) ⟩
190   fill (|gl₁| i) <$> just (content c)
191     ≡⟨ cong just (content-fill c) ⟩
192   just c ∎
193   where open ≡-Reasoning
194         open Get G
195
196 lemma-sequenceV-successful : {A : Set} {n : ℕ} → (v : Vec (Maybe A) n) → {r : Vec A n} → sequenceV v ≡ just r → v ≡ map just r
197 lemma-sequenceV-successful []             {r = []}       p = refl
198 lemma-sequenceV-successful (just x ∷ xs)                 p with sequenceV xs | inspect sequenceV xs
199 lemma-sequenceV-successful (just x ∷ xs)                 () | nothing | _
200 lemma-sequenceV-successful (just x ∷ xs)  {r = .x ∷ .ys} refl  | just ys | [ p′ ] = cong (_∷_ (just x)) (lemma-sequenceV-successful xs p′)
201 lemma-sequenceV-successful (nothing ∷ xs)                ()
202
203 lemma-sequence-successful : (G : Get) → {A : Set} {i : Get.|I| G} → (c : Get.Container G (Maybe A) (Get.|gl₁| G i)) → {r : Get.Container G A (Get.|gl₁| G i)} → Get.sequence G c ≡ just r → c ≡ Get.fmap G just r
204 lemma-sequence-successful G {i = i} c {r} p = just-injective (sym (begin
205   fill (|gl₁| i) <$> (map just <$> (content <$> just r))
206     ≡⟨ cong (_<$>_ (fill (|gl₁| i)) ∘ _<$>_ (map just)) (begin
207       content <$> just r
208         ≡⟨ cong (_<$>_ content) (sym p) ⟩
209       content <$> (fill (|gl₁| i) <$> sequenceV (content c))
210         ≡⟨ sym (Functor.composition MaybeFunctor content (fill (|gl₁| i)) (sequenceV (content c))) ⟩
211       content ∘ fill (|gl₁| i) <$> sequenceV (content c)
212         ≡⟨ Functor.cong MaybeFunctor (fill-content (|gl₁| i)) (sequenceV (content c)) ⟩
213       id <$> sequenceV (content c)
214         ≡⟨ Functor.identity MaybeFunctor (sequenceV (content c)) ⟩
215       sequenceV (content c)
216         ≡⟨ cong sequenceV (lemma-sequenceV-successful (content c) (proj₂ wp)) ⟩
217       sequenceV (map just (proj₁ wp))
218         ≡⟨ lemma-just-sequenceV (proj₁ wp) ⟩
219       just (proj₁ (lemma-<$>-just (sequenceV (content c)) p)) ∎) ⟩
220   fill (|gl₁| i) <$> (map just <$> just (proj₁ (lemma-<$>-just (sequenceV (content c)) p)))
221     ≡⟨ cong (_<$>_ (fill (|gl₁| i)) ∘ just) (sym (lemma-sequenceV-successful (content c) (proj₂ wp))) ⟩
222   fill (|gl₁| i) <$> just (content c)
223     ≡⟨ cong just (content-fill c) ⟩
224   just c ∎))
225   where open ≡-Reasoning
226         open Get G
227         wp = lemma-<$>-just (sequenceV (content c)) p
228
229 lemma-get-sequence : {A : Set} → (G : Get) → {i : Get.|I| G} {v : Get.Container G (Maybe A) (Get.|gl₁| G i)} {r : Get.Container G A (Get.|gl₁| G i)} → Get.sequence G v ≡ just r → Get.get G <$> Get.sequence G v ≡ sequenceV (Get.get G v)
230 lemma-get-sequence G {v = v} {r = r} p = begin
231   get <$> sequence v
232     ≡⟨ cong (_<$>_ get ∘ sequence) (lemma-sequence-successful G v p) ⟩
233   get <$> sequence (fmap just r)
234     ≡⟨ cong (_<$>_ get) (lemma-just-sequence G r) ⟩
235   get <$> just r
236     ≡⟨ sym (lemma-just-sequenceV (get r)) ⟩
237   sequenceV (map just (get r))
238     ≡⟨ cong sequenceV (sym (free-theorem just r)) ⟩
239   sequenceV (get (fmap just r))
240     ≡⟨ cong (sequenceV ∘ get) (sym (lemma-sequence-successful G v p)) ⟩
241   sequenceV (get v) ∎
242   where open ≡-Reasoning
243         open Get G
244
245 sequence-cong : {S : Setoid ℓ₀ ℓ₀} {n : ℕ} {m₁ m₂ : Setoid.Carrier (VecISetoid (MaybeSetoid S) at n)} → VecISetoid (MaybeSetoid S) at _ ∋ m₁ ≈ m₂ → MaybeSetoid (VecISetoid S at n) ∋ sequenceV m₁ ≈ sequenceV m₂
246 sequence-cong {S}                                       VecEq.[]-cong = Setoid.refl (MaybeSetoid (VecISetoid S at _))
247 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) with sequenceV xs | sequenceV ys | sequence-cong xs≈ys
248 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | just sys | just p = MaybeEq.just (VecEq._∷-cong_ x≈y p)
249 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | just sys | ()
250 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | nothing | ()
251 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | nothing | nothing = Setoid.refl (MaybeSetoid (VecISetoid S at _))
252 sequence-cong {S}                                       (VecEq._∷-cong_ nothing xs≈ys) = Setoid.refl (MaybeSetoid (VecISetoid S at _))
253
254 theorem-2 : (G : Get) → {i : Get.|I| G} → (j : Get.|I| G) → (s : Get.Container G Carrier (Get.|gl₁| G i)) → (v : Vec Carrier (Get.|gl₂| G j)) → (u : Get.Container G (Maybe Carrier) (Get.|gl₁| G j)) → bff G j s v ≡ just u → VecISetoid (MaybeSetoid A.setoid) at _ ∋ Get.get G u ≈ map just v
255 theorem-2 G {i} j s v u p with (lemma-<$>-just ((flip union (reshape (delete-many (Get.get G (enumerate (Get.ShapeT G) (Get.|gl₁| G i))) (fromFunc (denumerate (Get.ShapeT G) s))) (Get.arity G (Get.|gl₁| G j)))) <$> (assoc (Get.get G (enumerate (Get.ShapeT G) (Get.|gl₁| G j))) v)) p)
256 theorem-2 G {i} j s v u p | h′ , ph′ with (lemma-<$>-just (assoc (Get.get G (enumerate (Get.ShapeT G) (Get.|gl₁| G j))) v) ph′)
257 theorem-2 G {i} j s v u p | h′ , ph′ | h , ph = begin⟨ VecISetoid (MaybeSetoid A.setoid) at _ ⟩
258   get u
259     ≡⟨ just-injective (trans (cong (_<$>_ get) (sym p))
260                              (cong (_<$>_ get ∘ _<$>_ h′↦r ∘ _<$>_ h↦h′) ph)) ⟩
261   get (h′↦r (h↦h′ h))
262     ≡⟨ refl ⟩
263   get (fmap (flip lookupM (h↦h′ h)) t)
264     ≡⟨ free-theorem (flip lookupM (h↦h′ h)) t ⟩
265   map (flip lookupM (h↦h′ h)) (get t)
266     ≡⟨ lemma-union-not-used h g′ (get t) (lemma-assoc-domain (get t) v h ph) ⟩
267   map (flip lookupM h) (get t)
268     ≈⟨ lemma-2 (get t) v h ph ⟩
269   map just v ∎
270     where open SetoidReasoning
271           open Get G
272           s′   = enumerate ShapeT (|gl₁| i)
273           g    = fromFunc (denumerate ShapeT s)
274           g′   = delete-many (get s′) g
275           t    = enumerate ShapeT (|gl₁| j)
276           h↦h′ = flip union (reshape g′ (arity (|gl₁| j)))
277           h′↦r = (λ f → fmap f t) ∘ flip lookupM
278
279 theorem-2′ : (G : Get) → {i : Get.|I| G} → (j : Get.|I| G) → (s : Get.Container G Carrier (Get.|gl₁| G i)) → (v : Vec Carrier (Get.|gl₂| G j)) → (u : Get.Container G Carrier (Get.|gl₁| G j)) → bff G j s v ≡ just (Get.fmap G just u) → VecISetoid A.setoid at _ ∋ Get.get G u ≈ v
280 theorem-2′ G j s v u p = drop-just (begin
281   get <$> just u
282     ≡⟨ cong (_<$>_ get) (sym (lemma-just-sequence G u)) ⟩
283   get <$> sequence (fmap just u)
284     ≡⟨ lemma-get-sequence G (lemma-just-sequence G u) ⟩
285   sequenceV (get (fmap just u))
286     ≈⟨ sequence-cong (theorem-2 G j s v (fmap just u) p) ⟩
287   sequenceV (map just v)
288     ≡⟨ lemma-just-sequenceV v ⟩
289   just v ∎)
290   where open EqR (MaybeSetoid (VecISetoid A.setoid at _))
291         open Get G