32d0ae73ee4cfbb555184fd55bdcfbb9c92f3aba
[~helmut/bidiragda.git] / Bidir.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module Bidir (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin)
8 import Level
9 import Category.Monad
10 import Category.Functor
11 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′ ; drop-just) renaming (setoid to MaybeSetoid ; Eq to MaybeEq)
12 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
13 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
14 open import Data.List using (List)
15 open import Data.List.All using (All)
16 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; map ; tabulate) renaming (lookup to lookupVec)
17 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
18 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
19 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
20 open import Function using (id ; _∘_ ; flip)
21 open import Relation.Binary.Core using (refl ; _≡_)
22 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; trans ; cong₂ ; decSetoid ; module ≡-Reasoning) renaming (setoid to EqSetoid)
23 open import Relation.Binary using (Setoid ; module Setoid ; module DecSetoid)
24 import Relation.Binary.EqReasoning as EqR
25
26 import FreeTheorems
27 open FreeTheorems.VecVec using (get-type ; free-theorem)
28 open import Generic using (just-injective ; vecIsSetoid ; mapMV ; mapMV-cong ; mapMV-purity ; sequenceV ; sequence-map)
29 open import FinMap
30 import CheckInsert
31 open CheckInsert A
32 import BFF
33 open BFF.VecBFF A using (assoc ; enumerate ; denumerate ; bff)
34 open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
35
36 module SetoidReasoning where
37  infix 1 begin⟨_⟩_
38  infixr 2 _≈⟨_⟩_ _≡⟨_⟩_
39  infix 2 _∎
40  begin⟨_⟩_ : (X : Setoid ℓ₀ ℓ₀) → {x y : Setoid.Carrier X} → EqR._IsRelatedTo_ X x y → Setoid._≈_ X x y
41  begin⟨_⟩_ X p = EqR.begin_ X p
42  _∎ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → EqR._IsRelatedTo_ X x x
43  _∎ {X} = EqR._∎ X
44  _≈⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → Setoid._≈_ X x y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
45  _≈⟨_⟩_ {X} = EqR._≈⟨_⟩_ X
46
47  _≡⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → x ≡ y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
48  _≡⟨_⟩_ {X} = EqR._≡⟨_⟩_ X
49
50 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
51 lemma-1 f []        = refl
52 lemma-1 f (i ∷ is′) = begin
53   (assoc is′ (map f is′) >>= checkInsert i (f i))
54     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
55   checkInsert i (f i) (restrict f (toList is′))
56     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
57   just (restrict f (toList (i ∷ is′))) ∎
58   where open ≡-Reasoning
59
60 lemma-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc (i ∷ is) (x ∷ xs) ≡ just h → Setoid._≈_ (MaybeSetoid A.setoid) (lookupM i h) (just x)
61 lemma-lookupM-assoc i is x xs h    p with assoc is xs
62 lemma-lookupM-assoc i is x xs h    () | nothing
63 lemma-lookupM-assoc i is x xs h    p | just h' with checkInsert i x h' | insertionresult i x h'
64 lemma-lookupM-assoc i is x xs .h refl | just h | ._ | same x' x≈x' pl = begin
65   lookupM i h
66     ≡⟨ pl ⟩
67   just x'
68     ≈⟨ MaybeEq.just (Setoid.sym A.setoid x≈x') ⟩
69   just x ∎
70   where open EqR (MaybeSetoid A.setoid)
71 lemma-lookupM-assoc i is x xs ._ refl | just h' | ._ | new _ =  Setoid.reflexive (MaybeSetoid A.setoid) (lemma-lookupM-insert i x h')
72 lemma-lookupM-assoc i is x xs h () | just h' | ._ | wrong _ _ _
73
74 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
75 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
76
77 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
78 lemma-assoc-domain []         []         h ph = Data.List.All.[]
79 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
80 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
81 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
82 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') .h refl | just h | [ ph' ] | ._ | _ | same x _ pl = All._∷_ (x , pl) (lemma-assoc-domain is' xs' h ph')
83 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ._ refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
84   (x' , lemma-lookupM-insert i' x' h')
85   (Data.List.All.map
86     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' (insert i' x' h') (proj₂ p) cI≡)
87     (lemma-assoc-domain is' xs' h' ph'))
88 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
89
90 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → (h' : FinMapMaybe m Carrier) → checkInsert i x h' ≡ just h → {n : ℕ} → (js : Vec (Fin m) n) → (toList js) in-domain-of h' → map (flip lookupM h) js ≡ map (flip lookupM h') js
91 lemma-map-lookupM-assoc i x h h' ph [] pj = refl
92 lemma-map-lookupM-assoc i x h h' ph (j ∷ js) (Data.List.All._∷_ (x' , pl) pj) = cong₂ _∷_
93   (trans (lemma-lookupM-checkInsert j i x' x h' h pl ph) (sym pl))
94   (lemma-map-lookupM-assoc i x h h' ph js pj)
95
96 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → Setoid._≈_ (vecIsSetoid (MaybeSetoid A.setoid) m) (map (flip lookupM h) is) (map just v)
97 lemma-2 []       []       h p = Setoid.refl (vecIsSetoid (MaybeSetoid A.setoid) _)
98 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
99 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
100 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
101   lookupM i h ∷ map (flip lookupM h) is
102     ≈⟨ lemma-lookupM-assoc i is x xs h (trans (cong (flip _>>=_ (checkInsert i x)) ir) p) VecEq.∷-cong Setoid.refl (vecIsSetoid (MaybeSetoid A.setoid) _) ⟩
103   just x ∷ map (flip lookupM h) is
104     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h h' p is (lemma-assoc-domain is xs h' ir)) ⟩
105   just x ∷ map (flip lookupM h') is
106     ≈⟨ Setoid.refl (MaybeSetoid A.setoid) VecEq.∷-cong (lemma-2 is xs h' ir) ⟩
107   just x ∷ map just xs ∎
108   where open EqR (vecIsSetoid (MaybeSetoid A.setoid) _)
109
110 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
111 lemma-map-denumerate-enumerate []       = refl
112 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
113   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
114     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
115   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
116     ≡⟨ refl ⟩
117   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
118     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
119   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
120     ≡⟨ refl ⟩
121   map (denumerate as) (enumerate as)
122     ≡⟨ lemma-map-denumerate-enumerate as ⟩
123   as ∎)
124   where open ≡-Reasoning
125
126 theorem-1 : {getlen : ℕ → ℕ} → (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → bff get s (get s) ≡ just s
127 theorem-1 get s = begin
128   bff get s (get s)
129     ≡⟨ cong (bff get s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
130   bff get s (get (map (denumerate s) (enumerate s)))
131     ≡⟨ cong (bff get s) (free-theorem get (denumerate s) (enumerate s)) ⟩
132   bff get s (map (denumerate s) (get (enumerate s)))
133     ≡⟨ refl ⟩
134   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
135     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
136   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
137     ≡⟨ refl ⟩
138   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (delete-many (get (enumerate s)) (fromFunc (denumerate s))))
139     ≡⟨ cong (h′↦r ∘ just) (lemma-disjoint-union (denumerate s) (get (enumerate s))) ⟩
140   (h′↦r ∘ just) (fromFunc (denumerate s))
141     ≡⟨ refl ⟩
142   mapMV (flip lookupVec (fromFunc (denumerate s))) (enumerate s)
143     ≡⟨ cong (flip mapMV (enumerate s) ∘ flip lookupVec) (lemma-fromFunc-tabulate (denumerate s)) ⟩
144   mapMV (flip lookupVec (tabulate (Maybe.just ∘ denumerate s))) (enumerate s)
145     ≡⟨ mapMV-cong (lookup∘tabulate (Maybe.just ∘ denumerate s)) (enumerate s) ⟩
146   mapMV (Maybe.just ∘ denumerate s) (enumerate s)
147     ≡⟨ mapMV-purity (denumerate s) (enumerate s) ⟩
148   just (map (denumerate s) (enumerate s))
149     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
150   just s ∎
151     where open ≡-Reasoning
152           h↦h′ = _<$>_ (flip union (delete-many (get (enumerate s)) (fromFunc (denumerate s))))
153           h′↦r = flip _>>=_ (flip mapMV (enumerate s) ∘ flip lookupVec)
154
155
156 lemma-<$>-just : {A B : Set} {f : A → B} {b : B} (ma : Maybe A) → f <$> ma ≡ just b → ∃ λ a → ma ≡ just a
157 lemma-<$>-just (just x) f<$>ma≡just-b = x , refl
158 lemma-<$>-just nothing  ()
159
160 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMapMaybe n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map (flip lookupM (union h h')) is ≡ map (flip lookupM h) is
161 lemma-union-not-used h h' []        p = refl
162 lemma-union-not-used h h' (i ∷ is') (Data.List.All._∷_ (x , px) p') = cong₂ _∷_ (begin
163       lookupM i (union h h')
164         ≡⟨ lookup∘tabulate (λ j → maybe′ just (lookupM j h') (lookupM j h)) i ⟩
165       maybe′ just (lookupM i h') (lookupM i h)
166         ≡⟨ cong (maybe′ just (lookupM i h')) px ⟩
167       maybe′ just (lookupM i h') (just x)
168         ≡⟨ sym px ⟩
169       lookupM i h ∎)
170   (lemma-union-not-used h h' is' p')
171   where open ≡-Reasoning
172
173 map-just-≈-injective : {n : ℕ} {x y : Vec Carrier n} → Setoid._≈_ (vecIsSetoid (MaybeSetoid A.setoid) n) (map just x) (map just y) → Setoid._≈_ (vecIsSetoid A.setoid n) x y
174 map-just-≈-injective {x = []}    {y = []}    VecEq.[]-cong              = VecEq.[]-cong
175 map-just-≈-injective {x = _ ∷ _} {y = _ ∷ _} (just x≈y VecEq.∷-cong ps) = x≈y VecEq.∷-cong map-just-≈-injective ps
176
177 lemma->>=-just : {A B : Set} (ma : Maybe A) {f : A → Maybe B} {b : B} → (ma >>= f) ≡ just b → ∃ λ a → ma ≡ just a
178 lemma->>=-just (just a) p = a , refl
179 lemma->>=-just nothing  ()
180
181 lemma-just-sequence : {A : Set} {n : ℕ} → (v : Vec A n) → sequenceV (map just v) ≡ just v
182 lemma-just-sequence [] = refl
183 lemma-just-sequence (x ∷ xs) rewrite lemma-just-sequence xs = refl
184
185 lemma-mapM-successful : {A B : Set} {f : A → Maybe B} {n : ℕ} → (v : Vec A n) → {r : Vec B n} → mapMV f v ≡ just r → ∃ λ w → map f v ≡ map just w
186 lemma-mapM-successful         []      p = [] , refl
187 lemma-mapM-successful {f = f} (x ∷ xs) p with f x | mapMV f xs | inspect (mapMV f) xs
188 lemma-mapM-successful         (x ∷ xs) () | nothing | _ | _
189 lemma-mapM-successful         (x ∷ xs) () | just y | nothing | _
190 lemma-mapM-successful         (x ∷ xs) p  | just y | just ys | [ p′ ] with lemma-mapM-successful xs p′
191 lemma-mapM-successful         (x ∷ xs) p  | just y | just ys | [ p′ ] | w , pw = y ∷ w , cong (_∷_ (just y)) pw
192
193
194 lemma-get-mapMV : {A B : Set} {f : A → Maybe B} {n : ℕ} {v : Vec A n} {r : Vec B n} → mapMV f v ≡ just r → {getlen : ℕ → ℕ} (get : get-type getlen) → get <$> mapMV f v ≡ mapMV f (get v)
195 lemma-get-mapMV {f = f} {v = v} p get = let w , pw = lemma-mapM-successful v p in begin
196   get <$> mapMV f v
197     ≡⟨ cong (_<$>_ get) (sym (sequence-map f v)) ⟩
198   get <$> (sequenceV (map f v))
199     ≡⟨ cong (_<$>_ get ∘ sequenceV) pw ⟩
200   get <$> (sequenceV (map just w))
201     ≡⟨ cong (_<$>_ get) (lemma-just-sequence w) ⟩
202   get <$> just w
203     ≡⟨ sym (lemma-just-sequence (get w)) ⟩
204   sequenceV (map just (get w))
205     ≡⟨ cong sequenceV (sym (free-theorem get just w)) ⟩
206   sequenceV (get (map just w))
207     ≡⟨ cong (sequenceV ∘ get) (sym pw) ⟩
208   sequenceV (get (map f v))
209     ≡⟨ cong sequenceV (free-theorem get f v) ⟩
210   sequenceV (map f (get v))
211     ≡⟨ sequence-map f (get v) ⟩
212   mapMV f (get v) ∎
213   where open ≡-Reasoning
214
215 sequence-cong : {S : Setoid ℓ₀ ℓ₀} {n : ℕ} {m₁ m₂ : Setoid.Carrier (vecIsSetoid (MaybeSetoid S) n)} → Setoid._≈_ (vecIsSetoid (MaybeSetoid S) n) m₁ m₂ → Setoid._≈_ (MaybeSetoid (vecIsSetoid S n)) (sequenceV m₁) (sequenceV m₂)
216 sequence-cong {S}                                       VecEq.[]-cong = Setoid.refl (MaybeSetoid (vecIsSetoid S _))
217 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (just x≈y VecEq.∷-cong xs≈ys) with sequenceV xs | sequenceV ys | sequence-cong xs≈ys
218 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (just x≈y VecEq.∷-cong xs≈ys) | just sxs | just sys | just p = MaybeEq.just (x≈y VecEq.∷-cong p)
219 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (just x≈y VecEq.∷-cong xs≈ys) | nothing | nothing | nothing = Setoid.refl (MaybeSetoid (vecIsSetoid S _))
220 sequence-cong {S}                                       (nothing VecEq.∷-cong xs≈ys) = Setoid.refl (MaybeSetoid (vecIsSetoid S _))
221
222 theorem-2 : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (v : Vec Carrier (getlen m)) → (s u : Vec Carrier m) → bff get s v ≡ just u → Setoid._≈_ (vecIsSetoid A.setoid (getlen m)) (get u) v
223 theorem-2 get v s u p with (lemma->>=-just ((flip union (delete-many (get (enumerate s)) (fromFunc (denumerate s)))) <$> (assoc (get (enumerate s)) v)) p)
224 theorem-2 get v s u p | h′ , ph′ with (lemma-<$>-just (assoc (get (enumerate s)) v) ph′)
225 theorem-2 get v s u p | h′ , ph′ | h , ph = drop-just (begin⟨ MaybeSetoid (vecIsSetoid A.setoid _) ⟩
226   get <$> (just u)
227     ≡⟨ cong (_<$>_ get) (sym p) ⟩
228   get <$> (bff get s v)
229     ≡⟨ cong (_<$>_ get ∘ flip _>>=_ h′↦r ∘ _<$>_ h↦h′) ph ⟩
230   get <$> mapMV (flip lookupM (h↦h′ h)) s′
231     ≡⟨ lemma-get-mapMV (trans (cong (flip _>>=_ h′↦r ∘ _<$>_ h↦h′) (sym ph)) p) get ⟩
232   mapMV (flip lookupM (h↦h′ h)) (get s′)
233     ≡⟨ sym (sequence-map (flip lookupM (h↦h′ h)) (get s′)) ⟩
234   sequenceV (map (flip lookupM (h↦h′ h)) (get s′))
235     ≡⟨ cong sequenceV (lemma-union-not-used h g′ (get s′) (lemma-assoc-domain (get s′) v h ph)) ⟩
236   sequenceV (map (flip lookupM h) (get s′))
237     ≈⟨ sequence-cong (lemma-2 (get s′) v h ph) ⟩
238   sequenceV (map just v)
239     ≡⟨ lemma-just-sequence v ⟩
240   just v ∎)
241     where open SetoidReasoning
242           s′   = enumerate s
243           g    = fromFunc (denumerate s)
244           g′   = delete-many (get s′) g
245           h↦h′ = flip union g′
246           h′↦r = flip mapMV s′ ∘ flip lookupM