use allFin rather than tabulate id
[~helmut/bidiragda.git] / Bidir.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module Bidir (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin)
8 import Level
9 import Category.Monad
10 import Category.Functor
11 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′ ; drop-just) renaming (setoid to MaybeSetoid ; Eq to MaybeEq)
12 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
13 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
14 open import Data.List using (List)
15 open import Data.List.All using (All)
16 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; map) renaming (lookup to lookupVec)
17 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
18 open import Data.Vec.Properties using (lookup∘tabulate ; map-cong ; map-∘ ; map-lookup-allFin)
19 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
20 open import Function using (id ; _∘_ ; flip)
21 open import Relation.Binary.Core using (refl ; _≡_)
22 open import Relation.Binary.Indexed using (_at_) renaming (Setoid to ISetoid)
23 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; trans ; cong₂ ; decSetoid ; module ≡-Reasoning) renaming (setoid to EqSetoid)
24 open import Relation.Binary using (Setoid ; module Setoid ; module DecSetoid)
25 import Relation.Binary.EqReasoning as EqR
26
27 import GetTypes
28 open GetTypes.PartialVecVec using (Get ; module Get)
29 open import Generic using (mapMV ; mapMV-cong ; mapMV-purity ; sequenceV ; VecISetoid ; just-injective)
30 open import FinMap
31 import CheckInsert
32 open CheckInsert A
33 import BFF
34 open BFF.PartialVecBFF A using (assoc ; enumerate ; enumeratel ; denumerate ; bff)
35 open Setoid using () renaming (_≈_ to _∋_≈_)
36 open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
37
38 module SetoidReasoning where
39  infix 1 begin⟨_⟩_
40  infixr 2 _≈⟨_⟩_ _≡⟨_⟩_
41  infix 2 _∎
42  begin⟨_⟩_ : (X : Setoid ℓ₀ ℓ₀) → {x y : Setoid.Carrier X} → EqR._IsRelatedTo_ X x y → X ∋ x ≈ y
43  begin⟨_⟩_ X p = EqR.begin_ X p
44  _∎ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → EqR._IsRelatedTo_ X x x
45  _∎ {X} = EqR._∎ X
46  _≈⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → X ∋ x ≈ y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
47  _≈⟨_⟩_ {X} = EqR._≈⟨_⟩_ X
48
49  _≡⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → x ≡ y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
50  _≡⟨_⟩_ {X} = EqR._≡⟨_⟩_ X
51
52 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
53 lemma-1 f []        = refl
54 lemma-1 f (i ∷ is′) = begin
55   (assoc is′ (map f is′) >>= checkInsert i (f i))
56     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
57   checkInsert i (f i) (restrict f (toList is′))
58     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
59   just (restrict f (toList (i ∷ is′))) ∎
60   where open ≡-Reasoning
61
62 lemma-lookupM-checkInserted : {n : ℕ} → (i : Fin n) → (x : Carrier) → (h h' : FinMapMaybe n Carrier) → checkInsert i x h ≡ just h' → MaybeSetoid A.setoid ∋ lookupM i h' ≈ just x
63 lemma-lookupM-checkInserted i x h h' p with checkInsert i x h | insertionresult i x h
64 lemma-lookupM-checkInserted i x h .h refl | ._ | same x' x≈x' pl = begin
65   lookupM i h
66     ≡⟨ pl ⟩
67   just x'
68     ≈⟨ MaybeEq.just (Setoid.sym A.setoid x≈x') ⟩
69   just x ∎
70   where open EqR (MaybeSetoid A.setoid)
71 lemma-lookupM-checkInserted i x h ._ refl | ._ | new _ = Setoid.reflexive (MaybeSetoid A.setoid) (lemma-lookupM-insert i x h)
72 lemma-lookupM-checkInserted i x h h' () | ._ | wrong _ _ _
73
74 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
75 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
76
77 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
78 lemma-assoc-domain []         []         h ph = Data.List.All.[]
79 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
80 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
81 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
82 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') .h refl | just h | [ ph' ] | ._ | _ | same x _ pl = All._∷_ (x , pl) (lemma-assoc-domain is' xs' h ph')
83 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ._ refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
84   (x' , lemma-lookupM-insert i' x' h')
85   (Data.List.All.map
86     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' (insert i' x' h') (proj₂ p) cI≡)
87     (lemma-assoc-domain is' xs' h' ph'))
88 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
89
90 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → (h' : FinMapMaybe m Carrier) → checkInsert i x h' ≡ just h → {n : ℕ} → (js : Vec (Fin m) n) → (toList js) in-domain-of h' → map (flip lookupM h) js ≡ map (flip lookupM h') js
91 lemma-map-lookupM-assoc i x h h' ph [] pj = refl
92 lemma-map-lookupM-assoc i x h h' ph (j ∷ js) (Data.List.All._∷_ (x' , pl) pj) = cong₂ _∷_
93   (trans (lemma-lookupM-checkInsert j i x' x h' h pl ph) (sym pl))
94   (lemma-map-lookupM-assoc i x h h' ph js pj)
95
96 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → VecISetoid (MaybeSetoid A.setoid) at _ ∋ map (flip lookupM h) is ≈ map just v
97 lemma-2 []       []       h p = ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))
98 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
99 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
100 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
101   lookupM i h ∷ map (flip lookupM h) is
102     ≈⟨ VecEq._∷-cong_ (lemma-lookupM-checkInserted i x h' h p) (ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))) ⟩
103   just x ∷ map (flip lookupM h) is
104     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h h' p is (lemma-assoc-domain is xs h' ir)) ⟩
105   just x ∷ map (flip lookupM h') is
106     ≈⟨ VecEq._∷-cong_ (Setoid.refl (MaybeSetoid A.setoid)) (lemma-2 is xs h' ir) ⟩
107   just x ∷ map just xs ∎
108   where open EqR (VecISetoid (MaybeSetoid A.setoid) at _)
109
110 theorem-1 : (G : Get) → {i : Get.|I| G} → (s : Vec Carrier (Get.|gl₁| G i)) → bff G i s (Get.get G s) ≡ just (map just s)
111 theorem-1 G {i} s = begin
112   bff G i s (get s)
113     ≡⟨ cong (bff G i s ∘ get) (sym (map-lookup-allFin s)) ⟩
114   bff G i s (get (map (denumerate s) (enumerate s)))
115     ≡⟨ cong (bff G i s) (free-theorem (denumerate s) (enumerate s)) ⟩
116   bff G i s (map (denumerate s) (get (enumerate s)))
117     ≡⟨ refl ⟩
118   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
119     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
120   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
121     ≡⟨ refl ⟩
122   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (reshape (delete-many (get (enumerate s)) (fromFunc (denumerate s))) (Get.|gl₁| G i)))
123     ≡⟨ cong (h′↦r ∘ Maybe.just ∘ union (restrict (denumerate s) (toList (get (enumerate s))))) (lemma-reshape-id (delete-many (get (enumerate s)) (fromFunc (denumerate s)))) ⟩
124   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (delete-many (get (enumerate s)) (fromFunc (denumerate s))))
125     ≡⟨ cong (h′↦r ∘ just) (lemma-disjoint-union (denumerate s) (get (enumerate s))) ⟩
126   (h′↦r ∘ just) (fromFunc (denumerate s))
127     ≡⟨ refl ⟩
128   just (map (flip lookupM (fromFunc (denumerate s))) (enumerate s))
129     ≡⟨ cong just (map-cong (lemma-lookupM-fromFunc (denumerate s)) (enumerate s)) ⟩
130   just (map (Maybe.just ∘ denumerate s) (enumerate s))
131     ≡⟨ cong just (map-∘ just (denumerate s) (enumerate s)) ⟩
132   just (map just (map (denumerate s) (enumerate s)))
133     ≡⟨ cong (Maybe.just ∘ map just) (map-lookup-allFin s) ⟩
134   just (map just s) ∎
135     where open ≡-Reasoning
136           open Get G
137           h↦h′ = _<$>_ (flip union (reshape (delete-many (get (enumerate s)) (fromFunc (denumerate s))) (Get.|gl₁| G i)))
138           h′↦r = _<$>_ (flip map (enumerate s) ∘ flip lookupM)
139
140
141 lemma-<$>-just : {A B : Set} {f : A → B} {b : B} (ma : Maybe A) → f <$> ma ≡ just b → ∃ λ a → ma ≡ just a
142 lemma-<$>-just (just x) f<$>ma≡just-b = x , refl
143 lemma-<$>-just nothing  ()
144
145 lemma-union-not-used : {m n n' : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMapMaybe n' A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map (flip lookupM (union h (reshape h' n))) is ≡ map (flip lookupM h) is
146 lemma-union-not-used         h h' []        p = refl
147 lemma-union-not-used {n = n} h h' (i ∷ is') (Data.List.All._∷_ (x , px) p') = cong₂ _∷_ (begin
148       lookupM i (union h (reshape h' n))
149         ≡⟨ lookup∘tabulate (λ j → maybe′ just (lookupM j (reshape h' n)) (lookupM j h)) i ⟩
150       maybe′ just (lookupM i (reshape h' n)) (lookupM i h)
151         ≡⟨ cong (maybe′ just (lookupM i (reshape h' n))) px ⟩
152       maybe′ just (lookupM i (reshape h' n)) (just x)
153         ≡⟨ sym px ⟩
154       lookupM i h ∎)
155   (lemma-union-not-used h h' is' p')
156   where open ≡-Reasoning
157
158 lemma->>=-just : {A B : Set} (ma : Maybe A) {f : A → Maybe B} {b : B} → (ma >>= f) ≡ just b → ∃ λ a → ma ≡ just a
159 lemma->>=-just (just a) p = a , refl
160 lemma->>=-just nothing  ()
161
162 lemma-just-sequence : {A : Set} {n : ℕ} → (v : Vec A n) → sequenceV (map just v) ≡ just v
163 lemma-just-sequence []       = refl
164 lemma-just-sequence (x ∷ xs) = cong (_<$>_ (_∷_ x)) (lemma-just-sequence xs)
165
166 lemma-sequenceV-successful : {A : Set} {n : ℕ} → (v : Vec (Maybe A) n) → {r : Vec A n} → sequenceV v ≡ just r → v ≡ map just r
167 lemma-sequenceV-successful []             {r = []}       p = refl
168 lemma-sequenceV-successful (just x ∷ xs)                 p with sequenceV xs | inspect sequenceV xs
169 lemma-sequenceV-successful (just x ∷ xs)                 () | nothing | _
170 lemma-sequenceV-successful (just x ∷ xs)  {r = .x ∷ .ys} refl  | just ys | [ p′ ] = cong (_∷_ (just x)) (lemma-sequenceV-successful xs p′)
171 lemma-sequenceV-successful (nothing ∷ xs)                ()
172
173 lemma-get-sequenceV : {A : Set} → (G : Get) → {i : Get.|I| G} {v : Vec (Maybe A) (Get.|gl₁| G i)} {r : Vec A (Get.|gl₁| G i)} → sequenceV v ≡ just r → Get.get G <$> sequenceV v ≡ sequenceV (Get.get G v)
174 lemma-get-sequenceV G {v = v} {r = r} p = begin
175   get <$> sequenceV v
176     ≡⟨ cong (_<$>_ get ∘ sequenceV) (lemma-sequenceV-successful v p) ⟩
177   get <$> sequenceV (map just r)
178     ≡⟨ cong (_<$>_ get) (lemma-just-sequence r) ⟩
179   get <$> just r
180     ≡⟨ sym (lemma-just-sequence (get r)) ⟩
181   sequenceV (map just (get r))
182     ≡⟨ cong sequenceV (sym (free-theorem just r)) ⟩
183   sequenceV (get (map just r))
184     ≡⟨ cong (sequenceV ∘ get) (sym (lemma-sequenceV-successful v p)) ⟩
185   sequenceV (get v) ∎
186   where open ≡-Reasoning
187         open Get G
188
189 sequence-cong : {S : Setoid ℓ₀ ℓ₀} {n : ℕ} {m₁ m₂ : Setoid.Carrier (VecISetoid (MaybeSetoid S) at n)} → VecISetoid (MaybeSetoid S) at _ ∋ m₁ ≈ m₂ → MaybeSetoid (VecISetoid S at n) ∋ sequenceV m₁ ≈ sequenceV m₂
190 sequence-cong {S}                                       VecEq.[]-cong = Setoid.refl (MaybeSetoid (VecISetoid S at _))
191 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) with sequenceV xs | sequenceV ys | sequence-cong xs≈ys
192 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | just sys | just p = MaybeEq.just (VecEq._∷-cong_ x≈y p)
193 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | just sys | ()
194 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | nothing | ()
195 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | nothing | nothing = Setoid.refl (MaybeSetoid (VecISetoid S at _))
196 sequence-cong {S}                                       (VecEq._∷-cong_ nothing xs≈ys) = Setoid.refl (MaybeSetoid (VecISetoid S at _))
197
198 theorem-2 : (G : Get) → {i : Get.|I| G} → (j : Get.|I| G) → (s : Vec Carrier (Get.|gl₁| G i)) → (v : Vec Carrier (Get.|gl₂| G j)) → (u : Vec (Maybe Carrier) (Get.|gl₁| G j)) → bff G j s v ≡ just u → VecISetoid (MaybeSetoid A.setoid) at _ ∋ Get.get G u ≈ map just v
199 theorem-2 G j s v u p with (lemma-<$>-just ((flip union (reshape (delete-many (Get.get G (enumerate s)) (fromFunc (denumerate s))) (Get.|gl₁| G j))) <$> (assoc (Get.get G (enumeratel (Get.|gl₁| G j))) v)) p)
200 theorem-2 G j s v u p | h′ , ph′ with (lemma-<$>-just (assoc (Get.get G (enumeratel (Get.|gl₁| G j))) v) ph′)
201 theorem-2 G j s v u p | h′ , ph′ | h , ph = begin⟨ VecISetoid (MaybeSetoid A.setoid) at _ ⟩
202   get u
203     ≡⟨ just-injective (trans (cong (_<$>_ get) (sym p))
204                              (cong (_<$>_ get ∘ _<$>_ h′↦r ∘ _<$>_ h↦h′) ph)) ⟩
205   get (h′↦r (h↦h′ h))
206     ≡⟨ refl ⟩
207   get (map (flip lookupM (h↦h′ h)) t)
208     ≡⟨ free-theorem (flip lookupM (h↦h′ h)) t ⟩
209   map (flip lookupM (h↦h′ h)) (get t)
210     ≡⟨ lemma-union-not-used h g′ (get t) (lemma-assoc-domain (get t) v h ph) ⟩
211   map (flip lookupM h) (get t)
212     ≈⟨ lemma-2 (get t) v h ph ⟩
213   map just v ∎
214     where open SetoidReasoning
215           open Get G
216           s′   = enumerate s
217           g    = fromFunc (denumerate s)
218           g′   = delete-many (get s′) g
219           t    = enumeratel (Get.|gl₁| G j)
220           h↦h′ = flip union (reshape g′ (Get.|gl₁| G j))
221           h′↦r = flip map t ∘ flip lookupM
222
223 theorem-2′ : (G : Get) → {i : Get.|I| G} → (j : Get.|I| G) → (s : Vec Carrier (Get.|gl₁| G i)) → (v : Vec Carrier (Get.|gl₂| G j)) → (u : Vec Carrier (Get.|gl₁| G j)) → bff G j s v ≡ just (map just u) → VecISetoid A.setoid at _ ∋ Get.get G u ≈ v
224 theorem-2′ G j s v u p = drop-just (begin
225   get <$> just u
226     ≡⟨ cong (_<$>_ get) (sym (lemma-just-sequence u)) ⟩
227   get <$> sequenceV (map just u)
228     ≡⟨ lemma-get-sequenceV G (lemma-just-sequence u) ⟩
229   sequenceV (get (map just u))
230     ≈⟨ sequence-cong (theorem-2 G j s v (map just u) p) ⟩
231   sequenceV (map just v)
232     ≡⟨ lemma-just-sequence v ⟩
233   just v ∎)
234   where open EqR (MaybeSetoid (VecISetoid A.setoid at _))
235         open Get G