move imports for agda-stdlib 1.3
[~helmut/bidiragda.git] / Bidir.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module Bidir (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin)
8 import Level
9 import Category.Monad
10 import Category.Functor
11 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
12 import Data.Maybe.Categorical
13 open import Data.Maybe.Properties using (just-injective)
14 open import Data.Maybe.Relation.Binary.Pointwise using (just ; nothing ; drop-just) renaming (setoid to MaybeSetoid ; Pointwise to MaybeEq)
15 open Category.Monad.RawMonad {Level.zero} Data.Maybe.Categorical.monad using (_>>=_)
16 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.Categorical.functor using (_<$>_)
17 open import Data.List using (List)
18 open import Data.List.Relation.Unary.All using (All)
19 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; map ; allFin) renaming (lookup to lookupVec)
20 open import Data.Vec.Relation.Binary.Pointwise.Inductive using (Pointwise)
21 open import Data.Vec.Properties using (lookup∘tabulate ; lookup∘update ; map-cong ; map-∘ ; map-lookup-allFin)
22 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
23 open import Function using (id ; _∘_ ; flip)
24 open import Relation.Binary.Indexed.Heterogeneous using () renaming (IndexedSetoid to ISetoid)
25 open import Relation.Binary.Indexed.Heterogeneous.Construct.At using (_atₛ_)
26 open import Relation.Binary.PropositionalEquality as P using (_≡_ ; inspect ; [_] ; module ≡-Reasoning)
27 open import Relation.Binary using (Setoid ; module Setoid ; module DecSetoid)
28 import Relation.Binary.Reasoning.Setoid as EqR
29
30 open import Structures using (Functor ; IsFunctor ; Shaped ; module Shaped)
31 open import Instances using (MaybeFunctor ; ShapedISetoid)
32 import GetTypes
33 open GetTypes.PartialShapeShape using (Get ; module Get)
34 open import Generic using (mapMV ; mapMV-cong ; mapMV-purity ; sequenceV ; VecISetoid)
35 open import FinMap
36 import CheckInsert
37 open CheckInsert A
38 import BFF
39 open BFF.PartialShapeBFF A using (assoc ; enumerate ; denumerate ; bff)
40 open Setoid using () renaming (_≈_ to _∋_≈_)
41 open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
42
43 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f is)
44 lemma-1 f []        = P.refl
45 lemma-1 f (i ∷ is′) = begin
46   (assoc is′ (map f is′) >>= checkInsert i (f i))
47     ≡⟨ P.cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
48   checkInsert i (f i) (restrict f is′)
49     ≡⟨ lemma-checkInsert-restrict f i is′ ⟩
50   just (restrict f (i ∷ is′)) ∎
51   where open ≡-Reasoning
52
53 lemma-lookupM-checkInserted : {n : ℕ} → (i : Fin n) → (x : Carrier) → (h : FinMapMaybe n Carrier) → {h' : FinMapMaybe n Carrier} → checkInsert i x h ≡ just h' → MaybeSetoid A.setoid ∋ lookupM i h' ≈ just x
54 lemma-lookupM-checkInserted i x h p with checkInsert i x h | insertionresult i x h
55 lemma-lookupM-checkInserted i x h P.refl | ._              | same x' x≈x' pl = begin
56   lookupM i h
57     ≡⟨ pl ⟩
58   just x'
59     ≈⟨ MaybeEq.just (Setoid.sym A.setoid x≈x') ⟩
60   just x ∎
61   where open EqR (MaybeSetoid A.setoid)
62 lemma-lookupM-checkInserted i x h P.refl | ._ | new _ = Setoid.reflexive (MaybeSetoid A.setoid) (lookup∘update i h (just x))
63 lemma-lookupM-checkInserted i x h ()     | ._ | wrong _ _ _
64
65 _in-domain-of_ : {m n : ℕ} {A : Set} → (is : Vec (Fin m) n) → (FinMapMaybe m A) → Set
66 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) (toList is)
67
68 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → {h : FinMapMaybe n Carrier} → assoc is xs ≡ just h → is in-domain-of h
69 lemma-assoc-domain []         []         ph = Data.List.Relation.Unary.All.[]
70 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ph with assoc is' xs' | inspect (assoc is') xs'
71 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') () | nothing | [ ph' ]
72 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
73 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') P.refl | just h | [ ph' ] | ._ | _ | same x _ pl = All._∷_ (x , pl) (lemma-assoc-domain is' xs' ph')
74 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') P.refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
75   (x' , lookup∘update i' h' (just x'))
76   (Data.List.Relation.Unary.All.map
77     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' h' (proj₂ p) x' cI≡)
78     (lemma-assoc-domain is' xs' ph'))
79 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
80
81 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → {h' : FinMapMaybe m Carrier} → checkInsert i x h ≡ just h' → {n : ℕ} → (js : Vec (Fin m) n) → js in-domain-of h → map (flip lookupM h') js ≡ map (flip lookupM h) js
82 lemma-map-lookupM-assoc i x h ph [] pj = P.refl
83 lemma-map-lookupM-assoc i x h ph (j ∷ js) (Data.List.Relation.Unary.All._∷_ (x' , pl) pj) = P.cong₂ _∷_
84   (P.trans (lemma-lookupM-checkInsert j i h pl x ph) (P.sym pl))
85   (lemma-map-lookupM-assoc i x h ph js pj)
86
87 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → VecISetoid (MaybeSetoid A.setoid) atₛ _ ∋ map (flip lookupM h) is ≈ map just v
88 lemma-2 []       []       h p = ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))
89 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
90 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
91 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
92   lookupM i h ∷ map (flip lookupM h) is
93     ≈⟨ Pointwise._∷_ (lemma-lookupM-checkInserted i x h' p) (ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))) ⟩
94   just x ∷ map (flip lookupM h) is
95     ≡⟨  P.cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h' p is (lemma-assoc-domain is xs ir)) ⟩
96   just x ∷ map (flip lookupM h') is
97     ≈⟨ Pointwise._∷_ (Setoid.refl (MaybeSetoid A.setoid)) (lemma-2 is xs h' ir) ⟩
98   just x ∷ map just xs ∎
99   where open EqR (VecISetoid (MaybeSetoid A.setoid) atₛ _)
100
101 lemma-fmap-denumerate-enumerate : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {α : Set} {s : S} → (c : C α s) → Shaped.fmap ShapeT (denumerate ShapeT c) (enumerate ShapeT s) ≡ c
102 lemma-fmap-denumerate-enumerate {S} {C} ShapeT {s = s} c = begin
103   fmap (denumerate ShapeT c) (fill s (allFin (arity s)))
104     ≡⟨ fill-fmap (denumerate ShapeT c) s (allFin (arity s)) ⟩
105   fill s (map (lookupVec (content c)) (allFin (arity s)))
106     ≡⟨ P.cong (fill s) (map-lookup-allFin (content c)) ⟩
107   fill s (content c)
108     ≡⟨ content-fill c ⟩
109   c ∎
110   where open ≡-Reasoning
111         open Shaped ShapeT
112
113
114 theorem-1 : (G : Get) → {i : Get.I G} → (s : Get.SourceContainer G Carrier (Get.gl₁ G i)) → bff G i s (Get.get G s) ≡ just (Get.fmapS G just s)
115 theorem-1 G {i} s = begin
116   bff G i s (get s)
117     ≡⟨ P.cong (bff G i s ∘ get) (P.sym (lemma-fmap-denumerate-enumerate SourceShapeT s)) ⟩
118   bff G i s (get (fmapS f t))
119     ≡⟨ P.cong (bff G i s) (free-theorem f t) ⟩
120   bff G i s (fmapV f (get t))
121     ≡⟨ P.refl ⟩
122   h′↦r <$> (h↦h′ <$> (assoc (Shaped.content ViewShapeT (get t)) (Shaped.content ViewShapeT (fmapV f (get t)))))
123     ≡⟨ P.cong (_<$>_ h′↦r ∘ _<$>_ h↦h′ ∘ assoc (Shaped.content ViewShapeT (get t))) (Shaped.fmap-content ViewShapeT f (get t)) ⟩
124   h′↦r <$> (h↦h′ <$> (assoc (Shaped.content ViewShapeT (get t)) (map f (Shaped.content ViewShapeT (get t)))))
125     ≡⟨ P.cong (_<$>_ h′↦r ∘ _<$>_ h↦h′) (lemma-1 f (Shaped.content ViewShapeT (get t))) ⟩
126   (Maybe.just ∘ h′↦r ∘ h↦h′) (restrict f (Shaped.content ViewShapeT (get t)))
127     ≡⟨ P.cong just (begin
128       h′↦r (union (restrict f (Shaped.content ViewShapeT (get t))) (reshape g′ (Shaped.arity SourceShapeT (gl₁ i))))
129         ≡⟨ P.cong (h′↦r ∘ union (restrict f (Shaped.content ViewShapeT (get t)))) (lemma-reshape-id g′) ⟩
130       h′↦r (union (restrict f (Shaped.content ViewShapeT (get t))) g′)
131         ≡⟨ P.cong h′↦r (lemma-disjoint-union f (Shaped.content ViewShapeT (get t))) ⟩
132       h′↦r (fromFunc f)
133         ≡⟨ P.refl ⟩
134       fmapS (flip lookupM (fromFunc f)) t
135         ≡⟨ IsFunctor.cong (Shaped.isFunctor SourceShapeT (gl₁ i)) (lookup∘tabulate (just ∘ f)) t ⟩
136       fmapS (Maybe.just ∘ f) t
137         ≡⟨ IsFunctor.composition (Shaped.isFunctor SourceShapeT (gl₁ i)) just f t ⟩
138       fmapS just (fmapS f t)
139         ≡⟨ P.cong (fmapS just) (lemma-fmap-denumerate-enumerate SourceShapeT s) ⟩
140       fmapS just s ∎) ⟩ _ ∎
141     where open ≡-Reasoning
142           open Get G
143           t    = enumerate SourceShapeT (gl₁ i)
144           f    = denumerate SourceShapeT s
145           g′   = delete-many (Shaped.content ViewShapeT (get t)) (fromFunc f)
146           h↦h′ = flip union (reshape g′ (Shaped.arity SourceShapeT (gl₁ i)))
147           h′↦r = (λ f′ → fmapS f′ t) ∘ flip lookupM
148
149
150 lemma-<$>-just : {A B : Set} {f : A → B} {b : B} (ma : Maybe A) → (f <$> ma) ≡ just b → ∃ λ a → ma ≡ just a
151 lemma-<$>-just (just x) f<$>ma≡just-b = x , P.refl
152 lemma-<$>-just nothing  ()
153
154 lemma-union-not-used : {n : ℕ} → {A : Set} → (h h′ : FinMapMaybe n A) → (i : Fin n) → ∃ (λ x → lookupM i h ≡ just x) → lookupM i (union h h′) ≡ lookupM i h
155 lemma-union-not-used h h′ i (x , px) = begin
156   lookupM i (union h h′)
157     ≡⟨ lookup∘tabulate (λ j → maybe′ just (lookupM j h′) (lookupM j h)) i ⟩
158   maybe′ just (lookupM i h′) (lookupM i h)
159     ≡⟨ P.cong (maybe′ just (lookupM i h′)) px ⟩
160   maybe′ just (lookupM i h′) (just x)
161     ≡⟨ P.sym px ⟩
162   lookupM i h ∎
163   where open ≡-Reasoning
164
165 lemma->>=-just : {A B : Set} (ma : Maybe A) {f : A → Maybe B} {b : B} → (ma >>= f) ≡ just b → ∃ λ a → ma ≡ just a
166 lemma->>=-just (just a) p = a , P.refl
167 lemma->>=-just nothing  ()
168
169 lemma-just-sequenceV : {A : Set} {n : ℕ} → (v : Vec A n) → sequenceV (map just v) ≡ just v
170 lemma-just-sequenceV []       = P.refl
171 lemma-just-sequenceV (x ∷ xs) = P.cong (_<$>_ (_∷_ x)) (lemma-just-sequenceV xs)
172
173 lemma-just-sequence : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {A : Set} {s : S} → (c : C A s) → Shaped.sequence ShapeT (Shaped.fmap ShapeT just c) ≡ just c
174 lemma-just-sequence ShapeT {s = s} c = begin
175   fill s <$> sequenceV (content (fmap just c))
176     ≡⟨ P.cong (_<$>_ (fill s) ∘ sequenceV) (fmap-content just c) ⟩
177   fill s <$> sequenceV (map just (content c))
178     ≡⟨ P.cong (_<$>_ (fill s)) (lemma-just-sequenceV (content c)) ⟩
179   fill s <$> just (content c)
180     ≡⟨ P.cong just (content-fill c) ⟩
181   just c ∎
182   where open ≡-Reasoning
183         open Shaped ShapeT
184
185 lemma-sequenceV-successful : {A : Set} {n : ℕ} → (v : Vec (Maybe A) n) → {r : Vec A n} → sequenceV v ≡ just r → v ≡ map just r
186 lemma-sequenceV-successful []             {r = []}       p = P.refl
187 lemma-sequenceV-successful (just x ∷ xs)                 p with sequenceV xs | inspect sequenceV xs
188 lemma-sequenceV-successful (just x ∷ xs)                 () | nothing | _
189 lemma-sequenceV-successful (just x ∷ xs)  {r = .x ∷ .ys} P.refl  | just ys | [ p′ ] = P.cong (_∷_ (just x)) (lemma-sequenceV-successful xs p′)
190 lemma-sequenceV-successful (nothing ∷ xs)                ()
191
192 lemma-sequence-successful : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {A : Set} {s : S} → (c : C (Maybe A) s) → {r : C A s} → Shaped.sequence ShapeT c ≡ just r → c ≡ Shaped.fmap ShapeT just r
193 lemma-sequence-successful ShapeT {s = s} c {r} p = just-injective (P.sym (begin
194   fill s <$> (map just <$> (content <$> just r))
195     ≡⟨ P.cong (_<$>_ (fill s) ∘ _<$>_ (map just)) (begin
196       content <$> just r
197         ≡⟨ P.cong (_<$>_ content) (P.sym p) ⟩
198       content <$> (fill s <$> sequenceV (content c))
199         ≡⟨ P.sym (Functor.composition MaybeFunctor content (fill s) (sequenceV (content c))) ⟩
200       content ∘ fill s <$> sequenceV (content c)
201         ≡⟨ Functor.cong MaybeFunctor (fill-content s) (sequenceV (content c)) ⟩
202       id <$> sequenceV (content c)
203         ≡⟨ Functor.identity MaybeFunctor (sequenceV (content c)) ⟩
204       sequenceV (content c)
205         ≡⟨ P.cong sequenceV (lemma-sequenceV-successful (content c) (proj₂ wp)) ⟩
206       sequenceV (map just (proj₁ wp))
207         ≡⟨ lemma-just-sequenceV (proj₁ wp) ⟩
208       just (proj₁ (lemma-<$>-just (sequenceV (content c)) p)) ∎) ⟩
209   fill s <$> (map just <$> just (proj₁ (lemma-<$>-just (sequenceV (content c)) p)))
210     ≡⟨ P.cong (_<$>_ (fill s) ∘ just) (P.sym (lemma-sequenceV-successful (content c) (proj₂ wp))) ⟩
211   fill s <$> just (content c)
212     ≡⟨ P.cong just (content-fill c) ⟩
213   just c ∎))
214   where open ≡-Reasoning
215         open Shaped ShapeT
216         wp = lemma-<$>-just (sequenceV (content c)) p
217
218 module _ (G : Get) where
219   open ≡-Reasoning
220   open Get G
221   open Shaped SourceShapeT using () renaming (sequence to sequenceSource)
222   open Shaped ViewShapeT using () renaming (sequence to sequenceView)
223
224   lemma-get-sequence : {A : Set} → {i : I} {v : SourceContainer (Maybe A) (gl₁ i)} {r : SourceContainer A (gl₁ i)} → sequenceSource v ≡ just r → (get <$> sequenceSource v) ≡ sequenceView (get v)
225   lemma-get-sequence {v = v} {r = r} p = begin
226     get <$> sequenceSource v
227       ≡⟨ P.cong (_<$>_ get ∘ sequenceSource) (lemma-sequence-successful SourceShapeT v p) ⟩
228     get <$> sequenceSource (fmapS just r)
229       ≡⟨ P.cong (_<$>_ get) (lemma-just-sequence SourceShapeT r) ⟩
230     get <$> just r
231       ≡⟨ P.sym (lemma-just-sequence ViewShapeT (get r)) ⟩
232     sequenceView (fmapV just (get r))
233       ≡⟨ P.cong sequenceView (P.sym (free-theorem just r)) ⟩
234     sequenceView (get (fmapS just r))
235       ≡⟨ P.cong (sequenceView ∘ get) (P.sym (lemma-sequence-successful SourceShapeT v p)) ⟩
236     sequenceView (get v) ∎
237
238 sequenceV-cong : (S : Setoid ℓ₀ ℓ₀) {n : ℕ} {m₁ m₂ : Setoid.Carrier (VecISetoid (MaybeSetoid S) atₛ n)} → VecISetoid (MaybeSetoid S) atₛ _ ∋ m₁ ≈ m₂ → MaybeSetoid (VecISetoid S atₛ n) ∋ sequenceV m₁ ≈ sequenceV m₂
239 sequenceV-cong S                                       Pointwise.[] = Setoid.refl (MaybeSetoid (VecISetoid S atₛ _))
240 sequenceV-cong S {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (Pointwise._∷_ (just x≈y) xs≈ys) with sequenceV xs | sequenceV ys | sequenceV-cong S xs≈ys
241 sequenceV-cong S {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (Pointwise._∷_ (just x≈y) xs≈ys) | just sxs | just sys | just p = MaybeEq.just (Pointwise._∷_ x≈y p)
242 sequenceV-cong S {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (Pointwise._∷_ (just x≈y) xs≈ys) | nothing | just sys | ()
243 sequenceV-cong S {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (Pointwise._∷_ (just x≈y) xs≈ys) | just sxs | nothing | ()
244 sequenceV-cong S {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (Pointwise._∷_ (just x≈y) xs≈ys) | nothing | nothing | nothing = Setoid.refl (MaybeSetoid (VecISetoid S atₛ _))
245 sequenceV-cong S                                       (Pointwise._∷_ nothing xs≈ys) = Setoid.refl (MaybeSetoid (VecISetoid S atₛ _))
246
247 sequence-cong : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → (α : Setoid ℓ₀ ℓ₀) → {s : S} {x y : C (Maybe (Setoid.Carrier α)) s} → ShapedISetoid (P.setoid S) ShapeT (MaybeSetoid α) atₛ _ ∋ x ≈ y → MaybeSetoid (ShapedISetoid (P.setoid S) ShapeT α atₛ _) ∋ Shaped.sequence ShapeT x ≈ Shaped.sequence ShapeT y
248 sequence-cong ShapeT α {x = x} {y = y} (shape≈ , content≈) with sequenceV (Shaped.content ShapeT x) | sequenceV (Shaped.content ShapeT y) | sequenceV-cong α content≈
249 sequence-cong ShapeT α {s} (shape≈ , content≈) | .(just x) | .(just y) | just {x} {y} x≈y = just (P.refl , (begin
250   content (fill s x)
251     ≡⟨ fill-content s x ⟩
252   x
253     ≈⟨ x≈y ⟩
254   y
255     ≡⟨ P.sym (fill-content s y) ⟩
256   content (fill s y) ∎))
257   where open EqR (VecISetoid α atₛ _)
258         open Shaped ShapeT
259 sequence-cong ShapeT α (shape≈ , content≈) | .nothing  | .nothing  | nothing = nothing
260
261 module _ (G : Get) where
262   open Get G
263   open Shaped SourceShapeT using () renaming (arity to arityS)
264   open Shaped ViewShapeT using () renaming (content to contentV)
265
266   theorem-2 : {i : I} → (j : I) → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ j)) → (u : SourceContainer (Maybe Carrier) (gl₁ j)) → bff G j s v ≡ just u → ShapedISetoid (P.setoid _) ViewShapeT (MaybeSetoid A.setoid) atₛ _ ∋ get u ≈ Get.fmapV G just v
267   theorem-2 {i} j s v u p with lemma-<$>-just ((flip union (reshape (delete-many (contentV (get (enumerate SourceShapeT (gl₁ i)))) (fromFunc (denumerate SourceShapeT s))) (arityS (gl₁ j)))) <$> assoc (contentV (get (enumerate SourceShapeT (gl₁ j)))) (contentV v)) p
268   theorem-2 {i} j s v u p | h′ , ph′ with lemma-<$>-just (assoc (contentV (get (enumerate SourceShapeT (gl₁ j)))) (contentV v)) ph′
269   theorem-2 {i} j s v u p | h′ , ph′ | h , ph = P.refl , (begin
270     contentV (get u)
271       ≡⟨ P.cong contentV (just-injective (P.trans (P.cong (_<$>_ get) (P.sym p))
272                                                   (P.cong (_<$>_ get ∘ _<$>_ h′↦r ∘ _<$>_ h↦h′) ph))) ⟩
273     contentV (get (h′↦r (h↦h′ h)))
274       ≡⟨ P.refl ⟩
275     contentV (get (fmapS (flip lookupM (h↦h′ h)) t))
276       ≡⟨ P.cong contentV (free-theorem (flip lookupM (h↦h′ h)) t) ⟩
277     contentV (fmapV (flip lookupM (h↦h′ h)) (get t))
278       ≡⟨ Shaped.fmap-content ViewShapeT (flip lookupM (h↦h′ h)) (get t) ⟩
279     map (flip lookupM (h↦h′ h)) (contentV (get t))
280       ≡⟨ lemma-exchange-maps (h↦h′ h) h (lemma-union-not-used h (reshape g′ (arityS (gl₁ j)))) (lemma-assoc-domain (contentV (get t)) (contentV v) ph) ⟩
281     map (flip lookupM h) (contentV (get t))
282       ≈⟨ lemma-2 (contentV (get t)) (contentV v) h ph ⟩
283     map just (contentV v)
284       ≡⟨ P.sym (Shaped.fmap-content ViewShapeT just v) ⟩
285     contentV (fmapV just v) ∎)
286       where open EqR (VecISetoid (MaybeSetoid A.setoid) atₛ _)
287             s′   = enumerate SourceShapeT (gl₁ i)
288             g    = fromFunc (denumerate SourceShapeT s)
289             g′   = delete-many (contentV (get s′)) g
290             t    = enumerate SourceShapeT (gl₁ j)
291             h↦h′ = flip union (reshape g′ (arityS (gl₁ j)))
292             h′↦r = (λ f → fmapS f t) ∘ flip lookupM
293
294 module _ (G : Get) where
295   open Get G
296
297   theorem-2′ : {i : I} → (j : I) → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ j)) → (u : SourceContainer Carrier (gl₁ j)) → bff G j s v ≡ just (Get.fmapS G just u) → ShapedISetoid (P.setoid _) ViewShapeT A.setoid atₛ _ ∋ get u ≈ v
298   theorem-2′ j s v u p = drop-just (begin
299     get <$> just u
300       ≡⟨ P.cong (_<$>_ get) (P.sym (lemma-just-sequence SourceShapeT u)) ⟩
301     get <$> Shaped.sequence SourceShapeT (fmapS just u)
302       ≡⟨ lemma-get-sequence G (lemma-just-sequence SourceShapeT u) ⟩
303     Shaped.sequence ViewShapeT (get (fmapS just u))
304       ≈⟨ sequence-cong ViewShapeT A.setoid (theorem-2 G j s v (fmapS just u) p) ⟩
305     Shaped.sequence ViewShapeT (fmapV just v)
306       ≡⟨ lemma-just-sequence ViewShapeT v ⟩
307     just v ∎)
308     where open EqR (MaybeSetoid (ShapedISetoid (P.setoid _) ViewShapeT A.setoid atₛ _))