c4c2f602e3ef91fea05bea8c7ed90adbce9c6d1f
[~helmut/bidiragda.git] / Bidir.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module Bidir (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin)
8 import Level
9 import Category.Monad
10 import Category.Functor
11 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′ ; drop-just) renaming (setoid to MaybeSetoid ; Eq to MaybeEq)
12 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
13 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
14 open import Data.List using (List)
15 open import Data.List.All using (All)
16 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; map ; allFin) renaming (lookup to lookupVec)
17 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
18 open import Data.Vec.Properties using (lookup∘tabulate ; lookup∘update ; map-cong ; map-∘ ; map-lookup-allFin)
19 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
20 open import Function using (id ; _∘_ ; flip)
21 open import Relation.Binary.Indexed using (_at_) renaming (Setoid to ISetoid)
22 open import Relation.Binary.PropositionalEquality as P using (_≡_ ; inspect ; [_] ; module ≡-Reasoning)
23 open import Relation.Binary using (Setoid ; module Setoid ; module DecSetoid)
24 import Relation.Binary.EqReasoning as EqR
25
26 open import Structures using (Functor ; IsFunctor ; Shaped ; module Shaped)
27 open import Instances using (MaybeFunctor ; ShapedISetoid)
28 import GetTypes
29 open GetTypes.PartialShapeShape using (Get ; module Get)
30 open import Generic using (mapMV ; mapMV-cong ; mapMV-purity ; sequenceV ; VecISetoid ; just-injective)
31 open import FinMap
32 import CheckInsert
33 open CheckInsert A
34 import BFF
35 open BFF.PartialShapeBFF A using (assoc ; enumerate ; denumerate ; bff)
36 open Setoid using () renaming (_≈_ to _∋_≈_)
37 open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
38
39 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f is)
40 lemma-1 f []        = P.refl
41 lemma-1 f (i ∷ is′) = begin
42   (assoc is′ (map f is′) >>= checkInsert i (f i))
43     ≡⟨ P.cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
44   checkInsert i (f i) (restrict f is′)
45     ≡⟨ lemma-checkInsert-restrict f i is′ ⟩
46   just (restrict f (i ∷ is′)) ∎
47   where open ≡-Reasoning
48
49 lemma-lookupM-checkInserted : {n : ℕ} → (i : Fin n) → (x : Carrier) → (h : FinMapMaybe n Carrier) → {h' : FinMapMaybe n Carrier} → checkInsert i x h ≡ just h' → MaybeSetoid A.setoid ∋ lookupM i h' ≈ just x
50 lemma-lookupM-checkInserted i x h p with checkInsert i x h | insertionresult i x h
51 lemma-lookupM-checkInserted i x h P.refl | ._              | same x' x≈x' pl = begin
52   lookupM i h
53     ≡⟨ pl ⟩
54   just x'
55     ≈⟨ MaybeEq.just (Setoid.sym A.setoid x≈x') ⟩
56   just x ∎
57   where open EqR (MaybeSetoid A.setoid)
58 lemma-lookupM-checkInserted i x h P.refl | ._ | new _ = Setoid.reflexive (MaybeSetoid A.setoid) (lookup∘update i h (just x))
59 lemma-lookupM-checkInserted i x h ()     | ._ | wrong _ _ _
60
61 _in-domain-of_ : {m n : ℕ} {A : Set} → (is : Vec (Fin m) n) → (FinMapMaybe m A) → Set
62 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) (toList is)
63
64 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → {h : FinMapMaybe n Carrier} → assoc is xs ≡ just h → is in-domain-of h
65 lemma-assoc-domain []         []         ph = Data.List.All.[]
66 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ph with assoc is' xs' | inspect (assoc is') xs'
67 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') () | nothing | [ ph' ]
68 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
69 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') P.refl | just h | [ ph' ] | ._ | _ | same x _ pl = All._∷_ (x , pl) (lemma-assoc-domain is' xs' ph')
70 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') P.refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
71   (x' , lookup∘update i' h' (just x'))
72   (Data.List.All.map
73     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' h' (proj₂ p) x' cI≡)
74     (lemma-assoc-domain is' xs' ph'))
75 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
76
77 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → {h' : FinMapMaybe m Carrier} → checkInsert i x h ≡ just h' → {n : ℕ} → (js : Vec (Fin m) n) → js in-domain-of h → map (flip lookupM h') js ≡ map (flip lookupM h) js
78 lemma-map-lookupM-assoc i x h ph [] pj = P.refl
79 lemma-map-lookupM-assoc i x h ph (j ∷ js) (Data.List.All._∷_ (x' , pl) pj) = P.cong₂ _∷_
80   (P.trans (lemma-lookupM-checkInsert j i h pl x ph) (P.sym pl))
81   (lemma-map-lookupM-assoc i x h ph js pj)
82
83 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → VecISetoid (MaybeSetoid A.setoid) at _ ∋ map (flip lookupM h) is ≈ map just v
84 lemma-2 []       []       h p = ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))
85 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
86 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
87 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
88   lookupM i h ∷ map (flip lookupM h) is
89     ≈⟨ VecEq._∷-cong_ (lemma-lookupM-checkInserted i x h' p) (ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))) ⟩
90   just x ∷ map (flip lookupM h) is
91     ≡⟨  P.cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h' p is (lemma-assoc-domain is xs ir)) ⟩
92   just x ∷ map (flip lookupM h') is
93     ≈⟨ VecEq._∷-cong_ (Setoid.refl (MaybeSetoid A.setoid)) (lemma-2 is xs h' ir) ⟩
94   just x ∷ map just xs ∎
95   where open EqR (VecISetoid (MaybeSetoid A.setoid) at _)
96
97 lemma-fmap-denumerate-enumerate : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {α : Set} {s : S} → (c : C α s) → Shaped.fmap ShapeT (denumerate ShapeT c) (enumerate ShapeT s) ≡ c
98 lemma-fmap-denumerate-enumerate {S} {C} ShapeT {s = s} c = begin
99   fmap (denumerate ShapeT c) (fill s (allFin (arity s)))
100     ≡⟨ fill-fmap (denumerate ShapeT c) s (allFin (arity s)) ⟩
101   fill s (map (flip lookupVec (content c)) (allFin (arity s)))
102     ≡⟨ P.cong (fill s) (map-lookup-allFin (content c)) ⟩
103   fill s (content c)
104     ≡⟨ content-fill c ⟩
105   c ∎
106   where open ≡-Reasoning
107         open Shaped ShapeT
108
109
110 theorem-1 : (G : Get) → {i : Get.I G} → (s : Get.SourceContainer G Carrier (Get.gl₁ G i)) → bff G i s (Get.get G s) ≡ just (Get.fmapS G just s)
111 theorem-1 G {i} s = begin
112   bff G i s (get s)
113     ≡⟨ P.cong (bff G i s ∘ get) (P.sym (lemma-fmap-denumerate-enumerate SourceShapeT s)) ⟩
114   bff G i s (get (fmapS f t))
115     ≡⟨ P.cong (bff G i s) (free-theorem f t) ⟩
116   bff G i s (fmapV f (get t))
117     ≡⟨ P.refl ⟩
118   h′↦r <$> (h↦h′ <$> (assoc (Shaped.content ViewShapeT (get t)) (Shaped.content ViewShapeT (fmapV f (get t)))))
119     ≡⟨ P.cong (_<$>_ h′↦r ∘ _<$>_ h↦h′ ∘ assoc (Shaped.content ViewShapeT (get t))) (Shaped.fmap-content ViewShapeT f (get t)) ⟩
120   h′↦r <$> (h↦h′ <$> (assoc (Shaped.content ViewShapeT (get t)) (map f (Shaped.content ViewShapeT (get t)))))
121     ≡⟨ P.cong (_<$>_ h′↦r ∘ _<$>_ h↦h′) (lemma-1 f (Shaped.content ViewShapeT (get t))) ⟩
122   (Maybe.just ∘ h′↦r ∘ h↦h′) (restrict f (Shaped.content ViewShapeT (get t)))
123     ≡⟨ P.cong just (begin
124       h′↦r (union (restrict f (Shaped.content ViewShapeT (get t))) (reshape g′ (Shaped.arity SourceShapeT (gl₁ i))))
125         ≡⟨ P.cong (h′↦r ∘ union (restrict f (Shaped.content ViewShapeT (get t)))) (lemma-reshape-id g′) ⟩
126       h′↦r (union (restrict f (Shaped.content ViewShapeT (get t))) g′)
127         ≡⟨ P.cong h′↦r (lemma-disjoint-union f (Shaped.content ViewShapeT (get t))) ⟩
128       h′↦r (fromFunc f)
129         ≡⟨ P.refl ⟩
130       fmapS (flip lookupM (fromFunc f)) t
131         ≡⟨ IsFunctor.cong (Shaped.isFunctor SourceShapeT (gl₁ i)) (lemma-lookupM-fromFunc f) t ⟩
132       fmapS (Maybe.just ∘ f) t
133         ≡⟨ IsFunctor.composition (Shaped.isFunctor SourceShapeT (gl₁ i)) just f t ⟩
134       fmapS just (fmapS f t)
135         ≡⟨ P.cong (fmapS just) (lemma-fmap-denumerate-enumerate SourceShapeT s) ⟩
136       fmapS just s ∎) ⟩ _ ∎
137     where open ≡-Reasoning
138           open Get G
139           t    = enumerate SourceShapeT (gl₁ i)
140           f    = denumerate SourceShapeT s
141           g′   = delete-many (Shaped.content ViewShapeT (get t)) (fromFunc f)
142           h↦h′ = flip union (reshape g′ (Shaped.arity SourceShapeT (gl₁ i)))
143           h′↦r = (λ f′ → fmapS f′ t) ∘ flip lookupM
144
145
146 lemma-<$>-just : {A B : Set} {f : A → B} {b : B} (ma : Maybe A) → (f <$> ma) ≡ just b → ∃ λ a → ma ≡ just a
147 lemma-<$>-just (just x) f<$>ma≡just-b = x , P.refl
148 lemma-<$>-just nothing  ()
149
150 lemma-union-not-used : {n : ℕ} → {A : Set} → (h h′ : FinMapMaybe n A) → (i : Fin n) → ∃ (λ x → lookupM i h ≡ just x) → lookupM i (union h h′) ≡ lookupM i h
151 lemma-union-not-used h h′ i (x , px) = begin
152   lookupM i (union h h′)
153     ≡⟨ lookup∘tabulate (λ j → maybe′ just (lookupM j h′) (lookupM j h)) i ⟩
154   maybe′ just (lookupM i h′) (lookupM i h)
155     ≡⟨ P.cong (maybe′ just (lookupM i h′)) px ⟩
156   maybe′ just (lookupM i h′) (just x)
157     ≡⟨ P.sym px ⟩
158   lookupM i h ∎
159   where open ≡-Reasoning
160
161 lemma->>=-just : {A B : Set} (ma : Maybe A) {f : A → Maybe B} {b : B} → (ma >>= f) ≡ just b → ∃ λ a → ma ≡ just a
162 lemma->>=-just (just a) p = a , P.refl
163 lemma->>=-just nothing  ()
164
165 lemma-just-sequenceV : {A : Set} {n : ℕ} → (v : Vec A n) → sequenceV (map just v) ≡ just v
166 lemma-just-sequenceV []       = P.refl
167 lemma-just-sequenceV (x ∷ xs) = P.cong (_<$>_ (_∷_ x)) (lemma-just-sequenceV xs)
168
169 lemma-just-sequence : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {A : Set} {s : S} → (c : C A s) → Shaped.sequence ShapeT (Shaped.fmap ShapeT just c) ≡ just c
170 lemma-just-sequence ShapeT {s = s} c = begin
171   fill s <$> sequenceV (content (fmap just c))
172     ≡⟨ P.cong (_<$>_ (fill s) ∘ sequenceV) (fmap-content just c) ⟩
173   fill s <$> sequenceV (map just (content c))
174     ≡⟨ P.cong (_<$>_ (fill s)) (lemma-just-sequenceV (content c)) ⟩
175   fill s <$> just (content c)
176     ≡⟨ P.cong just (content-fill c) ⟩
177   just c ∎
178   where open ≡-Reasoning
179         open Shaped ShapeT
180
181 lemma-sequenceV-successful : {A : Set} {n : ℕ} → (v : Vec (Maybe A) n) → {r : Vec A n} → sequenceV v ≡ just r → v ≡ map just r
182 lemma-sequenceV-successful []             {r = []}       p = P.refl
183 lemma-sequenceV-successful (just x ∷ xs)                 p with sequenceV xs | inspect sequenceV xs
184 lemma-sequenceV-successful (just x ∷ xs)                 () | nothing | _
185 lemma-sequenceV-successful (just x ∷ xs)  {r = .x ∷ .ys} P.refl  | just ys | [ p′ ] = P.cong (_∷_ (just x)) (lemma-sequenceV-successful xs p′)
186 lemma-sequenceV-successful (nothing ∷ xs)                ()
187
188 lemma-sequence-successful : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {A : Set} {s : S} → (c : C (Maybe A) s) → {r : C A s} → Shaped.sequence ShapeT c ≡ just r → c ≡ Shaped.fmap ShapeT just r
189 lemma-sequence-successful ShapeT {s = s} c {r} p = just-injective (P.sym (begin
190   fill s <$> (map just <$> (content <$> just r))
191     ≡⟨ P.cong (_<$>_ (fill s) ∘ _<$>_ (map just)) (begin
192       content <$> just r
193         ≡⟨ P.cong (_<$>_ content) (P.sym p) ⟩
194       content <$> (fill s <$> sequenceV (content c))
195         ≡⟨ P.sym (Functor.composition MaybeFunctor content (fill s) (sequenceV (content c))) ⟩
196       content ∘ fill s <$> sequenceV (content c)
197         ≡⟨ Functor.cong MaybeFunctor (fill-content s) (sequenceV (content c)) ⟩
198       id <$> sequenceV (content c)
199         ≡⟨ Functor.identity MaybeFunctor (sequenceV (content c)) ⟩
200       sequenceV (content c)
201         ≡⟨ P.cong sequenceV (lemma-sequenceV-successful (content c) (proj₂ wp)) ⟩
202       sequenceV (map just (proj₁ wp))
203         ≡⟨ lemma-just-sequenceV (proj₁ wp) ⟩
204       just (proj₁ (lemma-<$>-just (sequenceV (content c)) p)) ∎) ⟩
205   fill s <$> (map just <$> just (proj₁ (lemma-<$>-just (sequenceV (content c)) p)))
206     ≡⟨ P.cong (_<$>_ (fill s) ∘ just) (P.sym (lemma-sequenceV-successful (content c) (proj₂ wp))) ⟩
207   fill s <$> just (content c)
208     ≡⟨ P.cong just (content-fill c) ⟩
209   just c ∎))
210   where open ≡-Reasoning
211         open Shaped ShapeT
212         wp = lemma-<$>-just (sequenceV (content c)) p
213
214 module _ (G : Get) where
215   open ≡-Reasoning
216   open Get G
217   open Shaped SourceShapeT using () renaming (sequence to sequenceSource)
218   open Shaped ViewShapeT using () renaming (sequence to sequenceView)
219
220   lemma-get-sequence : {A : Set} → {i : I} {v : SourceContainer (Maybe A) (gl₁ i)} {r : SourceContainer A (gl₁ i)} → sequenceSource v ≡ just r → (get <$> sequenceSource v) ≡ sequenceView (get v)
221   lemma-get-sequence {v = v} {r = r} p = begin
222     get <$> sequenceSource v
223       ≡⟨ P.cong (_<$>_ get ∘ sequenceSource) (lemma-sequence-successful SourceShapeT v p) ⟩
224     get <$> sequenceSource (fmapS just r)
225       ≡⟨ P.cong (_<$>_ get) (lemma-just-sequence SourceShapeT r) ⟩
226     get <$> just r
227       ≡⟨ P.sym (lemma-just-sequence ViewShapeT (get r)) ⟩
228     sequenceView (fmapV just (get r))
229       ≡⟨ P.cong sequenceView (P.sym (free-theorem just r)) ⟩
230     sequenceView (get (fmapS just r))
231       ≡⟨ P.cong (sequenceView ∘ get) (P.sym (lemma-sequence-successful SourceShapeT v p)) ⟩
232     sequenceView (get v) ∎
233
234 sequenceV-cong : {S : Setoid ℓ₀ ℓ₀} {n : ℕ} {m₁ m₂ : Setoid.Carrier (VecISetoid (MaybeSetoid S) at n)} → VecISetoid (MaybeSetoid S) at _ ∋ m₁ ≈ m₂ → MaybeSetoid (VecISetoid S at n) ∋ sequenceV m₁ ≈ sequenceV m₂
235 sequenceV-cong {S}                                       VecEq.[]-cong = Setoid.refl (MaybeSetoid (VecISetoid S at _))
236 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) with sequenceV xs | sequenceV ys | sequenceV-cong xs≈ys
237 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | just sys | just p = MaybeEq.just (VecEq._∷-cong_ x≈y p)
238 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | just sys | ()
239 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | nothing | ()
240 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | nothing | nothing = Setoid.refl (MaybeSetoid (VecISetoid S at _))
241 sequenceV-cong {S}                                       (VecEq._∷-cong_ nothing xs≈ys) = Setoid.refl (MaybeSetoid (VecISetoid S at _))
242
243 sequence-cong : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → (α : Setoid ℓ₀ ℓ₀) → {s : S} {x y : C (Maybe (Setoid.Carrier α)) s} → ShapedISetoid (P.setoid S) ShapeT (MaybeSetoid α) at _ ∋ x ≈ y → MaybeSetoid (ShapedISetoid (P.setoid S) ShapeT α at _) ∋ Shaped.sequence ShapeT x ≈ Shaped.sequence ShapeT y
244 sequence-cong ShapeT α {x = x} {y = y} (shape≈ , content≈) with sequenceV (Shaped.content ShapeT x) | sequenceV (Shaped.content ShapeT y) | sequenceV-cong content≈
245 sequence-cong ShapeT α {s} (shape≈ , content≈) | .(just x) | .(just y) | just {x} {y} x≈y = just (P.refl , (begin
246   content (fill s x)
247     ≡⟨ fill-content s x ⟩
248   x
249     ≈⟨ x≈y ⟩
250   y
251     ≡⟨ P.sym (fill-content s y) ⟩
252   content (fill s y) ∎))
253   where open EqR (VecISetoid α at _)
254         open Shaped ShapeT
255 sequence-cong ShapeT α (shape≈ , content≈) | .nothing  | .nothing  | nothing = nothing
256
257 module _ (G : Get) where
258   open Get G
259   open Shaped SourceShapeT using () renaming (arity to arityS)
260   open Shaped ViewShapeT using () renaming (content to contentV)
261
262   theorem-2 : {i : I} → (j : I) → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ j)) → (u : SourceContainer (Maybe Carrier) (gl₁ j)) → bff G j s v ≡ just u → ShapedISetoid (P.setoid _) ViewShapeT (MaybeSetoid A.setoid) at _ ∋ get u ≈ Get.fmapV G just v
263   theorem-2 {i} j s v u p with lemma-<$>-just ((flip union (reshape (delete-many (contentV (get (enumerate SourceShapeT (gl₁ i)))) (fromFunc (denumerate SourceShapeT s))) (arityS (gl₁ j)))) <$> assoc (contentV (get (enumerate SourceShapeT (gl₁ j)))) (contentV v)) p
264   theorem-2 {i} j s v u p | h′ , ph′ with lemma-<$>-just (assoc (contentV (get (enumerate SourceShapeT (gl₁ j)))) (contentV v)) ph′
265   theorem-2 {i} j s v u p | h′ , ph′ | h , ph = P.refl , (begin
266     contentV (get u)
267       ≡⟨ P.cong contentV (just-injective (P.trans (P.cong (_<$>_ get) (P.sym p))
268                                                   (P.cong (_<$>_ get ∘ _<$>_ h′↦r ∘ _<$>_ h↦h′) ph))) ⟩
269     contentV (get (h′↦r (h↦h′ h)))
270       ≡⟨ P.refl ⟩
271     contentV (get (fmapS (flip lookupM (h↦h′ h)) t))
272       ≡⟨ P.cong contentV (free-theorem (flip lookupM (h↦h′ h)) t) ⟩
273     contentV (fmapV (flip lookupM (h↦h′ h)) (get t))
274       ≡⟨ Shaped.fmap-content ViewShapeT (flip lookupM (h↦h′ h)) (get t) ⟩
275     map (flip lookupM (h↦h′ h)) (contentV (get t))
276       ≡⟨ lemma-exchange-maps (lemma-union-not-used h (reshape g′ (arityS (gl₁ j)))) (lemma-assoc-domain (contentV (get t)) (contentV v) ph) ⟩
277     map (flip lookupM h) (contentV (get t))
278       ≈⟨ lemma-2 (contentV (get t)) (contentV v) h ph ⟩
279     map just (contentV v)
280       ≡⟨ P.sym (Shaped.fmap-content ViewShapeT just v) ⟩
281     contentV (fmapV just v) ∎)
282       where open EqR (VecISetoid (MaybeSetoid A.setoid) at _)
283             s′   = enumerate SourceShapeT (gl₁ i)
284             g    = fromFunc (denumerate SourceShapeT s)
285             g′   = delete-many (contentV (get s′)) g
286             t    = enumerate SourceShapeT (gl₁ j)
287             h↦h′ = flip union (reshape g′ (arityS (gl₁ j)))
288             h′↦r = (λ f → fmapS f t) ∘ flip lookupM
289
290 module _ (G : Get) where
291   open Get G
292
293   theorem-2′ : {i : I} → (j : I) → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ j)) → (u : SourceContainer Carrier (gl₁ j)) → bff G j s v ≡ just (Get.fmapS G just u) → ShapedISetoid (P.setoid _) ViewShapeT A.setoid at _ ∋ get u ≈ v
294   theorem-2′ j s v u p = drop-just (begin
295     get <$> just u
296       ≡⟨ P.cong (_<$>_ get) (P.sym (lemma-just-sequence SourceShapeT u)) ⟩
297     get <$> Shaped.sequence SourceShapeT (fmapS just u)
298       ≡⟨ lemma-get-sequence G (lemma-just-sequence SourceShapeT u) ⟩
299     Shaped.sequence ViewShapeT (get (fmapS just u))
300       ≈⟨ sequence-cong ViewShapeT A.setoid (theorem-2 G j s v (fmapS just u) p) ⟩
301     Shaped.sequence ViewShapeT (fmapV just v)
302       ≡⟨ lemma-just-sequence ViewShapeT v ⟩
303     just v ∎)
304     where open EqR (MaybeSetoid (ShapedISetoid (P.setoid _) ViewShapeT A.setoid at _))