Merge branch feature-omit-sequence into master
[~helmut/bidiragda.git] / Bidir.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module Bidir (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin)
8 import Level
9 import Category.Monad
10 import Category.Functor
11 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′ ; drop-just) renaming (setoid to MaybeSetoid ; Eq to MaybeEq)
12 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
13 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
14 open import Data.List using (List)
15 open import Data.List.All using (All)
16 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; map ; tabulate) renaming (lookup to lookupVec)
17 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
18 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
19 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
20 open import Function using (id ; _∘_ ; flip)
21 open import Relation.Binary.Core using (refl ; _≡_)
22 open import Relation.Binary.Indexed using (_at_) renaming (Setoid to ISetoid)
23 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; trans ; cong₂ ; decSetoid ; module ≡-Reasoning) renaming (setoid to EqSetoid)
24 open import Relation.Binary using (Setoid ; module Setoid ; module DecSetoid)
25 import Relation.Binary.EqReasoning as EqR
26
27 import GetTypes
28 open GetTypes.PartialVecVec using (Get ; module Get)
29 open import Generic using (mapMV ; mapMV-cong ; mapMV-purity ; sequenceV ; VecISetoid ; just-injective)
30 open import FinMap
31 import CheckInsert
32 open CheckInsert A
33 import BFF
34 open BFF.PartialVecBFF A using (assoc ; enumerate ; enumeratel ; denumerate ; bff)
35 open Setoid using () renaming (_≈_ to _∋_≈_)
36 open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
37
38 module SetoidReasoning where
39  infix 1 begin⟨_⟩_
40  infixr 2 _≈⟨_⟩_ _≡⟨_⟩_
41  infix 2 _∎
42  begin⟨_⟩_ : (X : Setoid ℓ₀ ℓ₀) → {x y : Setoid.Carrier X} → EqR._IsRelatedTo_ X x y → X ∋ x ≈ y
43  begin⟨_⟩_ X p = EqR.begin_ X p
44  _∎ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → EqR._IsRelatedTo_ X x x
45  _∎ {X} = EqR._∎ X
46  _≈⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → X ∋ x ≈ y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
47  _≈⟨_⟩_ {X} = EqR._≈⟨_⟩_ X
48
49  _≡⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → x ≡ y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
50  _≡⟨_⟩_ {X} = EqR._≡⟨_⟩_ X
51
52 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
53 lemma-1 f []        = refl
54 lemma-1 f (i ∷ is′) = begin
55   (assoc is′ (map f is′) >>= checkInsert i (f i))
56     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
57   checkInsert i (f i) (restrict f (toList is′))
58     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
59   just (restrict f (toList (i ∷ is′))) ∎
60   where open ≡-Reasoning
61
62 lemma-lookupM-checkInserted : {n : ℕ} → (i : Fin n) → (x : Carrier) → (h h' : FinMapMaybe n Carrier) → checkInsert i x h ≡ just h' → MaybeSetoid A.setoid ∋ lookupM i h' ≈ just x
63 lemma-lookupM-checkInserted i x h h' p with checkInsert i x h | insertionresult i x h
64 lemma-lookupM-checkInserted i x h .h refl | ._ | same x' x≈x' pl = begin
65   lookupM i h
66     ≡⟨ pl ⟩
67   just x'
68     ≈⟨ MaybeEq.just (Setoid.sym A.setoid x≈x') ⟩
69   just x ∎
70   where open EqR (MaybeSetoid A.setoid)
71 lemma-lookupM-checkInserted i x h ._ refl | ._ | new _ = Setoid.reflexive (MaybeSetoid A.setoid) (lemma-lookupM-insert i x h)
72 lemma-lookupM-checkInserted i x h h' () | ._ | wrong _ _ _
73
74 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
75 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
76
77 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
78 lemma-assoc-domain []         []         h ph = Data.List.All.[]
79 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
80 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
81 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
82 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') .h refl | just h | [ ph' ] | ._ | _ | same x _ pl = All._∷_ (x , pl) (lemma-assoc-domain is' xs' h ph')
83 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ._ refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
84   (x' , lemma-lookupM-insert i' x' h')
85   (Data.List.All.map
86     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' (insert i' x' h') (proj₂ p) cI≡)
87     (lemma-assoc-domain is' xs' h' ph'))
88 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
89
90 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → (h' : FinMapMaybe m Carrier) → checkInsert i x h' ≡ just h → {n : ℕ} → (js : Vec (Fin m) n) → (toList js) in-domain-of h' → map (flip lookupM h) js ≡ map (flip lookupM h') js
91 lemma-map-lookupM-assoc i x h h' ph [] pj = refl
92 lemma-map-lookupM-assoc i x h h' ph (j ∷ js) (Data.List.All._∷_ (x' , pl) pj) = cong₂ _∷_
93   (trans (lemma-lookupM-checkInsert j i x' x h' h pl ph) (sym pl))
94   (lemma-map-lookupM-assoc i x h h' ph js pj)
95
96 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → VecISetoid (MaybeSetoid A.setoid) at _ ∋ map (flip lookupM h) is ≈ map just v
97 lemma-2 []       []       h p = ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))
98 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
99 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
100 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
101   lookupM i h ∷ map (flip lookupM h) is
102     ≈⟨ VecEq._∷-cong_ (lemma-lookupM-checkInserted i x h' h p) (ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))) ⟩
103   just x ∷ map (flip lookupM h) is
104     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h h' p is (lemma-assoc-domain is xs h' ir)) ⟩
105   just x ∷ map (flip lookupM h') is
106     ≈⟨ VecEq._∷-cong_ (Setoid.refl (MaybeSetoid A.setoid)) (lemma-2 is xs h' ir) ⟩
107   just x ∷ map just xs ∎
108   where open EqR (VecISetoid (MaybeSetoid A.setoid) at _)
109
110 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
111 lemma-map-denumerate-enumerate []       = refl
112 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
113   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
114     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
115   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
116     ≡⟨ refl ⟩
117   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
118     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
119   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
120     ≡⟨ refl ⟩
121   map (denumerate as) (enumerate as)
122     ≡⟨ lemma-map-denumerate-enumerate as ⟩
123   as ∎)
124   where open ≡-Reasoning
125
126 theorem-1 : (G : Get) → {i : Get.|I| G} → (s : Vec Carrier (Get.|gl₁| G i)) → bff G i s (Get.get G s) ≡ just (map just s)
127 theorem-1 G {i} s = begin
128   bff G i s (get s)
129     ≡⟨ cong (bff G i s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
130   bff G i s (get (map (denumerate s) (enumerate s)))
131     ≡⟨ cong (bff G i s) (free-theorem (denumerate s) (enumerate s)) ⟩
132   bff G i s (map (denumerate s) (get (enumerate s)))
133     ≡⟨ refl ⟩
134   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
135     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
136   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
137     ≡⟨ refl ⟩
138   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (reshape (delete-many (get (enumerate s)) (fromFunc (denumerate s))) (Get.|gl₁| G i)))
139     ≡⟨ cong (h′↦r ∘ Maybe.just ∘ union (restrict (denumerate s) (toList (get (enumerate s))))) (lemma-reshape-id (delete-many (get (enumerate s)) (fromFunc (denumerate s)))) ⟩
140   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (delete-many (get (enumerate s)) (fromFunc (denumerate s))))
141     ≡⟨ cong (h′↦r ∘ just) (lemma-disjoint-union (denumerate s) (get (enumerate s))) ⟩
142   (h′↦r ∘ just) (fromFunc (denumerate s))
143     ≡⟨ refl ⟩
144   just (map (flip lookupM (fromFunc (denumerate s))) (enumerate s))
145     ≡⟨ cong just (map-cong (lemma-lookupM-fromFunc (denumerate s)) (enumerate s)) ⟩
146   just (map (Maybe.just ∘ denumerate s) (enumerate s))
147     ≡⟨ cong just (map-∘ just (denumerate s) (enumerate s)) ⟩
148   just (map just (map (denumerate s) (enumerate s)))
149     ≡⟨ cong (Maybe.just ∘ map just) (lemma-map-denumerate-enumerate s) ⟩
150   just (map just s) ∎
151     where open ≡-Reasoning
152           open Get G
153           h↦h′ = _<$>_ (flip union (reshape (delete-many (get (enumerate s)) (fromFunc (denumerate s))) (Get.|gl₁| G i)))
154           h′↦r = _<$>_ (flip map (enumerate s) ∘ flip lookupM)
155
156
157 lemma-<$>-just : {A B : Set} {f : A → B} {b : B} (ma : Maybe A) → f <$> ma ≡ just b → ∃ λ a → ma ≡ just a
158 lemma-<$>-just (just x) f<$>ma≡just-b = x , refl
159 lemma-<$>-just nothing  ()
160
161 lemma-union-not-used : {m n n' : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMapMaybe n' A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map (flip lookupM (union h (reshape h' n))) is ≡ map (flip lookupM h) is
162 lemma-union-not-used         h h' []        p = refl
163 lemma-union-not-used {n = n} h h' (i ∷ is') (Data.List.All._∷_ (x , px) p') = cong₂ _∷_ (begin
164       lookupM i (union h (reshape h' n))
165         ≡⟨ lookup∘tabulate (λ j → maybe′ just (lookupM j (reshape h' n)) (lookupM j h)) i ⟩
166       maybe′ just (lookupM i (reshape h' n)) (lookupM i h)
167         ≡⟨ cong (maybe′ just (lookupM i (reshape h' n))) px ⟩
168       maybe′ just (lookupM i (reshape h' n)) (just x)
169         ≡⟨ sym px ⟩
170       lookupM i h ∎)
171   (lemma-union-not-used h h' is' p')
172   where open ≡-Reasoning
173
174 lemma->>=-just : {A B : Set} (ma : Maybe A) {f : A → Maybe B} {b : B} → (ma >>= f) ≡ just b → ∃ λ a → ma ≡ just a
175 lemma->>=-just (just a) p = a , refl
176 lemma->>=-just nothing  ()
177
178 lemma-just-sequence : {A : Set} {n : ℕ} → (v : Vec A n) → sequenceV (map just v) ≡ just v
179 lemma-just-sequence []       = refl
180 lemma-just-sequence (x ∷ xs) = cong (_<$>_ (_∷_ x)) (lemma-just-sequence xs)
181
182 lemma-sequenceV-successful : {A : Set} {n : ℕ} → (v : Vec (Maybe A) n) → {r : Vec A n} → sequenceV v ≡ just r → v ≡ map just r
183 lemma-sequenceV-successful []             {r = []}       p = refl
184 lemma-sequenceV-successful (just x ∷ xs)                 p with sequenceV xs | inspect sequenceV xs
185 lemma-sequenceV-successful (just x ∷ xs)                 () | nothing | _
186 lemma-sequenceV-successful (just x ∷ xs)  {r = .x ∷ .ys} refl  | just ys | [ p′ ] = cong (_∷_ (just x)) (lemma-sequenceV-successful xs p′)
187 lemma-sequenceV-successful (nothing ∷ xs)                ()
188
189 lemma-get-sequenceV : {A : Set} → (G : Get) → {i : Get.|I| G} {v : Vec (Maybe A) (Get.|gl₁| G i)} {r : Vec A (Get.|gl₁| G i)} → sequenceV v ≡ just r → Get.get G <$> sequenceV v ≡ sequenceV (Get.get G v)
190 lemma-get-sequenceV G {v = v} {r = r} p = begin
191   get <$> sequenceV v
192     ≡⟨ cong (_<$>_ get ∘ sequenceV) (lemma-sequenceV-successful v p) ⟩
193   get <$> sequenceV (map just r)
194     ≡⟨ cong (_<$>_ get) (lemma-just-sequence r) ⟩
195   get <$> just r
196     ≡⟨ sym (lemma-just-sequence (get r)) ⟩
197   sequenceV (map just (get r))
198     ≡⟨ cong sequenceV (sym (free-theorem just r)) ⟩
199   sequenceV (get (map just r))
200     ≡⟨ cong (sequenceV ∘ get) (sym (lemma-sequenceV-successful v p)) ⟩
201   sequenceV (get v) ∎
202   where open ≡-Reasoning
203         open Get G
204
205 sequence-cong : {S : Setoid ℓ₀ ℓ₀} {n : ℕ} {m₁ m₂ : Setoid.Carrier (VecISetoid (MaybeSetoid S) at n)} → VecISetoid (MaybeSetoid S) at _ ∋ m₁ ≈ m₂ → MaybeSetoid (VecISetoid S at n) ∋ sequenceV m₁ ≈ sequenceV m₂
206 sequence-cong {S}                                       VecEq.[]-cong = Setoid.refl (MaybeSetoid (VecISetoid S at _))
207 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) with sequenceV xs | sequenceV ys | sequence-cong xs≈ys
208 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | just sys | just p = MaybeEq.just (VecEq._∷-cong_ x≈y p)
209 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | just sys | ()
210 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | nothing | ()
211 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | nothing | nothing = Setoid.refl (MaybeSetoid (VecISetoid S at _))
212 sequence-cong {S}                                       (VecEq._∷-cong_ nothing xs≈ys) = Setoid.refl (MaybeSetoid (VecISetoid S at _))
213
214 theorem-2 : (G : Get) → {i : Get.|I| G} → (j : Get.|I| G) → (s : Vec Carrier (Get.|gl₁| G i)) → (v : Vec Carrier (Get.|gl₂| G j)) → (u : Vec (Maybe Carrier) (Get.|gl₁| G j)) → bff G j s v ≡ just u → VecISetoid (MaybeSetoid A.setoid) at _ ∋ Get.get G u ≈ map just v
215 theorem-2 G j s v u p with (lemma-<$>-just ((flip union (reshape (delete-many (Get.get G (enumerate s)) (fromFunc (denumerate s))) (Get.|gl₁| G j))) <$> (assoc (Get.get G (enumeratel (Get.|gl₁| G j))) v)) p)
216 theorem-2 G j s v u p | h′ , ph′ with (lemma-<$>-just (assoc (Get.get G (enumeratel (Get.|gl₁| G j))) v) ph′)
217 theorem-2 G j s v u p | h′ , ph′ | h , ph = begin⟨ VecISetoid (MaybeSetoid A.setoid) at _ ⟩
218   get u
219     ≡⟨ just-injective (trans (cong (_<$>_ get) (sym p))
220                              (cong (_<$>_ get ∘ _<$>_ h′↦r ∘ _<$>_ h↦h′) ph)) ⟩
221   get (h′↦r (h↦h′ h))
222     ≡⟨ refl ⟩
223   get (map (flip lookupM (h↦h′ h)) t)
224     ≡⟨ free-theorem (flip lookupM (h↦h′ h)) t ⟩
225   map (flip lookupM (h↦h′ h)) (get t)
226     ≡⟨ lemma-union-not-used h g′ (get t) (lemma-assoc-domain (get t) v h ph) ⟩
227   map (flip lookupM h) (get t)
228     ≈⟨ lemma-2 (get t) v h ph ⟩
229   map just v ∎
230     where open SetoidReasoning
231           open Get G
232           s′   = enumerate s
233           g    = fromFunc (denumerate s)
234           g′   = delete-many (get s′) g
235           t    = enumeratel (Get.|gl₁| G j)
236           h↦h′ = flip union (reshape g′ (Get.|gl₁| G j))
237           h′↦r = flip map t ∘ flip lookupM
238
239 theorem-2′ : (G : Get) → {i : Get.|I| G} → (j : Get.|I| G) → (s : Vec Carrier (Get.|gl₁| G i)) → (v : Vec Carrier (Get.|gl₂| G j)) → (u : Vec Carrier (Get.|gl₁| G j)) → bff G j s v ≡ just (map just u) → VecISetoid A.setoid at _ ∋ Get.get G u ≈ v
240 theorem-2′ G j s v u p = drop-just (begin
241   get <$> just u
242     ≡⟨ cong (_<$>_ get) (sym (lemma-just-sequence u)) ⟩
243   get <$> sequenceV (map just u)
244     ≡⟨ lemma-get-sequenceV G (lemma-just-sequence u) ⟩
245   sequenceV (get (map just u))
246     ≈⟨ sequence-cong (theorem-2 G j s v (map just u) p) ⟩
247   sequenceV (map just v)
248     ≡⟨ lemma-just-sequence v ⟩
249   just v ∎)
250   where open EqR (MaybeSetoid (VecISetoid A.setoid at _))
251         open Get G