cb29420004681708171d8c4edd156d04e54175cf
[~helmut/bidiragda.git] / Bidir.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module Bidir (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin)
8 import Level
9 import Category.Monad
10 import Category.Functor
11 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′ ; drop-just) renaming (setoid to MaybeSetoid ; Eq to MaybeEq)
12 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
13 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
14 open import Data.List using (List)
15 open import Data.List.All using (All)
16 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; map ; tabulate) renaming (lookup to lookupVec)
17 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
18 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
19 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
20 open import Function using (id ; _∘_ ; flip)
21 open import Function.Equality using (_⟶_ ; _⟨$⟩_)
22 open import Function.Injection using (module Injection) renaming (Injection to _↪_)
23 open Injection using (to)
24 open import Relation.Binary.Core using (refl ; _≡_)
25 open import Relation.Binary.Indexed using (_at_) renaming (Setoid to ISetoid)
26 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; trans ; cong₂ ; decSetoid ; module ≡-Reasoning) renaming (setoid to EqSetoid)
27 open import Relation.Binary using (Setoid ; module Setoid ; module DecSetoid)
28 import Relation.Binary.EqReasoning as EqR
29
30 import GetTypes
31 open GetTypes.PartialVecVec using (Get ; module Get)
32 open import Generic using (mapMV ; mapMV-cong ; mapMV-purity ; sequenceV ; sequence-map ; VecISetoid)
33 open import FinMap
34 import CheckInsert
35 open CheckInsert A
36 import BFF
37 open BFF.PartialVecBFF A using (assoc ; enumerate ; denumerate ; bff)
38 open Setoid using () renaming (_≈_ to _∋_≈_)
39 open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
40
41 module SetoidReasoning where
42  infix 1 begin⟨_⟩_
43  infixr 2 _≈⟨_⟩_ _≡⟨_⟩_
44  infix 2 _∎
45  begin⟨_⟩_ : (X : Setoid ℓ₀ ℓ₀) → {x y : Setoid.Carrier X} → EqR._IsRelatedTo_ X x y → X ∋ x ≈ y
46  begin⟨_⟩_ X p = EqR.begin_ X p
47  _∎ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → EqR._IsRelatedTo_ X x x
48  _∎ {X} = EqR._∎ X
49  _≈⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → X ∋ x ≈ y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
50  _≈⟨_⟩_ {X} = EqR._≈⟨_⟩_ X
51
52  _≡⟨_⟩_ : {X : Setoid ℓ₀ ℓ₀} → (x : Setoid.Carrier X) → {y z : Setoid.Carrier X} → x ≡ y → EqR._IsRelatedTo_ X y z → EqR._IsRelatedTo_ X x z
53  _≡⟨_⟩_ {X} = EqR._≡⟨_⟩_ X
54
55 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
56 lemma-1 f []        = refl
57 lemma-1 f (i ∷ is′) = begin
58   (assoc is′ (map f is′) >>= checkInsert i (f i))
59     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
60   checkInsert i (f i) (restrict f (toList is′))
61     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
62   just (restrict f (toList (i ∷ is′))) ∎
63   where open ≡-Reasoning
64
65 lemma-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc (i ∷ is) (x ∷ xs) ≡ just h → MaybeSetoid A.setoid ∋ lookupM i h ≈ just x
66 lemma-lookupM-assoc i is x xs h    p with assoc is xs
67 lemma-lookupM-assoc i is x xs h    () | nothing
68 lemma-lookupM-assoc i is x xs h    p | just h' with checkInsert i x h' | insertionresult i x h'
69 lemma-lookupM-assoc i is x xs .h refl | just h | ._ | same x' x≈x' pl = begin
70   lookupM i h
71     ≡⟨ pl ⟩
72   just x'
73     ≈⟨ MaybeEq.just (Setoid.sym A.setoid x≈x') ⟩
74   just x ∎
75   where open EqR (MaybeSetoid A.setoid)
76 lemma-lookupM-assoc i is x xs ._ refl | just h' | ._ | new _ =  Setoid.reflexive (MaybeSetoid A.setoid) (lemma-lookupM-insert i x h')
77 lemma-lookupM-assoc i is x xs h () | just h' | ._ | wrong _ _ _
78
79 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
80 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
81
82 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
83 lemma-assoc-domain []         []         h ph = Data.List.All.[]
84 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
85 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
86 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
87 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') .h refl | just h | [ ph' ] | ._ | _ | same x _ pl = All._∷_ (x , pl) (lemma-assoc-domain is' xs' h ph')
88 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ._ refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
89   (x' , lemma-lookupM-insert i' x' h')
90   (Data.List.All.map
91     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' (insert i' x' h') (proj₂ p) cI≡)
92     (lemma-assoc-domain is' xs' h' ph'))
93 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
94
95 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → (h' : FinMapMaybe m Carrier) → checkInsert i x h' ≡ just h → {n : ℕ} → (js : Vec (Fin m) n) → (toList js) in-domain-of h' → map (flip lookupM h) js ≡ map (flip lookupM h') js
96 lemma-map-lookupM-assoc i x h h' ph [] pj = refl
97 lemma-map-lookupM-assoc i x h h' ph (j ∷ js) (Data.List.All._∷_ (x' , pl) pj) = cong₂ _∷_
98   (trans (lemma-lookupM-checkInsert j i x' x h' h pl ph) (sym pl))
99   (lemma-map-lookupM-assoc i x h h' ph js pj)
100
101 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → VecISetoid (MaybeSetoid A.setoid) at _ ∋ map (flip lookupM h) is ≈ map just v
102 lemma-2 []       []       h p = ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))
103 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
104 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
105 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
106   lookupM i h ∷ map (flip lookupM h) is
107     ≈⟨ lemma-lookupM-assoc i is x xs h (trans (cong (flip _>>=_ (checkInsert i x)) ir) p) VecEq.∷-cong ISetoid.refl (VecISetoid (MaybeSetoid A.setoid)) ⟩
108   just x ∷ map (flip lookupM h) is
109     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h h' p is (lemma-assoc-domain is xs h' ir)) ⟩
110   just x ∷ map (flip lookupM h') is
111     ≈⟨ Setoid.refl (MaybeSetoid A.setoid) VecEq.∷-cong (lemma-2 is xs h' ir) ⟩
112   just x ∷ map just xs ∎
113   where open EqR (VecISetoid (MaybeSetoid A.setoid) at _)
114
115 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
116 lemma-map-denumerate-enumerate []       = refl
117 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
118   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
119     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
120   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
121     ≡⟨ refl ⟩
122   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
123     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
124   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
125     ≡⟨ refl ⟩
126   map (denumerate as) (enumerate as)
127     ≡⟨ lemma-map-denumerate-enumerate as ⟩
128   as ∎)
129   where open ≡-Reasoning
130
131 theorem-1 : (G : Get) → {i : Setoid.Carrier (Get.I G)} → (s : Vec Carrier (to (Get.gl₁ G) ⟨$⟩ i)) → bff G s (Get.get G s) ≡ just s
132 theorem-1 G s = begin
133   bff G s (get s)
134     ≡⟨ cong (bff G s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
135   bff G s (get (map (denumerate s) (enumerate s)))
136     ≡⟨ cong (bff G s) (free-theorem (denumerate s) (enumerate s)) ⟩
137   bff G s (map (denumerate s) (get (enumerate s)))
138     ≡⟨ refl ⟩
139   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
140     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
141   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
142     ≡⟨ refl ⟩
143   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (delete-many (get (enumerate s)) (fromFunc (denumerate s))))
144     ≡⟨ cong (h′↦r ∘ just) (lemma-disjoint-union (denumerate s) (get (enumerate s))) ⟩
145   (h′↦r ∘ just) (fromFunc (denumerate s))
146     ≡⟨ refl ⟩
147   mapMV (flip lookupVec (fromFunc (denumerate s))) (enumerate s)
148     ≡⟨ cong (flip mapMV (enumerate s) ∘ flip lookupVec) (lemma-fromFunc-tabulate (denumerate s)) ⟩
149   mapMV (flip lookupVec (tabulate (Maybe.just ∘ denumerate s))) (enumerate s)
150     ≡⟨ mapMV-cong (lookup∘tabulate (Maybe.just ∘ denumerate s)) (enumerate s) ⟩
151   mapMV (Maybe.just ∘ denumerate s) (enumerate s)
152     ≡⟨ mapMV-purity (denumerate s) (enumerate s) ⟩
153   just (map (denumerate s) (enumerate s))
154     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
155   just s ∎
156     where open ≡-Reasoning
157           open Get G
158           h↦h′ = _<$>_ (flip union (delete-many (get (enumerate s)) (fromFunc (denumerate s))))
159           h′↦r = flip _>>=_ (flip mapMV (enumerate s) ∘ flip lookupVec)
160
161
162 lemma-<$>-just : {A B : Set} {f : A → B} {b : B} (ma : Maybe A) → f <$> ma ≡ just b → ∃ λ a → ma ≡ just a
163 lemma-<$>-just (just x) f<$>ma≡just-b = x , refl
164 lemma-<$>-just nothing  ()
165
166 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMapMaybe n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map (flip lookupM (union h h')) is ≡ map (flip lookupM h) is
167 lemma-union-not-used h h' []        p = refl
168 lemma-union-not-used h h' (i ∷ is') (Data.List.All._∷_ (x , px) p') = cong₂ _∷_ (begin
169       lookupM i (union h h')
170         ≡⟨ lookup∘tabulate (λ j → maybe′ just (lookupM j h') (lookupM j h)) i ⟩
171       maybe′ just (lookupM i h') (lookupM i h)
172         ≡⟨ cong (maybe′ just (lookupM i h')) px ⟩
173       maybe′ just (lookupM i h') (just x)
174         ≡⟨ sym px ⟩
175       lookupM i h ∎)
176   (lemma-union-not-used h h' is' p')
177   where open ≡-Reasoning
178
179 lemma->>=-just : {A B : Set} (ma : Maybe A) {f : A → Maybe B} {b : B} → (ma >>= f) ≡ just b → ∃ λ a → ma ≡ just a
180 lemma->>=-just (just a) p = a , refl
181 lemma->>=-just nothing  ()
182
183 lemma-just-sequence : {A : Set} {n : ℕ} → (v : Vec A n) → sequenceV (map just v) ≡ just v
184 lemma-just-sequence [] = refl
185 lemma-just-sequence (x ∷ xs) rewrite lemma-just-sequence xs = refl
186
187 lemma-mapM-successful : {A B : Set} {f : A → Maybe B} {n : ℕ} → (v : Vec A n) → {r : Vec B n} → mapMV f v ≡ just r → ∃ λ w → map f v ≡ map just w
188 lemma-mapM-successful         []      p = [] , refl
189 lemma-mapM-successful {f = f} (x ∷ xs) p with f x | mapMV f xs | inspect (mapMV f) xs
190 lemma-mapM-successful         (x ∷ xs) () | nothing | _ | _
191 lemma-mapM-successful         (x ∷ xs) () | just y | nothing | _
192 lemma-mapM-successful         (x ∷ xs) p  | just y | just ys | [ p′ ] with lemma-mapM-successful xs p′
193 lemma-mapM-successful         (x ∷ xs) p  | just y | just ys | [ p′ ] | w , pw = y ∷ w , cong (_∷_ (just y)) pw
194
195 lemma-get-mapMV : {A B : Set} {f : A → Maybe B} → (G : Get) → {i : Setoid.Carrier (Get.I G)} {v : Vec A (to (Get.gl₁ G) ⟨$⟩ i)} {r : Vec B (to (Get.gl₁ G) ⟨$⟩ i)} → mapMV f v ≡ just r → Get.get G <$> mapMV f v ≡ mapMV f (Get.get G v)
196 lemma-get-mapMV {f = f} G {v = v} p = let w , pw = lemma-mapM-successful v p in begin
197   get <$> mapMV f v
198     ≡⟨ cong (_<$>_ get) (sym (sequence-map f v)) ⟩
199   get <$> (sequenceV (map f v))
200     ≡⟨ cong (_<$>_ get ∘ sequenceV) pw ⟩
201   get <$> (sequenceV (map just w))
202     ≡⟨ cong (_<$>_ get) (lemma-just-sequence w) ⟩
203   get <$> just w
204     ≡⟨ sym (lemma-just-sequence (get w)) ⟩
205   sequenceV (map just (get w))
206     ≡⟨ cong sequenceV (sym (free-theorem just w)) ⟩
207   sequenceV (get (map just w))
208     ≡⟨ cong (sequenceV ∘ get) (sym pw) ⟩
209   sequenceV (get (map f v))
210     ≡⟨ cong sequenceV (free-theorem f v) ⟩
211   sequenceV (map f (get v))
212     ≡⟨ sequence-map f (get v) ⟩
213   mapMV f (get v) ∎
214   where open ≡-Reasoning
215         open Get G
216
217 sequence-cong : {S : Setoid ℓ₀ ℓ₀} {n : ℕ} {m₁ m₂ : Setoid.Carrier (VecISetoid (MaybeSetoid S) at n)} → VecISetoid (MaybeSetoid S) at _ ∋ m₁ ≈ m₂ → MaybeSetoid (VecISetoid S at n) ∋ sequenceV m₁ ≈ sequenceV m₂
218 sequence-cong {S}                                       VecEq.[]-cong = Setoid.refl (MaybeSetoid (VecISetoid S at _))
219 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (just x≈y VecEq.∷-cong xs≈ys) with sequenceV xs | sequenceV ys | sequence-cong xs≈ys
220 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (just x≈y VecEq.∷-cong xs≈ys) | just sxs | just sys | just p = MaybeEq.just (x≈y VecEq.∷-cong p)
221 sequence-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (just x≈y VecEq.∷-cong xs≈ys) | nothing | nothing | nothing = Setoid.refl (MaybeSetoid (VecISetoid S at _))
222 sequence-cong {S}                                       (nothing VecEq.∷-cong xs≈ys) = Setoid.refl (MaybeSetoid (VecISetoid S at _))
223
224 theorem-2 : (G : Get) → {i : Setoid.Carrier (Get.I G)} → (v : Vec Carrier (Get.gl₂ G ⟨$⟩ i)) → (s u : Vec Carrier (to (Get.gl₁ G) ⟨$⟩ i)) → bff G s v ≡ just u → VecISetoid A.setoid at _ ∋ Get.get G u ≈ v
225 theorem-2 G v s u p with (lemma->>=-just ((flip union (delete-many (Get.get G (enumerate s)) (fromFunc (denumerate s)))) <$> (assoc (Get.get G (enumerate s)) v)) p)
226 theorem-2 G v s u p | h′ , ph′ with (lemma-<$>-just (assoc (Get.get G (enumerate s)) v) ph′)
227 theorem-2 G v s u p | h′ , ph′ | h , ph = drop-just (begin⟨ MaybeSetoid (VecISetoid A.setoid at _) ⟩
228   get <$> (just u)
229     ≡⟨ cong (_<$>_ get) (sym p) ⟩
230   get <$> (bff G s v)
231     ≡⟨ cong (_<$>_ get ∘ flip _>>=_ h′↦r ∘ _<$>_ h↦h′) ph ⟩
232   get <$> mapMV (flip lookupM (h↦h′ h)) s′
233     ≡⟨ lemma-get-mapMV G (trans (cong (flip _>>=_ h′↦r ∘ _<$>_ h↦h′) (sym ph)) p) ⟩
234   mapMV (flip lookupM (h↦h′ h)) (get s′)
235     ≡⟨ sym (sequence-map (flip lookupM (h↦h′ h)) (get s′)) ⟩
236   sequenceV (map (flip lookupM (h↦h′ h)) (get s′))
237     ≡⟨ cong sequenceV (lemma-union-not-used h g′ (get s′) (lemma-assoc-domain (get s′) v h ph)) ⟩
238   sequenceV (map (flip lookupM h) (get s′))
239     ≈⟨ sequence-cong (lemma-2 (get s′) v h ph) ⟩
240   sequenceV (map just v)
241     ≡⟨ lemma-just-sequence v ⟩
242   just v ∎)
243     where open SetoidReasoning
244           open Get G
245           s′   = enumerate s
246           g    = fromFunc (denumerate s)
247           g′   = delete-many (get s′) g
248           h↦h′ = flip union g′
249           h′↦r = flip mapMV s′ ∘ flip lookupM