ce88f1e5f60fcdc7901e2a8b43ccf882037d77c4
[~helmut/bidiragda.git] / Bidir.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module Bidir (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin)
8 import Level
9 import Category.Monad
10 import Category.Functor
11 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′ ; drop-just) renaming (setoid to MaybeSetoid ; Eq to MaybeEq)
12 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
13 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
14 open import Data.List using (List)
15 open import Data.List.All using (All)
16 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; map ; allFin) renaming (lookup to lookupVec)
17 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
18 open import Data.Vec.Properties using (lookup∘tabulate ; lookup∘update ; map-cong ; map-∘ ; map-lookup-allFin)
19 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
20 open import Function using (id ; _∘_ ; flip)
21 open import Relation.Binary.Core using (refl ; _≡_)
22 open import Relation.Binary.Indexed using (_at_) renaming (Setoid to ISetoid)
23 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; trans ; cong₂ ; decSetoid ; module ≡-Reasoning) renaming (setoid to EqSetoid)
24 open import Relation.Binary using (Setoid ; module Setoid ; module DecSetoid)
25 import Relation.Binary.EqReasoning as EqR
26
27 open import Structures using (Functor ; IsFunctor ; Shaped ; module Shaped)
28 open import Instances using (MaybeFunctor ; ShapedISetoid)
29 import GetTypes
30 open GetTypes.PartialShapeShape using (Get ; module Get)
31 open import Generic using (mapMV ; mapMV-cong ; mapMV-purity ; sequenceV ; VecISetoid ; just-injective)
32 open import FinMap
33 import CheckInsert
34 open CheckInsert A
35 import BFF
36 open BFF.PartialShapeBFF A using (assoc ; enumerate ; denumerate ; bff)
37 open Setoid using () renaming (_≈_ to _∋_≈_)
38 open module A = DecSetoid A using (Carrier) renaming (_≟_ to deq)
39
40 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f is)
41 lemma-1 f []        = refl
42 lemma-1 f (i ∷ is′) = begin
43   (assoc is′ (map f is′) >>= checkInsert i (f i))
44     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
45   checkInsert i (f i) (restrict f is′)
46     ≡⟨ lemma-checkInsert-restrict f i is′ ⟩
47   just (restrict f (i ∷ is′)) ∎
48   where open ≡-Reasoning
49
50 lemma-lookupM-checkInserted : {n : ℕ} → (i : Fin n) → (x : Carrier) → (h : FinMapMaybe n Carrier) → {h' : FinMapMaybe n Carrier} → checkInsert i x h ≡ just h' → MaybeSetoid A.setoid ∋ lookupM i h' ≈ just x
51 lemma-lookupM-checkInserted i x h p with checkInsert i x h | insertionresult i x h
52 lemma-lookupM-checkInserted i x h refl | ._ | same x' x≈x' pl = begin
53   lookupM i h
54     ≡⟨ pl ⟩
55   just x'
56     ≈⟨ MaybeEq.just (Setoid.sym A.setoid x≈x') ⟩
57   just x ∎
58   where open EqR (MaybeSetoid A.setoid)
59 lemma-lookupM-checkInserted i x h refl | ._ | new _ = Setoid.reflexive (MaybeSetoid A.setoid) (lookup∘update i h (just x))
60 lemma-lookupM-checkInserted i x h () | ._ | wrong _ _ _
61
62 _in-domain-of_ : {m n : ℕ} {A : Set} → (is : Vec (Fin m) n) → (FinMapMaybe m A) → Set
63 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) (toList is)
64
65 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → {h : FinMapMaybe n Carrier} → assoc is xs ≡ just h → is in-domain-of h
66 lemma-assoc-domain []         []         ph = Data.List.All.[]
67 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ph with assoc is' xs' | inspect (assoc is') xs'
68 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') () | nothing | [ ph' ]
69 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
70 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') refl | just h | [ ph' ] | ._ | _ | same x _ pl = All._∷_ (x , pl) (lemma-assoc-domain is' xs' ph')
71 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
72   (x' , lookup∘update i' h' (just x'))
73   (Data.List.All.map
74     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' h' (proj₂ p) x' cI≡)
75     (lemma-assoc-domain is' xs' ph'))
76 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
77
78 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → {h' : FinMapMaybe m Carrier} → checkInsert i x h ≡ just h' → {n : ℕ} → (js : Vec (Fin m) n) → js in-domain-of h → map (flip lookupM h') js ≡ map (flip lookupM h) js
79 lemma-map-lookupM-assoc i x h ph [] pj = refl
80 lemma-map-lookupM-assoc i x h ph (j ∷ js) (Data.List.All._∷_ (x' , pl) pj) = cong₂ _∷_
81   (trans (lemma-lookupM-checkInsert j i h pl x ph) (sym pl))
82   (lemma-map-lookupM-assoc i x h ph js pj)
83
84 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → VecISetoid (MaybeSetoid A.setoid) at _ ∋ map (flip lookupM h) is ≈ map just v
85 lemma-2 []       []       h p = ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))
86 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
87 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
88 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
89   lookupM i h ∷ map (flip lookupM h) is
90     ≈⟨ VecEq._∷-cong_ (lemma-lookupM-checkInserted i x h' p) (ISetoid.refl (VecISetoid (MaybeSetoid A.setoid))) ⟩
91   just x ∷ map (flip lookupM h) is
92     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h' p is (lemma-assoc-domain is xs ir)) ⟩
93   just x ∷ map (flip lookupM h') is
94     ≈⟨ VecEq._∷-cong_ (Setoid.refl (MaybeSetoid A.setoid)) (lemma-2 is xs h' ir) ⟩
95   just x ∷ map just xs ∎
96   where open EqR (VecISetoid (MaybeSetoid A.setoid) at _)
97
98 lemma-fmap-denumerate-enumerate : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {α : Set} {s : S} → (c : C α s) → Shaped.fmap ShapeT (denumerate ShapeT c) (enumerate ShapeT s) ≡ c
99 lemma-fmap-denumerate-enumerate {S} {C} ShapeT {s = s} c = begin
100   fmap (denumerate ShapeT c) (fill s (allFin (arity s)))
101     ≡⟨ fill-fmap (denumerate ShapeT c) s (allFin (arity s)) ⟩
102   fill s (map (flip lookupVec (content c)) (allFin (arity s)))
103     ≡⟨ cong (fill s) (map-lookup-allFin (content c)) ⟩
104   fill s (content c)
105     ≡⟨ content-fill c ⟩
106   c ∎
107   where open ≡-Reasoning
108         open Shaped ShapeT
109
110
111 theorem-1 : (G : Get) → {i : Get.I G} → (s : Get.SourceContainer G Carrier (Get.gl₁ G i)) → bff G i s (Get.get G s) ≡ just (Get.fmapS G just s)
112 theorem-1 G {i} s = begin
113   bff G i s (get s)
114     ≡⟨ cong (bff G i s ∘ get) (sym (lemma-fmap-denumerate-enumerate SourceShapeT s)) ⟩
115   bff G i s (get (fmapS f t))
116     ≡⟨ cong (bff G i s) (free-theorem f t) ⟩
117   bff G i s (fmapV f (get t))
118     ≡⟨ refl ⟩
119   h′↦r <$> (h↦h′ <$> (assoc (Shaped.content ViewShapeT (get t)) (Shaped.content ViewShapeT (fmapV f (get t)))))
120     ≡⟨ cong (_<$>_ h′↦r ∘ _<$>_ h↦h′ ∘ assoc (Shaped.content ViewShapeT (get t))) (Shaped.fmap-content ViewShapeT f (get t)) ⟩
121   h′↦r <$> (h↦h′ <$> (assoc (Shaped.content ViewShapeT (get t)) (map f (Shaped.content ViewShapeT (get t)))))
122     ≡⟨ cong (_<$>_ h′↦r ∘ _<$>_ h↦h′) (lemma-1 f (Shaped.content ViewShapeT (get t))) ⟩
123   (Maybe.just ∘ h′↦r ∘ h↦h′) (restrict f (Shaped.content ViewShapeT (get t)))
124     ≡⟨ cong just (begin
125       h′↦r (union (restrict f (Shaped.content ViewShapeT (get t))) (reshape g′ (Shaped.arity SourceShapeT (gl₁ i))))
126         ≡⟨ cong (h′↦r ∘ union (restrict f (Shaped.content ViewShapeT (get t)))) (lemma-reshape-id g′) ⟩
127       h′↦r (union (restrict f (Shaped.content ViewShapeT (get t))) g′)
128         ≡⟨ cong h′↦r (lemma-disjoint-union f (Shaped.content ViewShapeT (get t))) ⟩
129       h′↦r (fromFunc f)
130         ≡⟨ refl ⟩
131       fmapS (flip lookupM (fromFunc f)) t
132         ≡⟨ IsFunctor.cong (Shaped.isFunctor SourceShapeT (gl₁ i)) (lemma-lookupM-fromFunc f) t ⟩
133       fmapS (Maybe.just ∘ f) t
134         ≡⟨ IsFunctor.composition (Shaped.isFunctor SourceShapeT (gl₁ i)) just f t ⟩
135       fmapS just (fmapS f t)
136         ≡⟨ cong (fmapS just) (lemma-fmap-denumerate-enumerate SourceShapeT s) ⟩
137       fmapS just s ∎) ⟩ _ ∎
138     where open ≡-Reasoning
139           open Get G
140           t    = enumerate SourceShapeT (gl₁ i)
141           f    = denumerate SourceShapeT s
142           g′   = delete-many (Shaped.content ViewShapeT (get t)) (fromFunc f)
143           h↦h′ = flip union (reshape g′ (Shaped.arity SourceShapeT (gl₁ i)))
144           h′↦r = (λ f′ → fmapS f′ t) ∘ flip lookupM
145
146
147 lemma-<$>-just : {A B : Set} {f : A → B} {b : B} (ma : Maybe A) → (f <$> ma) ≡ just b → ∃ λ a → ma ≡ just a
148 lemma-<$>-just (just x) f<$>ma≡just-b = x , refl
149 lemma-<$>-just nothing  ()
150
151 lemma-union-not-used : {n : ℕ} → {A : Set} → (h h′ : FinMapMaybe n A) → (i : Fin n) → ∃ (λ x → lookupM i h ≡ just x) → lookupM i (union h h′) ≡ lookupM i h
152 lemma-union-not-used h h′ i (x , px) = begin
153   lookupM i (union h h′)
154     ≡⟨ lookup∘tabulate (λ j → maybe′ just (lookupM j h′) (lookupM j h)) i ⟩
155   maybe′ just (lookupM i h′) (lookupM i h)
156     ≡⟨ cong (maybe′ just (lookupM i h′)) px ⟩
157   maybe′ just (lookupM i h′) (just x)
158     ≡⟨ sym px ⟩
159   lookupM i h ∎
160   where open ≡-Reasoning
161
162 lemma->>=-just : {A B : Set} (ma : Maybe A) {f : A → Maybe B} {b : B} → (ma >>= f) ≡ just b → ∃ λ a → ma ≡ just a
163 lemma->>=-just (just a) p = a , refl
164 lemma->>=-just nothing  ()
165
166 lemma-just-sequenceV : {A : Set} {n : ℕ} → (v : Vec A n) → sequenceV (map just v) ≡ just v
167 lemma-just-sequenceV []       = refl
168 lemma-just-sequenceV (x ∷ xs) = cong (_<$>_ (_∷_ x)) (lemma-just-sequenceV xs)
169
170 lemma-just-sequence : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {A : Set} {s : S} → (c : C A s) → Shaped.sequence ShapeT (Shaped.fmap ShapeT just c) ≡ just c
171 lemma-just-sequence ShapeT {s = s} c = begin
172   fill s <$> sequenceV (content (fmap just c))
173     ≡⟨ cong (_<$>_ (fill s) ∘ sequenceV) (fmap-content just c) ⟩
174   fill s <$> sequenceV (map just (content c))
175     ≡⟨ cong (_<$>_ (fill s)) (lemma-just-sequenceV (content c)) ⟩
176   fill s <$> just (content c)
177     ≡⟨ cong just (content-fill c) ⟩
178   just c ∎
179   where open ≡-Reasoning
180         open Shaped ShapeT
181
182 lemma-sequenceV-successful : {A : Set} {n : ℕ} → (v : Vec (Maybe A) n) → {r : Vec A n} → sequenceV v ≡ just r → v ≡ map just r
183 lemma-sequenceV-successful []             {r = []}       p = refl
184 lemma-sequenceV-successful (just x ∷ xs)                 p with sequenceV xs | inspect sequenceV xs
185 lemma-sequenceV-successful (just x ∷ xs)                 () | nothing | _
186 lemma-sequenceV-successful (just x ∷ xs)  {r = .x ∷ .ys} refl  | just ys | [ p′ ] = cong (_∷_ (just x)) (lemma-sequenceV-successful xs p′)
187 lemma-sequenceV-successful (nothing ∷ xs)                ()
188
189 lemma-sequence-successful : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → {A : Set} {s : S} → (c : C (Maybe A) s) → {r : C A s} → Shaped.sequence ShapeT c ≡ just r → c ≡ Shaped.fmap ShapeT just r
190 lemma-sequence-successful ShapeT {s = s} c {r} p = just-injective (sym (begin
191   fill s <$> (map just <$> (content <$> just r))
192     ≡⟨ cong (_<$>_ (fill s) ∘ _<$>_ (map just)) (begin
193       content <$> just r
194         ≡⟨ cong (_<$>_ content) (sym p) ⟩
195       content <$> (fill s <$> sequenceV (content c))
196         ≡⟨ sym (Functor.composition MaybeFunctor content (fill s) (sequenceV (content c))) ⟩
197       content ∘ fill s <$> sequenceV (content c)
198         ≡⟨ Functor.cong MaybeFunctor (fill-content s) (sequenceV (content c)) ⟩
199       id <$> sequenceV (content c)
200         ≡⟨ Functor.identity MaybeFunctor (sequenceV (content c)) ⟩
201       sequenceV (content c)
202         ≡⟨ cong sequenceV (lemma-sequenceV-successful (content c) (proj₂ wp)) ⟩
203       sequenceV (map just (proj₁ wp))
204         ≡⟨ lemma-just-sequenceV (proj₁ wp) ⟩
205       just (proj₁ (lemma-<$>-just (sequenceV (content c)) p)) ∎) ⟩
206   fill s <$> (map just <$> just (proj₁ (lemma-<$>-just (sequenceV (content c)) p)))
207     ≡⟨ cong (_<$>_ (fill s) ∘ just) (sym (lemma-sequenceV-successful (content c) (proj₂ wp))) ⟩
208   fill s <$> just (content c)
209     ≡⟨ cong just (content-fill c) ⟩
210   just c ∎))
211   where open ≡-Reasoning
212         open Shaped ShapeT
213         wp = lemma-<$>-just (sequenceV (content c)) p
214
215 module _ (G : Get) where
216   open ≡-Reasoning
217   open Get G
218   open Shaped SourceShapeT using () renaming (sequence to sequenceSource)
219   open Shaped ViewShapeT using () renaming (sequence to sequenceView)
220
221   lemma-get-sequence : {A : Set} → {i : I} {v : SourceContainer (Maybe A) (gl₁ i)} {r : SourceContainer A (gl₁ i)} → sequenceSource v ≡ just r → (get <$> sequenceSource v) ≡ sequenceView (get v)
222   lemma-get-sequence {v = v} {r = r} p = begin
223     get <$> sequenceSource v
224       ≡⟨ cong (_<$>_ get ∘ sequenceSource) (lemma-sequence-successful SourceShapeT v p) ⟩
225     get <$> sequenceSource (fmapS just r)
226       ≡⟨ cong (_<$>_ get) (lemma-just-sequence SourceShapeT r) ⟩
227     get <$> just r
228       ≡⟨ sym (lemma-just-sequence ViewShapeT (get r)) ⟩
229     sequenceView (fmapV just (get r))
230       ≡⟨ cong sequenceView (sym (free-theorem just r)) ⟩
231     sequenceView (get (fmapS just r))
232       ≡⟨ cong (sequenceView ∘ get) (sym (lemma-sequence-successful SourceShapeT v p)) ⟩
233     sequenceView (get v) ∎
234
235 sequenceV-cong : {S : Setoid ℓ₀ ℓ₀} {n : ℕ} {m₁ m₂ : Setoid.Carrier (VecISetoid (MaybeSetoid S) at n)} → VecISetoid (MaybeSetoid S) at _ ∋ m₁ ≈ m₂ → MaybeSetoid (VecISetoid S at n) ∋ sequenceV m₁ ≈ sequenceV m₂
236 sequenceV-cong {S}                                       VecEq.[]-cong = Setoid.refl (MaybeSetoid (VecISetoid S at _))
237 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) with sequenceV xs | sequenceV ys | sequenceV-cong xs≈ys
238 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | just sys | just p = MaybeEq.just (VecEq._∷-cong_ x≈y p)
239 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | just sys | ()
240 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | just sxs | nothing | ()
241 sequenceV-cong {S} {m₁ = just x ∷ xs} {m₂ = just y ∷ ys} (VecEq._∷-cong_ (just x≈y) xs≈ys) | nothing | nothing | nothing = Setoid.refl (MaybeSetoid (VecISetoid S at _))
242 sequenceV-cong {S}                                       (VecEq._∷-cong_ nothing xs≈ys) = Setoid.refl (MaybeSetoid (VecISetoid S at _))
243
244 sequence-cong : {S : Set} {C : Set → S → Set} → (ShapeT : Shaped S C) → (α : Setoid ℓ₀ ℓ₀) → {s : S} {x y : C (Maybe (Setoid.Carrier α)) s} → ShapedISetoid (EqSetoid S) ShapeT (MaybeSetoid α) at _ ∋ x ≈ y → MaybeSetoid (ShapedISetoid (EqSetoid S) ShapeT α at _) ∋ Shaped.sequence ShapeT x ≈ Shaped.sequence ShapeT y
245 sequence-cong ShapeT α {x = x} {y = y} (shape≈ , content≈) with sequenceV (Shaped.content ShapeT x) | sequenceV (Shaped.content ShapeT y) | sequenceV-cong content≈
246 sequence-cong ShapeT α {s} (shape≈ , content≈) | .(just x) | .(just y) | just {x} {y} x≈y = just (refl , (begin
247   content (fill s x)
248     ≡⟨ fill-content s x ⟩
249   x
250     ≈⟨ x≈y ⟩
251   y
252     ≡⟨ sym (fill-content s y) ⟩
253   content (fill s y) ∎))
254   where open EqR (VecISetoid α at _)
255         open Shaped ShapeT
256 sequence-cong ShapeT α (shape≈ , content≈) | .nothing  | .nothing  | nothing = nothing
257
258 module _ (G : Get) where
259   open Get G
260   open Shaped SourceShapeT using () renaming (arity to arityS)
261   open Shaped ViewShapeT using () renaming (content to contentV)
262
263   theorem-2 : {i : I} → (j : I) → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ j)) → (u : SourceContainer (Maybe Carrier) (gl₁ j)) → bff G j s v ≡ just u → ShapedISetoid (EqSetoid _) ViewShapeT (MaybeSetoid A.setoid) at _ ∋ get u ≈ Get.fmapV G just v
264   theorem-2 {i} j s v u p with lemma-<$>-just ((flip union (reshape (delete-many (contentV (get (enumerate SourceShapeT (gl₁ i)))) (fromFunc (denumerate SourceShapeT s))) (arityS (gl₁ j)))) <$> assoc (contentV (get (enumerate SourceShapeT (gl₁ j)))) (contentV v)) p
265   theorem-2 {i} j s v u p | h′ , ph′ with lemma-<$>-just (assoc (contentV (get (enumerate SourceShapeT (gl₁ j)))) (contentV v)) ph′
266   theorem-2 {i} j s v u p | h′ , ph′ | h , ph = refl , (begin
267     contentV (get u)
268       ≡⟨ cong contentV (just-injective (trans (cong (_<$>_ get) (sym p))
269                                               (cong (_<$>_ get ∘ _<$>_ h′↦r ∘ _<$>_ h↦h′) ph))) ⟩
270     contentV (get (h′↦r (h↦h′ h)))
271       ≡⟨ refl ⟩
272     contentV (get (fmapS (flip lookupM (h↦h′ h)) t))
273       ≡⟨ cong contentV (free-theorem (flip lookupM (h↦h′ h)) t) ⟩
274     contentV (fmapV (flip lookupM (h↦h′ h)) (get t))
275       ≡⟨ Shaped.fmap-content ViewShapeT (flip lookupM (h↦h′ h)) (get t) ⟩
276     map (flip lookupM (h↦h′ h)) (contentV (get t))
277       ≡⟨ lemma-exchange-maps (lemma-union-not-used h (reshape g′ (arityS (gl₁ j)))) (lemma-assoc-domain (contentV (get t)) (contentV v) ph) ⟩
278     map (flip lookupM h) (contentV (get t))
279       ≈⟨ lemma-2 (contentV (get t)) (contentV v) h ph ⟩
280     map just (contentV v)
281       ≡⟨ sym (Shaped.fmap-content ViewShapeT just v) ⟩
282     contentV (fmapV just v) ∎)
283       where open EqR (VecISetoid (MaybeSetoid A.setoid) at _)
284             s′   = enumerate SourceShapeT (gl₁ i)
285             g    = fromFunc (denumerate SourceShapeT s)
286             g′   = delete-many (contentV (get s′)) g
287             t    = enumerate SourceShapeT (gl₁ j)
288             h↦h′ = flip union (reshape g′ (arityS (gl₁ j)))
289             h′↦r = (λ f → fmapS f t) ∘ flip lookupM
290
291 module _ (G : Get) where
292   open Get G
293
294   theorem-2′ : {i : I} → (j : I) → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ j)) → (u : SourceContainer Carrier (gl₁ j)) → bff G j s v ≡ just (Get.fmapS G just u) → ShapedISetoid (EqSetoid _) ViewShapeT A.setoid at _ ∋ get u ≈ v
295   theorem-2′ j s v u p = drop-just (begin
296     get <$> just u
297       ≡⟨ cong (_<$>_ get) (sym (lemma-just-sequence SourceShapeT u)) ⟩
298     get <$> Shaped.sequence SourceShapeT (fmapS just u)
299       ≡⟨ lemma-get-sequence G (lemma-just-sequence SourceShapeT u) ⟩
300     Shaped.sequence ViewShapeT (get (fmapS just u))
301       ≈⟨ sequence-cong ViewShapeT A.setoid (theorem-2 G j s v (fmapS just u) p) ⟩
302     Shaped.sequence ViewShapeT (fmapV just v)
303       ≡⟨ lemma-just-sequence ViewShapeT v ⟩
304     just v ∎)
305     where open EqR (MaybeSetoid (ShapedISetoid (EqSetoid _) ViewShapeT A.setoid at _))