shrink base case of lemma-/notin-lookupM-assoc
[~helmut/bidiragda.git] / Bidir.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Bidir (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
9 open import Data.List using (List)
10 open import Data.List.Any using (Any ; any ; here ; there)
11 open import Data.List.All using (All)
12 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
13 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; fromList ; map ; tabulate) renaming (lookup to lookupVec)
14 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
15 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
16 open import Data.Empty using (⊥-elim)
17 open import Function using (id ; _∘_ ; flip)
18 open import Relation.Nullary using (yes ; no)
19 open import Relation.Binary.Core using (refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; _≗_ ; trans)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 import FreeTheorems
24 open FreeTheorems.VecVec using (get-type ; free-theorem)
25 open import FinMap
26 import CheckInsert
27 open CheckInsert Carrier deq
28 open import BFF using (_>>=_ ; fmap)
29 open BFF.VecBFF Carrier deq using (assoc ; enumerate ; denumerate ; bff)
30
31 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
32 lemma-1 f []        = refl
33 lemma-1 f (i ∷ is′) = begin
34   assoc is′ (map f is′) >>= checkInsert i (f i)
35     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
36   checkInsert i (f i) (restrict f (toList is′))
37     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
38   just (restrict f (toList (i ∷ is′))) ∎
39
40 lemma-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
41 lemma-lookupM-assoc i is x xs h    p with assoc is xs
42 lemma-lookupM-assoc i is x xs h    () | nothing
43 lemma-lookupM-assoc i is x xs h    p | just h' = apply-checkInsertProof i x h' record
44   { same  = λ lookupM≡justx → begin
45       lookupM i h
46         ≡⟨ cong (lookupM i) (just-injective (trans (sym p) (lemma-checkInsert-same i x h' lookupM≡justx))) ⟩
47       lookupM i h'
48         ≡⟨ lookupM≡justx ⟩
49       just x ∎
50   ; new   = λ lookupM≡nothing → begin
51       lookupM i h
52         ≡⟨ cong (lookupM i) (just-injective (trans (sym p) (lemma-checkInsert-new i x h' lookupM≡nothing))) ⟩
53       lookupM i (insert i x h')
54         ≡⟨ lemma-lookupM-insert i x h' ⟩
55       just x ∎
56   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing (trans (sym p) (lemma-checkInsert-wrong i x h' x' x≢x' lookupM≡justx'))
57   }
58
59 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
60 lemma-∉-lookupM-assoc i []         []         .empty refl i∉is = lemma-lookupM-empty i
61 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
62 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
63 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = apply-checkInsertProof i' x' h' record {
64     same = λ lookupM-i'-h'≡just-x' → begin
65       lookupM i h
66         ≡⟨ cong (lookupM i) (just-injective (trans (sym ph) (lemma-checkInsert-same i' x' h' lookupM-i'-h'≡just-x'))) ⟩
67       lookupM i h'
68         ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
69       nothing ∎
70   ; new = λ lookupM-i'-h'≡nothing → begin
71       lookupM i h
72         ≡⟨ cong (lookupM i)  (just-injective (trans (sym ph) (lemma-checkInsert-new i' x' h' lookupM-i'-h'≡nothing))) ⟩
73       lookupM i (insert i' x' h')
74         ≡⟨ sym (lemma-lookupM-insert-other i i' x' h' (i∉is ∘ here)) ⟩
75       lookupM i h'
76         ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
77       nothing ∎
78   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
79   }
80
81 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
82 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
83
84 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
85 lemma-assoc-domain []         []         h ph = Data.List.All.[]
86 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
87 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
88 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] = apply-checkInsertProof i' x' h' record {
89     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
90       (x' , (trans (cong (lookupM i') (just-injective (trans (sym ph) (lemma-checkInsert-same i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
91       (lemma-assoc-domain is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same i' x' h' lookupM-i'-h'≡just-x')) ph)))
92   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
93       (x' , (trans (cong (lookupM i') (just-injective (trans (sym ph) (lemma-checkInsert-new i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
94       (Data.List.All.map
95         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' h (proj₂ p) ph)
96         (lemma-assoc-domain is' xs' h' ph'))
97   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
98   }
99
100 lemma-map-lookupM-insert : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (h : FinMapMaybe n Carrier) → i ∉ (toList is) → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
101 lemma-map-lookupM-insert i []         x h i∉is = refl
102 lemma-map-lookupM-insert i (i' ∷ is') x h i∉is = begin
103   lookupM i' (insert i x h) ∷ map (flip lookupM (insert i x h)) is'
104     ≡⟨ cong (flip _∷_ (map (flip lookupM (insert i x h)) is')) (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym))) ⟩
105   lookupM i' h ∷ map (flip lookupM (insert i x h)) is'
106     ≡⟨ cong (_∷_ (lookupM i' h)) (lemma-map-lookupM-insert i is' x h (i∉is ∘ there)) ⟩
107   lookupM i' h ∷ map (flip lookupM h) is' ∎
108
109 lemma-map-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → (h' : FinMapMaybe n Carrier) → assoc is xs ≡ just h' → checkInsert i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
110 lemma-map-lookupM-assoc i is x xs h h' ph' ph with any (_≟_ i) (toList is)
111 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain is xs h' ph') p
112 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
113 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p | (x'' , refl) | .(just x'') with deq x x''
114 lemma-map-lookupM-assoc i is x xs h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
115 lemma-map-lookupM-assoc i is x xs h h' ph' () | yes p | (x'' , refl) | .(just x'') | no p
116 lemma-map-lookupM-assoc i is x xs h h' ph' ph | no ¬p rewrite lemma-∉-lookupM-assoc i is xs h' ph' ¬p = begin
117   map (flip lookupM h) is
118     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (just-injective (sym ph))) is ⟩
119   map (flip lookupM (insert i x h')) is
120     ≡⟨ lemma-map-lookupM-insert i is x h' ¬p ⟩
121   map (flip lookupM h') is ∎
122
123 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → map (flip lookupM h) is ≡ map just v
124 lemma-2 []       []       h p = refl
125 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
126 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
127 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
128   lookupM i h ∷ map (flip lookupM h) is
129     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc i is x xs h (begin
130       assoc (i ∷ is) (x ∷ xs)
131         ≡⟨ cong (flip _>>=_ (checkInsert i x)) ir ⟩
132       checkInsert i x h'
133         ≡⟨ p ⟩
134       just h ∎) ) ⟩
135   just x ∷ map (flip lookupM h) is
136     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i is x xs h h' ir p) ⟩
137   just x ∷ map (flip lookupM h') is
138     ≡⟨ cong (_∷_ (just x)) (lemma-2 is xs h' ir) ⟩
139   just x ∷ map just xs ∎
140
141 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
142 lemma-map-denumerate-enumerate []       = refl
143 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
144   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
145     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
146   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
147     ≡⟨ refl ⟩
148   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
149     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
150   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
151     ≡⟨ refl ⟩
152   map (denumerate as) (enumerate as)
153     ≡⟨ lemma-map-denumerate-enumerate as ⟩
154   as ∎)
155
156 theorem-1 : {getlen : ℕ → ℕ} → (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → bff get s (get s) ≡ just s
157 theorem-1 get s = begin
158   bff get s (get s)
159     ≡⟨ cong (bff get s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
160   bff get s (get (map (denumerate s) (enumerate s)))
161     ≡⟨ cong (bff get s) (free-theorem get (denumerate s) (enumerate s)) ⟩
162   bff get s (map (denumerate s) (get (enumerate s)))
163     ≡⟨ refl ⟩
164   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
165     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
166   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
167     ≡⟨ refl ⟩
168   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (fromFunc (denumerate s)))
169     ≡⟨ cong (h′↦r ∘ just) (lemma-union-restrict (denumerate s) (toList (get (enumerate s)))) ⟩
170   (h′↦r ∘ just) (fromFunc (denumerate s))
171     ≡⟨ refl ⟩
172   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
173     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
174   just (map (denumerate s) (enumerate s))
175     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
176   just s ∎
177     where h↦h′ = fmap (flip union (fromFunc (denumerate s)))
178           h′↦r = fmap (flip map (enumerate s) ∘ flip lookupVec)
179
180 lemma-fmap-just : {A B : Set} {f : A → B} {b : B} {ma : Maybe A} → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
181 lemma-fmap-just {ma = just x}  fmap-f-ma≡just-b = x , refl
182 lemma-fmap-just {ma = nothing} ()
183
184 ∷-injective : {A : Set} {n : ℕ} {x y : A} {xs ys : Vec A n} → (x ∷ xs) ≡ (y ∷ ys) → x ≡ y × xs ≡ ys
185 ∷-injective refl = refl , refl
186
187 map-just-injective : {A : Set} {n : ℕ} {xs ys : Vec A n} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
188 map-just-injective {xs = []}      {ys = []}       p  = refl
189 map-just-injective {xs = x ∷ xs'} {ys = y ∷ ys'}  p with ∷-injective p
190 map-just-injective {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (map-just-injective p')
191
192 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
193 lemma-union-not-used h h' []        p = refl
194 lemma-union-not-used h h' (i ∷ is') p with Data.List.All.head p
195 lemma-union-not-used h h' (i ∷ is') p | x , lookupM-i-h≡just-x = begin
196   just (lookup i (union h h')) ∷ map just (map (flip lookup (union h h')) is')
197     ≡⟨ cong (flip _∷_ (map just (map (flip lookup (union h h')) is'))) (begin
198       just (lookup i (union h h'))
199         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
200       just (maybe′ id (lookup i h') (lookupM i h))
201         ≡⟨ cong just (cong (maybe′ id (lookup i h')) lookupM-i-h≡just-x) ⟩
202       just (maybe′ id (lookup i h') (just x))
203         ≡⟨ refl ⟩
204       just x
205         ≡⟨ sym lookupM-i-h≡just-x ⟩
206       lookupM i h ∎) ⟩
207   lookupM i h ∷ map just (map (flip lookup (union h h')) is')
208     ≡⟨ cong (_∷_ (lookupM i h)) (lemma-union-not-used h h' is' (Data.List.All.tail p)) ⟩
209   lookupM i h ∷ map (flip lookupM h) is' ∎
210
211 theorem-2 : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (v : Vec Carrier (getlen m)) → (s u : Vec Carrier m) → bff get s v ≡ just u → get u ≡ v
212 theorem-2 get v s u p with lemma-fmap-just (proj₂ (lemma-fmap-just p))
213 theorem-2 get v s u p | h , ph = begin
214   get u
215     ≡⟨ just-injective (begin
216       fmap get (just u)
217         ≡⟨ cong (fmap get) (sym p) ⟩
218       fmap get (bff get s v)
219         ≡⟨ cong (fmap get ∘ fmap h′↦r ∘ fmap h↦h′) ph ⟩
220       fmap get (fmap h′↦r (fmap h↦h′ (just h))) ∎) ⟩
221   get (map (flip lookup (h↦h′ h)) s′)
222     ≡⟨ free-theorem get (flip lookup (h↦h′ h)) s′ ⟩
223   map (flip lookup (h↦h′ h)) (get s′)
224      ≡⟨ map-just-injective (begin
225        map just (map (flip lookup (union h g)) (get s′))
226          ≡⟨ lemma-union-not-used h g (get s′) (lemma-assoc-domain (get s′) v h ph) ⟩
227        map (flip lookupM h) (get s′)
228          ≡⟨ lemma-2 (get s′) v h ph ⟩
229        map just v
230          ∎) ⟩
231   v ∎
232     where s′   = enumerate s
233           g    = fromFunc (denumerate s)
234           h↦h′ = flip union g
235           h′↦r = flip map s′ ∘ flip lookupVec