move definition of get-type to BFF and use it everywhere
[~helmut/bidiragda.git] / Bidir.agda
1 module Bidir where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Data.Fin.Props using (_≟_)
6 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
7 open import Data.List using (List)
8 open import Data.List.Any using (Any ; any ; here ; there)
9 open import Data.List.All using (All)
10 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
11 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; fromList ; map ; tabulate) renaming (lookup to lookupVec)
12 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
13 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
14 open import Data.Empty using (⊥-elim)
15 open import Function using (id ; _∘_ ; flip)
16 open import Relation.Nullary using (yes ; no)
17 open import Relation.Nullary.Negation using (contradiction)
18 open import Relation.Binary.Core using (_≡_ ; refl)
19 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; _≗_ ; trans)
20 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
21
22 open import FinMap
23 open import CheckInsert
24
25 open import BFF using (_>>=_ ; fmap)
26
27 open BFF.VecBFF using (get-type ; assoc ; enumerate ; denumerate ; bff)
28
29 lemma-1 : {τ : Set} {m n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (is : Vec (Fin n) m) → assoc eq is (map f is) ≡ just (restrict f (toList is))
30 lemma-1 eq f []        = refl
31 lemma-1 eq f (i ∷ is′) = begin
32   assoc eq (i ∷ is′) (map f (i ∷ is′))
33     ≡⟨ refl ⟩
34   assoc eq is′ (map f is′) >>= checkInsert eq i (f i)
35     ≡⟨ cong (λ m → m >>= checkInsert eq i (f i)) (lemma-1 eq f is′) ⟩
36   just (restrict f (toList is′)) >>= (checkInsert eq i (f i))
37     ≡⟨ refl ⟩
38   checkInsert eq i (f i) (restrict f (toList is′))
39     ≡⟨ lemma-checkInsert-restrict eq f i (toList is′) ⟩
40   just (restrict f (toList (i ∷ is′))) ∎
41
42 lemma-lookupM-assoc : {A : Set} {m n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : Vec (Fin n) m) → (x : A) → (xs : Vec A m) → (h : FinMapMaybe n A) → assoc eq (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
43 lemma-lookupM-assoc eq i is x xs h    p with assoc eq is xs
44 lemma-lookupM-assoc eq i is x xs h    () | nothing
45 lemma-lookupM-assoc eq i is x xs h    p | just h' = apply-checkInsertProof eq i x h' record
46   { same  = λ lookupM≡justx → begin
47       lookupM i h
48         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-same eq i x h' lookupM≡justx))) ⟩
49       lookupM i h'
50         ≡⟨ lookupM≡justx ⟩
51       just x ∎
52   ; new   = λ lookupM≡nothing → begin
53       lookupM i h
54         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-new eq i x h' lookupM≡nothing))) ⟩
55       lookupM i (insert i x h')
56         ≡⟨ lemma-lookupM-insert i x h' ⟩
57       just x ∎
58   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing (trans (sym p) (lemma-checkInsert-wrong eq i x h' x' x≢x' lookupM≡justx'))
59   }
60
61 lemma-∉-lookupM-assoc : {A : Set} {m n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec A m) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
62 lemma-∉-lookupM-assoc eq i []         []         h ph i∉is = begin
63   lookupM i h
64     ≡⟨ cong (lookupM i) (sym (lemma-from-just ph)) ⟩
65   lookupM i empty
66     ≡⟨ lemma-lookupM-empty i ⟩
67   nothing ∎
68 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc eq is' xs' | inspect (assoc eq is') xs'
69 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
70 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = apply-checkInsertProof eq i' x' h' record {
71     same = λ lookupM-i'-h'≡just-x' → begin
72       lookupM i h
73         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x'))) ⟩
74       lookupM i h'
75         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
76       nothing ∎
77   ; new = λ lookupM-i'-h'≡nothing → begin
78       lookupM i h
79         ≡⟨ cong (lookupM i)  (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing))) ⟩
80       lookupM i (insert i' x' h')
81         ≡⟨ sym (lemma-lookupM-insert-other i i' x' h' (i∉is ∘ here)) ⟩
82       lookupM i h'
83         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
84       nothing ∎
85   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
86   }
87
88 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
89 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
90
91 lemma-assoc-domain : {m n : ℕ} {A : Set} → (eq : EqInst A) → (is : Vec (Fin n) m) → (xs : Vec A m) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → (toList is) in-domain-of h
92 lemma-assoc-domain eq []         []         h ph = Data.List.All.[]
93 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph with assoc eq is' xs' | inspect (assoc eq is') xs'
94 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
95 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] = apply-checkInsertProof eq i' x' h' record {
96     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
97       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
98       (lemma-assoc-domain eq is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')) ph)))
99   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
100       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
101       (Data.List.All.map
102         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert eq i i' (proj₁ p) x' h' h (proj₂ p) ph)
103         (lemma-assoc-domain eq is' xs' h' ph'))
104   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
105   }
106
107 lemma-map-lookupM-insert : {m n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : Vec (Fin n) m) → (x : A) → (h : FinMapMaybe n A) → i ∉ (toList is) → (toList is) in-domain-of h → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
108 lemma-map-lookupM-insert eq i []         x h i∉is ph = refl
109 lemma-map-lookupM-insert eq i (i' ∷ is') x h i∉is ph = begin
110   lookupM i' (insert i x h) ∷ map (flip lookupM (insert i x h)) is'
111     ≡⟨ cong (flip _∷_ (map (flip lookupM (insert i x h)) is')) (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym))) ⟩
112   lookupM i' h ∷ map (flip lookupM (insert i x h)) is'
113     ≡⟨ cong (_∷_ (lookupM i' h)) (lemma-map-lookupM-insert eq i is' x h (i∉is ∘ there) (Data.List.All.tail ph)) ⟩
114   lookupM i' h ∷ map (flip lookupM h) is' ∎
115
116 lemma-map-lookupM-assoc : {m n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : Vec (Fin n) m) → (x : A) → (xs : Vec A m) → (h : FinMapMaybe n A) → (h' : FinMapMaybe n A) → assoc eq is xs ≡ just h' → checkInsert eq i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
117 lemma-map-lookupM-assoc eq i []         x []         h h' ph' ph = refl
118 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph with any (_≟_ i) (toList (i' ∷ is'))
119 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') p
120 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
121 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , refl) | .(just x'') with eq x x''
122 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
123 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' () | yes p | (x'' , refl) | .(just x'') | no ¬p
124 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p rewrite lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h' ph' ¬p = begin
125   map (flip lookupM h) (i' ∷ is')
126     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (lemma-from-just (sym ph))) (i' ∷ is') ⟩
127   map (flip lookupM (insert i x h')) (i' ∷ is')
128     ≡⟨ lemma-map-lookupM-insert eq i (i' ∷ is') x h' ¬p (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') ⟩
129   map (flip lookupM h') (i' ∷ is') ∎
130
131 lemma-2 : {τ : Set} {m n : ℕ} → (eq : EqInst τ) → (is : Vec (Fin n) m) → (v : Vec τ m) → (h : FinMapMaybe n τ) → assoc eq is v ≡ just h → map (flip lookupM h) is ≡ map just v
132 lemma-2 eq []       []       h p = refl
133 lemma-2 eq (i ∷ is) (x ∷ xs) h p with assoc eq is xs | inspect (assoc eq is) xs
134 lemma-2 eq (i ∷ is) (x ∷ xs) h () | nothing | _
135 lemma-2 eq (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
136   map (flip lookupM h) (i ∷ is)
137     ≡⟨ refl ⟩
138   lookupM i h ∷ map (flip lookupM h) is
139     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc eq i is x xs h (begin
140       assoc eq (i ∷ is) (x ∷ xs)
141         ≡⟨ cong (flip _>>=_ (checkInsert eq i x)) ir ⟩
142       checkInsert eq i x h'
143         ≡⟨ p ⟩
144       just h ∎) ) ⟩
145   just x ∷ map (flip lookupM h) is
146     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc eq i is x xs h h' ir p) ⟩
147   just x ∷ map (flip lookupM h') is
148     ≡⟨ cong (_∷_ (just x)) (lemma-2 eq is xs h' ir) ⟩
149   just x ∷ map just xs
150     ≡⟨ refl ⟩
151   map just (x ∷ xs) ∎
152
153 postulate
154   free-theorem-list-list : {getlen : ℕ → ℕ} → (get : get-type getlen) → {α β : Set} → (f : α → β) → {m : ℕ} → (v : Vec α m) → get (map f v) ≡ map f (get v)
155
156 lemma-map-denumerate-enumerate : {m : ℕ} {A : Set} → (as : Vec A m) → map (denumerate as) (enumerate as) ≡ as
157 lemma-map-denumerate-enumerate []       = refl
158 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
159   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
160     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
161   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
162     ≡⟨ refl ⟩
163   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
164     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
165   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
166     ≡⟨ refl ⟩
167   map (denumerate as) (enumerate as)
168     ≡⟨ lemma-map-denumerate-enumerate as ⟩
169   as ∎)
170
171 theorem-1 : {getlen : ℕ → ℕ} → (get : get-type getlen) → {m : ℕ} {τ : Set} → (eq : EqInst τ) → (s : Vec τ m) → bff get eq s (get s) ≡ just s
172 theorem-1 get eq s = begin
173   bff get eq s (get s)
174     ≡⟨ cong (bff get eq s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
175   bff get eq s (get (map (denumerate s) (enumerate s)))
176     ≡⟨ cong (bff get eq s) (free-theorem-list-list get (denumerate s) (enumerate s)) ⟩
177   bff get eq s (map (denumerate s) (get (enumerate s)))
178     ≡⟨ refl ⟩
179   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) (map (denumerate s) (get (enumerate s)))))
180     ≡⟨ cong (fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) (lemma-1 eq (denumerate s) (get (enumerate s))) ⟩
181   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (flip lookupVec s))) (just (restrict (denumerate s) (toList (get (enumerate s))))))
182     ≡⟨ refl ⟩
183   just ((flip map (enumerate s) ∘ flip lookup) (union (restrict (denumerate s) (toList (get (enumerate s)))) (fromFunc (denumerate s))))
184     ≡⟨ cong just (cong (flip map (enumerate s) ∘ flip lookup) (lemma-union-restrict (denumerate s) (toList (get (enumerate s))))) ⟩
185   just ((flip map (enumerate s) ∘ flip lookup) (fromFunc (denumerate s)))
186     ≡⟨ refl ⟩
187   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
188     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
189   just (map (denumerate s) (enumerate s))
190     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
191   just s ∎
192
193 lemma-fmap-just : {A B : Set} → {f : A → B} {b : B} → (ma : Maybe A) → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
194 lemma-fmap-just (just x) fmap-f-ma≡just-b = x , refl
195 lemma-fmap-just nothing  ()
196
197 ∷-injective : {A : Set} {n : ℕ} {x y : A} {xs ys : Vec A n} → (x ∷ xs) ≡ (y ∷ ys) → x ≡ y × xs ≡ ys
198 ∷-injective refl = refl , refl
199
200 lemma-from-map-just : {A : Set} {n : ℕ} → {xs ys : Vec A n} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
201 lemma-from-map-just {xs = []}      {ys = []}       p  = refl
202 lemma-from-map-just {xs = x ∷ xs'} {ys = y ∷ ys'}  p with ∷-injective p
203 lemma-from-map-just {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (lemma-from-map-just p')
204
205 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
206 lemma-union-not-used h h' []        p = refl
207 lemma-union-not-used h h' (i ∷ is') p with Data.List.All.head p
208 lemma-union-not-used h h' (i ∷ is') p | x , lookupM-i-h≡just-x = begin
209   just (lookup i (union h h')) ∷ map just (map (flip lookup (union h h')) is')
210     ≡⟨ cong (flip _∷_ (map just (map (flip lookup (union h h')) is'))) (begin
211       just (lookup i (union h h'))
212         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
213       just (maybe′ id (lookup i h') (lookupM i h))
214         ≡⟨ cong just (cong (maybe′ id (lookup i h')) lookupM-i-h≡just-x) ⟩
215       just (maybe′ id (lookup i h') (just x))
216         ≡⟨ refl ⟩
217       just x
218         ≡⟨ sym lookupM-i-h≡just-x ⟩
219       lookupM i h ∎) ⟩
220   lookupM i h ∷ map just (map (flip lookup (union h h')) is')
221     ≡⟨ cong (_∷_ (lookupM i h)) (lemma-union-not-used h h' is' (Data.List.All.tail p)) ⟩
222   lookupM i h ∷ map (flip lookupM h) is' ∎
223
224 theorem-2 : {getlen : ℕ → ℕ} (get : get-type getlen) → {τ : Set} {m : ℕ} → (eq : EqInst τ) → (v : Vec τ (getlen m)) → (s u : Vec τ m) → bff get eq s v ≡ just u → get u ≡ v
225 theorem-2 get eq v s u p with lemma-fmap-just (assoc eq (get (enumerate s)) v) (proj₂ (lemma-fmap-just (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) v)) p))
226 theorem-2 get eq v s u p | h , ph = begin
227   get u
228     ≡⟨ lemma-from-just (begin
229       just (get u)
230         ≡⟨ refl ⟩
231       fmap get (just u)
232         ≡⟨ cong (fmap get) (sym p) ⟩
233       fmap get (bff get eq s v)
234         ≡⟨ cong (fmap get ∘ fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) ph ⟩
235       fmap get (fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (just h)))
236        ≡⟨ refl ⟩
237      just (get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s)))
238        ∎) ⟩
239   get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s))
240     ≡⟨ free-theorem-list-list get (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s) ⟩
241   map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s))
242      ≡⟨ lemma-from-map-just (begin
243        map just (map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s)))
244          ≡⟨ lemma-union-not-used h (fromFunc (denumerate s)) (get (enumerate s)) (lemma-assoc-domain eq (get (enumerate s)) v h ph) ⟩
245        map (flip lookupM h) (get (enumerate s))
246          ≡⟨ lemma-2 eq (get (enumerate s)) v h ph ⟩
247        map just v
248          ∎) ⟩
249   v ∎