prove theorem-2 in the presence of delete
[~helmut/bidiragda.git] / Bidir.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Bidir (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin)
7 import Level
8 import Category.Monad
9 import Category.Functor
10 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
11 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
12 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
13 open import Data.List using (List)
14 open import Data.List.All using (All)
15 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; map ; tabulate) renaming (lookup to lookupVec)
16 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
17 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
18 open import Function using (id ; _∘_ ; flip)
19 open import Relation.Binary.Core using (refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; trans ; cong₂)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 import FreeTheorems
24 open FreeTheorems.VecVec using (get-type ; free-theorem)
25 open import Generic using (just-injective ; map-just-injective ; mapMV ; mapMV-cong ; mapMV-purity ; sequenceV ; sequence-map)
26 open import FinMap
27 import CheckInsert
28 open CheckInsert Carrier deq
29 import BFF
30 open BFF.VecBFF Carrier deq using (assoc ; enumerate ; denumerate ; bff)
31
32 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
33 lemma-1 f []        = refl
34 lemma-1 f (i ∷ is′) = begin
35   (assoc is′ (map f is′) >>= checkInsert i (f i))
36     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
37   checkInsert i (f i) (restrict f (toList is′))
38     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
39   just (restrict f (toList (i ∷ is′))) ∎
40
41 lemma-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
42 lemma-lookupM-assoc i is x xs h    p with assoc is xs
43 lemma-lookupM-assoc i is x xs h    () | nothing
44 lemma-lookupM-assoc i is x xs h    p | just h' with checkInsert i x h' | insertionresult i x h'
45 lemma-lookupM-assoc i is x xs .h refl | just h | ._ | same pl = pl
46 lemma-lookupM-assoc i is x xs ._ refl | just h' | ._ | new _ = lemma-lookupM-insert i x h'
47 lemma-lookupM-assoc i is x xs h () | just h' | ._ | wrong _ _ _
48
49 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
50 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
51
52 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
53 lemma-assoc-domain []         []         h ph = Data.List.All.[]
54 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
55 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
56 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
57 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') .h refl | just h | [ ph' ] | ._ | _ | same pl = All._∷_ (x' , pl) (lemma-assoc-domain is' xs' h ph')
58 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ._ refl | just h' | [ ph' ] | ._ | [ cI≡ ] | new _ = All._∷_
59   (x' , lemma-lookupM-insert i' x' h')
60   (Data.List.All.map
61     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' (insert i' x' h') (proj₂ p) cI≡)
62     (lemma-assoc-domain is' xs' h' ph'))
63 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | just h' | [ ph' ] | ._ | _ | wrong _ _ _
64
65 lemma-map-lookupM-assoc : {m : ℕ} → (i : Fin m) → (x : Carrier) → (h : FinMapMaybe m Carrier) → (h' : FinMapMaybe m Carrier) → checkInsert i x h' ≡ just h → {n : ℕ} → (js : Vec (Fin m) n) → (toList js) in-domain-of h' → map (flip lookupM h) js ≡ map (flip lookupM h') js
66 lemma-map-lookupM-assoc i x h h' ph [] pj = refl
67 lemma-map-lookupM-assoc i x h h' ph (j ∷ js) (Data.List.All._∷_ (x' , pl) pj) = cong₂ _∷_
68   (trans (lemma-lookupM-checkInsert j i x' x h' h pl ph) (sym pl))
69   (lemma-map-lookupM-assoc i x h h' ph js pj)
70
71 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → map (flip lookupM h) is ≡ map just v
72 lemma-2 []       []       h p = refl
73 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
74 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
75 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
76   lookupM i h ∷ map (flip lookupM h) is
77     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc i is x xs h (begin
78       assoc (i ∷ is) (x ∷ xs)
79         ≡⟨ cong (flip _>>=_ (checkInsert i x)) ir ⟩
80       checkInsert i x h'
81         ≡⟨ p ⟩
82       just h ∎) ) ⟩
83   just x ∷ map (flip lookupM h) is
84     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i x h h' p is (lemma-assoc-domain is xs h' ir)) ⟩
85   just x ∷ map (flip lookupM h') is
86     ≡⟨ cong (_∷_ (just x)) (lemma-2 is xs h' ir) ⟩
87   just x ∷ map just xs ∎
88
89 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
90 lemma-map-denumerate-enumerate []       = refl
91 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
92   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
93     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
94   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
95     ≡⟨ refl ⟩
96   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
97     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
98   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
99     ≡⟨ refl ⟩
100   map (denumerate as) (enumerate as)
101     ≡⟨ lemma-map-denumerate-enumerate as ⟩
102   as ∎)
103
104 theorem-1 : {getlen : ℕ → ℕ} → (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → bff get s (get s) ≡ just s
105 theorem-1 get s = begin
106   bff get s (get s)
107     ≡⟨ cong (bff get s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
108   bff get s (get (map (denumerate s) (enumerate s)))
109     ≡⟨ cong (bff get s) (free-theorem get (denumerate s) (enumerate s)) ⟩
110   bff get s (map (denumerate s) (get (enumerate s)))
111     ≡⟨ refl ⟩
112   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
113     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
114   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
115     ≡⟨ refl ⟩
116   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (delete-many (get (enumerate s)) (fromFunc (denumerate s))))
117     ≡⟨ cong (h′↦r ∘ just) (lemma-disjoint-union (denumerate s) (get (enumerate s))) ⟩
118   (h′↦r ∘ just) (fromFunc (denumerate s))
119     ≡⟨ refl ⟩
120   mapMV (flip lookupVec (fromFunc (denumerate s))) (enumerate s)
121     ≡⟨ cong (flip mapMV (enumerate s) ∘ flip lookupVec) (lemma-fromFunc-tabulate (denumerate s)) ⟩
122   mapMV (flip lookupVec (tabulate (Maybe.just ∘ denumerate s))) (enumerate s)
123     ≡⟨ mapMV-cong (lookup∘tabulate (Maybe.just ∘ denumerate s)) (enumerate s) ⟩
124   mapMV (Maybe.just ∘ denumerate s) (enumerate s)
125     ≡⟨ mapMV-purity (denumerate s) (enumerate s) ⟩
126   just (map (denumerate s) (enumerate s))
127     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
128   just s ∎
129     where h↦h′ = _<$>_ (flip union (delete-many (get (enumerate s)) (fromFunc (denumerate s))))
130           h′↦r = flip _>>=_ (flip mapMV (enumerate s) ∘ flip lookupVec)
131
132
133 lemma-<$>-just : {A B : Set} {f : A → B} {b : B} (ma : Maybe A) → f <$> ma ≡ just b → ∃ λ a → ma ≡ just a
134 lemma-<$>-just (just x) f<$>ma≡just-b = x , refl
135 lemma-<$>-just nothing  ()
136
137 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMapMaybe n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map (flip lookupM (union h h')) is ≡ map (flip lookupM h) is
138 lemma-union-not-used h h' []        p = refl
139 lemma-union-not-used h h' (i ∷ is') (Data.List.All._∷_ (x , px) p') = cong₂ _∷_ (begin
140       lookupM i (union h h')
141         ≡⟨ lookup∘tabulate (λ j → maybe′ just (lookupM j h') (lookupM j h)) i ⟩
142       maybe′ just (lookupM i h') (lookupM i h)
143         ≡⟨ cong (maybe′ just (lookupM i h')) px ⟩
144       maybe′ just (lookupM i h') (just x)
145         ≡⟨ sym px ⟩
146       lookupM i h ∎)
147   (lemma-union-not-used h h' is' p')
148
149 lemma->>=-just : {A B : Set} (ma : Maybe A) {f : A → Maybe B} {b : B} → (ma >>= f) ≡ just b → ∃ λ a → ma ≡ just a
150 lemma->>=-just (just a) p = a , refl
151 lemma->>=-just nothing  ()
152
153 lemma-mapMV-just : {A B : Set} {n : ℕ} {f : A → Maybe B} {s : Vec A n} {v : Vec B n} → mapMV f s ≡ just v → All (λ x → ∃ λ y → f x ≡ just y) (toList s)
154 lemma-mapMV-just         {s = []}     p = Data.List.All.[]
155 lemma-mapMV-just {f = f} {s = x ∷ xs} p with f x | inspect f x
156 lemma-mapMV-just         {s = x ∷ xs} () | nothing | _
157 lemma-mapMV-just {f = f} {s = x ∷ xs} p  | just y  | [ py ] with mapMV f xs | inspect (mapMV f) xs
158 lemma-mapMV-just         {s = x ∷ xs} () | just y  | [ py ] | nothing | _
159 lemma-mapMV-just         {s = x ∷ xs} p  | just y  | [ py ] | just ys | [ pys ] = (y , py) Data.List.All.∷ (lemma-mapMV-just pys)
160
161 lemma-just-sequence : {A : Set} {n : ℕ} → (v : Vec A n) → sequenceV (map just v) ≡ just v
162 lemma-just-sequence [] = refl
163 lemma-just-sequence (x ∷ xs) rewrite lemma-just-sequence xs = refl
164
165 lemma-mapM-successful : {A B : Set} {f : A → Maybe B} {n : ℕ} → (v : Vec A n) → {r : Vec B n} → mapMV f v ≡ just r → ∃ λ w → map f v ≡ map just w
166 lemma-mapM-successful         []      p = [] , refl
167 lemma-mapM-successful {f = f} (x ∷ xs) p with f x | mapMV f xs | inspect (mapMV f) xs
168 lemma-mapM-successful         (x ∷ xs) () | nothing | _ | _
169 lemma-mapM-successful         (x ∷ xs) () | just y | nothing | _
170 lemma-mapM-successful         (x ∷ xs) p  | just y | just ys | [ p′ ] with lemma-mapM-successful xs p′
171 lemma-mapM-successful         (x ∷ xs) p  | just y | just ys | [ p′ ] | w , pw = y ∷ w , cong (_∷_ (just y)) pw
172
173
174 lemma-get-mapMV : {A B : Set} {f : A → Maybe B} {n : ℕ} {v : Vec A n} {r : Vec B n} → mapMV f v ≡ just r → {getlen : ℕ → ℕ} (get : get-type getlen) → get <$> mapMV f v ≡ mapMV f (get v)
175 lemma-get-mapMV {f = f} {v = v} p get = let w , pw = lemma-mapM-successful v p in begin
176   get <$> mapMV f v
177     ≡⟨ cong (_<$>_ get) (sym (sequence-map f v)) ⟩
178   get <$> (sequenceV (map f v))
179     ≡⟨ cong (_<$>_ get ∘ sequenceV) pw ⟩
180   get <$> (sequenceV (map just w))
181     ≡⟨ cong (_<$>_ get) (lemma-just-sequence w) ⟩
182   get <$> just w
183     ≡⟨ sym (lemma-just-sequence (get w)) ⟩
184   sequenceV (map just (get w))
185     ≡⟨ cong sequenceV (sym (free-theorem get just w)) ⟩
186   sequenceV (get (map just w))
187     ≡⟨ cong (sequenceV ∘ get) (sym pw) ⟩
188   sequenceV (get (map f v))
189     ≡⟨ cong sequenceV (free-theorem get f v) ⟩
190   sequenceV (map f (get v))
191     ≡⟨ sequence-map f (get v) ⟩
192   mapMV f (get v) ∎
193
194 theorem-2 : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (v : Vec Carrier (getlen m)) → (s u : Vec Carrier m) → bff get s v ≡ just u → get u ≡ v
195 theorem-2 get v s u p with (lemma->>=-just ((flip union (delete-many (get (enumerate s)) (fromFunc (denumerate s)))) <$> (assoc (get (enumerate s)) v)) p)
196 theorem-2 get v s u p | h′ , ph′ with (lemma-<$>-just (assoc (get (enumerate s)) v) ph′)
197 theorem-2 get v s u p | h′ , ph′ | h , ph = just-injective (begin
198   get <$> (just u)
199     ≡⟨ cong (_<$>_ get) (sym p) ⟩
200   get <$> (bff get s v)
201     ≡⟨ cong (_<$>_ get ∘ flip _>>=_ h′↦r ∘ _<$>_ h↦h′) ph ⟩
202   get <$> mapMV (flip lookupM (h↦h′ h)) s′
203     ≡⟨ lemma-get-mapMV (trans (cong (flip _>>=_ h′↦r ∘ _<$>_ h↦h′) (sym ph)) p) get ⟩
204   mapMV (flip lookupM (h↦h′ h)) (get s′)
205     ≡⟨ sym (sequence-map (flip lookupM (h↦h′ h)) (get s′)) ⟩
206   sequenceV (map (flip lookupM (h↦h′ h)) (get s′))
207     ≡⟨ cong sequenceV (lemma-union-not-used h g′ (get s′) (lemma-assoc-domain (get s′) v h ph)) ⟩
208   sequenceV (map (flip lookupM h) (get s′))
209     ≡⟨ cong sequenceV (lemma-2 (get s′) v h ph) ⟩
210   sequenceV (map just v)
211     ≡⟨ lemma-just-sequence v ⟩
212   just v ∎)
213     where s′   = enumerate s
214           g    = fromFunc (denumerate s)
215           g′   = delete-many (get s′) g
216           h↦h′ = flip union g′
217           h′↦r = flip mapMV s′ ∘ flip lookupM