rewrite main theorems to using Vec instead of List
[~helmut/bidiragda.git] / Bidir.agda
1 module Bidir where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Data.Fin.Props using (_≟_)
6 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
7 open import Data.List using (List)
8 open import Data.List.Any using (Any ; any ; here ; there)
9 open import Data.List.All using (All)
10 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
11 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; fromList ; map ; tabulate) renaming (lookup to lookupVec)
12 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
13 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
14 open import Data.Empty using (⊥-elim)
15 open import Function using (id ; _∘_ ; flip)
16 open import Relation.Nullary using (yes ; no ; _)
17 open import Relation.Nullary.Negation using (contradiction)
18 open import Relation.Binary.Core using (_≡_ ; refl)
19 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; Reveal_is_ ; _≗_ ; trans)
20 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
21
22 open import FinMap
23 open import CheckInsert
24
25 open import BFF using (_>>=_ ; fmap)
26
27 open BFF.VecBFF using (assoc ; enumerate ; denumerate ; bff)
28
29 lemma-1 : {τ : Set} {m n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (is : Vec (Fin n) m) → assoc eq is (map f is) ≡ just (restrict f (toList is))
30 lemma-1 eq f []        = refl
31 lemma-1 eq f (i ∷ is′) = begin
32   assoc eq (i ∷ is′) (map f (i ∷ is′))
33     ≡⟨ refl ⟩
34   assoc eq is′ (map f is′) >>= checkInsert eq i (f i)
35     ≡⟨ cong (λ m → m >>= checkInsert eq i (f i)) (lemma-1 eq f is′) ⟩
36   just (restrict f (toList is′)) >>= (checkInsert eq i (f i))
37     ≡⟨ refl ⟩
38   checkInsert eq i (f i) (restrict f (toList is′))
39     ≡⟨ lemma-checkInsert-restrict eq f i (toList is′) ⟩
40   just (restrict f (toList (i ∷ is′))) ∎
41
42 lemma-lookupM-assoc : {A : Set} {m n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : Vec (Fin n) m) → (x : A) → (xs : Vec A m) → (h : FinMapMaybe n A) → assoc eq (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
43 lemma-lookupM-assoc eq i is x xs h    p with assoc eq is xs
44 lemma-lookupM-assoc eq i is x xs h    () | nothing
45 lemma-lookupM-assoc eq i is x xs h    p | just h' = apply-checkInsertProof eq i x h' record
46   { same  = λ lookupM≡justx → begin
47       lookupM i h
48         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-same eq i x h' lookupM≡justx))) ⟩
49       lookupM i h'
50         ≡⟨ lookupM≡justx ⟩
51       just x ∎
52   ; new   = λ lookupM≡nothing → begin
53       lookupM i h
54         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-new eq i x h' lookupM≡nothing))) ⟩
55       lookupM i (insert i x h')
56         ≡⟨ lemma-lookupM-insert i x h' ⟩
57       just x ∎
58   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing (trans (sym p) (lemma-checkInsert-wrong eq i x h' x' x≢x' lookupM≡justx'))
59   }
60
61 lemma-∉-lookupM-assoc : {A : Set} {m n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec A m) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
62 lemma-∉-lookupM-assoc eq i []         []         h ph i∉is = begin
63   lookupM i h
64     ≡⟨ cong (lookupM i) (sym (lemma-from-just ph)) ⟩
65   lookupM i empty
66     ≡⟨ lemma-lookupM-empty i ⟩
67   nothing ∎
68 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is with i ≟ i'
69 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | yes p = contradiction (here p) i∉is
70 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | no ¬p with assoc eq is' xs' | inspect (assoc eq is') xs'
71 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h () i∉is | no ¬p | nothing | Reveal_is_.[_] ph'
72 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | no ¬p | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
73     same = λ lookupM-i'-h'≡just-x' → begin
74       lookupM i h
75         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x'))) ⟩
76       lookupM i h'
77         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
78       nothing ∎
79   ; new = λ lookupM-i'-h'≡nothing → begin
80       lookupM i h
81         ≡⟨ cong (lookupM i)  (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing))) ⟩
82       lookupM i (insert i' x' h')
83         ≡⟨ sym (lemma-lookupM-insert-other i i' x' h' ¬p) ⟩
84       lookupM i h'
85         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
86       nothing ∎
87   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
88   }
89
90 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
91 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
92
93 lemma-assoc-domain : {m n : ℕ} {A : Set} → (eq : EqInst A) → (is : Vec (Fin n) m) → (xs : Vec A m) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → (toList is) in-domain-of h
94 lemma-assoc-domain eq []         []         h ph = Data.List.All.[]
95 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph with assoc eq is' xs' | inspect (assoc eq is') xs'
96 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h () | nothing | ph'
97 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
98     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
99       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
100       (lemma-assoc-domain eq is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')) ph)))
101   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
102       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
103       (Data.List.All.map
104         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert eq i i' (proj₁ p) x' h' h (proj₂ p) ph)
105         (lemma-assoc-domain eq is' xs' h' ph'))
106   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
107   }
108
109 lemma-map-lookupM-insert : {m n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : Vec (Fin n) m) → (x : A) → (h : FinMapMaybe n A) → ¬(i ∈ (toList is)) → (toList is) in-domain-of h → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
110 lemma-map-lookupM-insert eq i []         x h i∉is ph = refl
111 lemma-map-lookupM-insert eq i (i' ∷ is') x h i∉is ph = begin
112   lookupM i' (insert i x h) ∷ map (flip lookupM (insert i x h)) is'
113     ≡⟨ cong (flip _∷_ (map (flip lookupM (insert i x h)) is')) (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym))) ⟩
114   lookupM i' h ∷ map (flip lookupM (insert i x h)) is'
115     ≡⟨ cong (_∷_ (lookupM i' h)) (lemma-map-lookupM-insert eq i is' x h (i∉is ∘ there) (Data.List.All.tail ph)) ⟩
116   lookupM i' h ∷ map (flip lookupM h) is' ∎
117
118 lemma-map-lookupM-assoc : {m n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : Vec (Fin n) m) → (x : A) → (xs : Vec A m) → (h : FinMapMaybe n A) → (h' : FinMapMaybe n A) → assoc eq is xs ≡ just h' → checkInsert eq i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
119 lemma-map-lookupM-assoc eq i []         x []         h h' ph' ph = refl
120 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph with any (_≟_ i) (toList (i' ∷ is'))
121 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') p
122 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
123 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , refl) | .(just x'') with eq x x''
124 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
125 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' () | yes p | (x'' , refl) | .(just x'') | no ¬p
126 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p with lookupM i h' | lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h' ph' ¬p
127 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p | .nothing | refl = begin
128   map (flip lookupM h) (i' ∷ is')
129     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (lemma-from-just (sym ph))) (i' ∷ is') ⟩
130   map (flip lookupM (insert i x h')) (i' ∷ is')
131     ≡⟨ lemma-map-lookupM-insert eq i (i' ∷ is') x h' ¬p (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') ⟩
132   map (flip lookupM h') (i' ∷ is') ∎
133
134 lemma-2 : {τ : Set} {m n : ℕ} → (eq : EqInst τ) → (is : Vec (Fin n) m) → (v : Vec τ m) → (h : FinMapMaybe n τ) → assoc eq is v ≡ just h → map (flip lookupM h) is ≡ map just v
135 lemma-2 eq []       []       h p = refl
136 lemma-2 eq (i ∷ is) (x ∷ xs) h p with assoc eq is xs | inspect (assoc eq is) xs
137 lemma-2 eq (i ∷ is) (x ∷ xs) h () | nothing | _
138 lemma-2 eq (i ∷ is) (x ∷ xs) h p | just h' | Reveal_is_.[_] ir = begin
139   map (flip lookupM h) (i ∷ is)
140     ≡⟨ refl ⟩
141   lookupM i h ∷ map (flip lookupM h) is
142     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc eq i is x xs h (begin
143       assoc eq (i ∷ is) (x ∷ xs)
144         ≡⟨ cong (flip _>>=_ (checkInsert eq i x)) ir ⟩
145       checkInsert eq i x h'
146         ≡⟨ p ⟩
147       just h ∎) ) ⟩
148   just x ∷ map (flip lookupM h) is
149     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc eq i is x xs h h' ir p) ⟩
150   just x ∷ map (flip lookupM h') is
151     ≡⟨ cong (_∷_ (just x)) (lemma-2 eq is xs h' ir) ⟩
152   just x ∷ map just xs
153     ≡⟨ refl ⟩
154   map just (x ∷ xs) ∎
155
156 postulate
157   free-theorem-list-list : {β γ : Set} → {getlen : ℕ → ℕ} → (get : {α : Set} {n : ℕ} → Vec α n → Vec α (getlen n)) → (f : β → γ) → {m : ℕ } → (v : Vec β m) → get (map f v) ≡ map f (get v)
158
159 lemma-map-denumerate-enumerate : {m : ℕ} {A : Set} → (as : Vec A m) → map (denumerate as) (enumerate as) ≡ as
160 lemma-map-denumerate-enumerate []       = refl
161 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
162   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
163     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
164   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
165     ≡⟨ refl ⟩
166   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
167     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
168   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
169     ≡⟨ refl ⟩
170   map (denumerate as) (enumerate as)
171     ≡⟨ lemma-map-denumerate-enumerate as ⟩
172   as ∎)
173
174 theorem-1 : {getlen : ℕ → ℕ} → (get : {α : Set} {n : ℕ} → Vec α n → Vec α (getlen n)) → {m : ℕ} {τ : Set} → (eq : EqInst τ) → (s : Vec τ m) → bff get eq s (get s) ≡ just s
175 theorem-1 get eq s = begin
176   bff get eq s (get s)
177     ≡⟨ cong (bff get eq s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
178   bff get eq s (get (map (denumerate s) (enumerate s)))
179     ≡⟨ cong (bff get eq s) (free-theorem-list-list get (denumerate s) (enumerate s)) ⟩
180   bff get eq s (map (denumerate s) (get (enumerate s)))
181     ≡⟨ refl ⟩
182   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) (map (denumerate s) (get (enumerate s)))))
183     ≡⟨ cong (fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) (lemma-1 eq (denumerate s) (get (enumerate s))) ⟩
184   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (flip lookupVec s))) (just (restrict (denumerate s) (toList (get (enumerate s))))))
185     ≡⟨ refl ⟩
186   just ((flip map (enumerate s) ∘ flip lookup) (union (restrict (denumerate s) (toList (get (enumerate s)))) (fromFunc (denumerate s))))
187     ≡⟨ cong just (cong (flip map (enumerate s) ∘ flip lookup) (lemma-union-restrict (denumerate s) (toList (get (enumerate s))))) ⟩
188   just ((flip map (enumerate s) ∘ flip lookup) (fromFunc (denumerate s)))
189     ≡⟨ refl ⟩
190   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
191     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
192   just (map (denumerate s) (enumerate s))
193     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
194   just s ∎
195
196 lemma-fmap-just : {A B : Set} → {f : A → B} {b : B} → (ma : Maybe A) → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
197 lemma-fmap-just (just x) fmap-f-ma≡just-b = x , refl
198 lemma-fmap-just nothing  ()
199
200 ∷-injective : {A : Set} {n : ℕ} {x y : A} {xs ys : Vec A n} → (x ∷ xs) ≡ (y ∷ ys) → x ≡ y × xs ≡ ys
201 ∷-injective refl = refl , refl
202
203 lemma-from-map-just : {A : Set} {n : ℕ} → {xs ys : Vec A n} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
204 lemma-from-map-just {xs = []}      {ys = []}       p  = refl
205 lemma-from-map-just {xs = x ∷ xs'} {ys = y ∷ ys'}  p with ∷-injective p
206 lemma-from-map-just {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (lemma-from-map-just p')
207
208 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
209 lemma-union-not-used h h' []        p = refl
210 lemma-union-not-used h h' (i ∷ is') p with Data.List.All.head p
211 lemma-union-not-used h h' (i ∷ is') p | x , lookupM-i-h≡just-x = begin
212   just (lookup i (union h h')) ∷ map just (map (flip lookup (union h h')) is')
213     ≡⟨ cong (flip _∷_ (map just (map (flip lookup (union h h')) is'))) (begin
214       just (lookup i (union h h'))
215         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
216       just (maybe′ id (lookup i h') (lookupM i h))
217         ≡⟨ cong just (cong (maybe′ id (lookup i h')) lookupM-i-h≡just-x) ⟩
218       just (maybe′ id (lookup i h') (just x))
219         ≡⟨ refl ⟩
220       just x
221         ≡⟨ sym lookupM-i-h≡just-x ⟩
222       lookupM i h ∎) ⟩
223   lookupM i h ∷ map just (map (flip lookup (union h h')) is')
224     ≡⟨ cong (_∷_ (lookupM i h)) (lemma-union-not-used h h' is' (Data.List.All.tail p)) ⟩
225   lookupM i h ∷ map (flip lookupM h) is' ∎
226
227 theorem-2 : {getlen : ℕ → ℕ} (get : {α : Set} {n : ℕ} → Vec α n → Vec α (getlen n)) → {τ : Set} {m : ℕ} → (eq : EqInst τ) → (v : Vec τ (getlen m)) → (s u : Vec τ m) → bff get eq s v ≡ just u → get u ≡ v
228 theorem-2 get eq v s u p with lemma-fmap-just (assoc eq (get (enumerate s)) v) (proj₂ (lemma-fmap-just (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) v)) p))
229 theorem-2 get eq v s u p | h , ph = begin
230   get u
231     ≡⟨ lemma-from-just (begin
232       just (get u)
233         ≡⟨ refl ⟩
234       fmap get (just u)
235         ≡⟨ cong (fmap get) (sym p) ⟩
236       fmap get (bff get eq s v)
237         ≡⟨ cong (fmap get ∘ fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) ph ⟩
238       fmap get (fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (just h)))
239        ≡⟨ refl ⟩
240      just (get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s)))
241        ∎) ⟩
242   get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s))
243     ≡⟨ free-theorem-list-list get (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s) ⟩
244   map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s))
245      ≡⟨ lemma-from-map-just (begin
246        map just (map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s)))
247          ≡⟨ lemma-union-not-used h (fromFunc (denumerate s)) (get (enumerate s)) (lemma-assoc-domain eq (get (enumerate s)) v h ph) ⟩
248        map (flip lookupM h) (get (enumerate s))
249          ≡⟨ lemma-2 eq (get (enumerate s)) v h ph ⟩
250        map just v
251          ∎) ⟩
252   v ∎