prove the remaining parts of lemma-checkInsert-generate
[~helmut/bidiragda.git] / Bidir.agda
1 module Bidir where
2
3 open import Data.Bool hiding (_≟_)
4 open import Data.Nat
5 open import Data.Fin
6 open import Data.Fin.Props renaming (_≟_ to _≟F_)
7 open import Data.Maybe
8 open import Data.List hiding (replicate)
9 open import Data.Vec hiding (map ; zip ; _>>=_) renaming (lookup to lookupVec)
10 open import Data.Product hiding (zip ; map)
11 open import Function
12 open import Relation.Nullary
13 open import Relation.Nullary.Negation
14 open import Relation.Binary.Core
15 open import Relation.Binary.PropositionalEquality
16
17 _>>=_ : {A B : Set} → Maybe A → (A → Maybe B) → Maybe B
18 _>>=_ = flip (flip maybe′ nothing)
19
20 fmap : {A B : Set} → (A → B) → Maybe A → Maybe B
21 fmap f = maybe′ (λ a → just (f a)) nothing
22
23 module FinMap where
24
25   FinMapMaybe : ℕ → Set → Set
26   FinMapMaybe n A = Vec (Maybe A) n
27
28   lookupM : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → Maybe A
29   lookupM = lookupVec
30
31   insert : {A : Set} {n : ℕ} → Fin n → A → FinMapMaybe n A → FinMapMaybe n A
32   insert f a m = m [ f ]≔ (just a)
33
34   empty : {A : Set} {n : ℕ} → FinMapMaybe n A
35   empty = replicate nothing
36
37   fromAscList : {A : Set} {n : ℕ} → List (Fin n × A) → FinMapMaybe n A
38   fromAscList []             = empty
39   fromAscList ((f , a) ∷ xs) = insert f a (fromAscList xs)
40
41   FinMap : ℕ → Set → Set
42   FinMap n A = Vec A n
43
44   lookup : {A : Set} {n : ℕ} → Fin n → FinMap n A → A
45   lookup = lookupVec
46
47   fromFunc : {A : Set} {n : ℕ} → (Fin n → A) → FinMap n A
48   fromFunc = tabulate
49
50   union : {A : Set} {n : ℕ} → FinMapMaybe n A → FinMap n  A → FinMap n A
51   union m1 m2 = tabulate (λ f → maybe′ id (lookup f m2) (lookupM f m1))
52
53 open FinMap
54
55 EqInst : Set → Set
56 EqInst A = (x y : A) → Dec (x ≡ y)
57
58 checkInsert : {A : Set} {n : ℕ} → EqInst A → Fin n → A → FinMapMaybe n A → Maybe (FinMapMaybe n A)
59 checkInsert eq i b m with lookupM i m
60 checkInsert eq i b m | just c with eq b c
61 checkInsert eq i b m | just .b | yes refl = just m
62 checkInsert eq i b m | just c  | no p    = nothing
63 checkInsert eq i b m | nothing = just (insert i b m)
64
65 assoc : {A : Set} {n : ℕ} → EqInst A → List (Fin n) → List A → Maybe (FinMapMaybe n A)
66 assoc _  []       []       = just empty
67 assoc eq (i ∷ is) (b ∷ bs) = (assoc eq is bs) >>= (checkInsert eq i b)
68 assoc _  _        _        = nothing
69
70 generate : {A : Set} {n : ℕ} → (Fin n → A) → List (Fin n) → FinMapMaybe n A
71 generate f is = fromAscList (zip is (map f is))
72
73 lemma-insert-same : {τ : Set} {n : ℕ} → (m : FinMapMaybe n τ) → (f : Fin n) → (a : τ) → just a ≡ lookupM f m → m ≡ insert f a m
74 lemma-insert-same []               ()      a p
75 lemma-insert-same (.(just a) ∷ xs) zero    a refl = refl
76 lemma-insert-same (x ∷ xs)         (suc i) a p    = cong (_∷_ x) (lemma-insert-same xs i a p)
77
78 lemma-lookupM-empty : {A : Set} {n : ℕ} → (i : Fin n) → nothing ≡ lookupM {A} i empty
79 lemma-lookupM-empty zero    = refl
80 lemma-lookupM-empty (suc i) = lemma-lookupM-empty i
81
82 lemma-from-just : {A : Set} → {x y : A} → _≡_ {_} {Maybe A} (just x) (just y) → x ≡ y
83 lemma-from-just refl = refl
84
85 lemma-lookupM-insert : {A : Set} {n : ℕ} → (i : Fin n) → (a : A) → (m : FinMapMaybe n A) → just a ≡ lookupM i (insert i a m)
86 lemma-lookupM-insert zero    _ (_ ∷ _)  = sym refl
87 lemma-lookupM-insert (suc i) a (_ ∷ xs) = lemma-lookupM-insert i a xs
88
89 lemma-lookupM-insert-other : {A : Set} {n : ℕ} → (i j : Fin n) → (a : A) → (m : FinMapMaybe n A) → ¬(i ≡ j) → lookupM i m ≡ lookupM i (insert j a m)
90 lemma-lookupM-insert-other zero    zero    a m p = contradiction refl p
91 lemma-lookupM-insert-other zero (suc j) a (x ∷ xs) p = refl
92 lemma-lookupM-insert-other (suc i) zero a (x ∷ xs) p = refl
93 lemma-lookupM-insert-other (suc i) (suc j) a (x ∷ xs) p = lemma-lookupM-insert-other i j a xs (contraposition (cong suc) p)
94
95 lemma-lookupM-generate : {A : Set} {n : ℕ} → (i : Fin n) → (f : Fin n → A) → (is : List (Fin n)) → (a : A) → just a ≡ lookupM i (generate f is) → a ≡ f i
96 lemma-lookupM-generate {A} i f [] a p with begin
97   just a
98     ≡⟨ p ⟩
99   lookupM i (generate f [])
100     ≡⟨ refl ⟩
101   lookupM i empty
102     ≡⟨ sym (lemma-lookupM-empty i) ⟩
103   nothing ∎
104     where open Relation.Binary.PropositionalEquality.≡-Reasoning
105 lemma-lookupM-generate i f [] a p | ()
106 lemma-lookupM-generate i f (i' ∷ is) a p with i ≟F i'
107 lemma-lookupM-generate i f (.i ∷ is) a p | yes refl = lemma-from-just (begin
108    just a
109      ≡⟨ p ⟩
110    lookupM i (generate f (i ∷ is))
111      ≡⟨ refl ⟩
112    lookupM i (insert i (f i) (generate f is))
113      ≡⟨ sym (lemma-lookupM-insert i (f i) (generate f is)) ⟩
114    just (f i) ∎)
115     where open Relation.Binary.PropositionalEquality.≡-Reasoning
116 lemma-lookupM-generate i f (i' ∷ is) a p | no ¬p2 = lemma-lookupM-generate i f is a (begin
117   just a
118     ≡⟨ p ⟩
119   lookupM i (generate f (i' ∷ is))
120     ≡⟨ refl ⟩
121   lookupM i (insert i' (f i') (generate f is))
122     ≡⟨ sym (lemma-lookupM-insert-other i i' (f i') (generate f is) ¬p2) ⟩
123   lookupM i (generate f is) ∎)
124     where open Relation.Binary.PropositionalEquality.≡-Reasoning
125
126 lemma-checkInsert-generate : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (i : Fin n) → (is : List (Fin n)) → checkInsert eq i (f i) (generate f is) ≡ just (generate f (i ∷ is))
127 lemma-checkInsert-generate eq f i is with lookupM i (generate f is) | inspect (lookupM i) (generate f is)
128 lemma-checkInsert-generate eq f i is | nothing | _ = refl
129 lemma-checkInsert-generate eq f i is | just x | Reveal_is_.[_] prf with lemma-lookupM-generate i f is x (sym prf)
130 lemma-checkInsert-generate eq f i is | just .(f i) | Reveal_is_.[_] prf | refl with eq (f i) (f i)
131 lemma-checkInsert-generate eq f i is | just .(f i) | Reveal_is_.[_] prf | refl | yes refl = cong just (lemma-insert-same (generate f is) i (f i) (sym prf))
132 lemma-checkInsert-generate eq f i is | just .(f i) | Reveal_is_.[_] prf | refl | no p = contradiction refl p
133
134 lemma-1 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (is : List (Fin n)) → assoc eq is (map f is) ≡ just (generate f is)
135 lemma-1 eq f []        = refl
136 lemma-1 eq f (i ∷ is′) = begin
137   (assoc eq (i ∷ is′) (map f (i ∷ is′)))
138     ≡⟨ refl ⟩
139   (assoc eq is′ (map f is′) >>= checkInsert eq i (f i))
140     ≡⟨ cong (λ m → m >>= checkInsert eq i (f i)) (lemma-1 eq f is′) ⟩
141   (just (generate f is′) >>= (checkInsert eq i (f i)))
142     ≡⟨ refl ⟩
143   (checkInsert eq i (f i) (generate f is′))
144     ≡⟨ lemma-checkInsert-generate eq f i is′ ⟩
145   just (generate f (i ∷ is′)) ∎
146      where open Relation.Binary.PropositionalEquality.≡-Reasoning
147
148 lemma-2 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (is : List (Fin n)) → (v : List τ) → (h : FinMapMaybe n τ) → just h ≡ assoc eq is v → map (flip lookup h) is ≡ map just v
149 lemma-2 eq []       []       h p = refl
150 lemma-2 eq []       (x ∷ xs) h ()
151 lemma-2 eq (x ∷ xs) []       h ()
152 lemma-2 eq (i ∷ is) (x ∷ xs) h p = {!!}
153
154 idrange : (n : ℕ) → List (Fin n)
155 idrange n = toList (tabulate id)
156
157 bff : ({A : Set} → List A → List A) → ({B : Set} → EqInst B → List B → List B → Maybe (List B))
158 bff get eq s v = let s′ = idrange (length s)
159                      g  = fromFunc (λ f → lookupVec f (fromList s))
160                      h  = assoc eq (get s′) v
161                      h′ = fmap (flip union g) h
162                  in fmap (flip map s′ ∘ flip lookup) h′
163
164 theorem-1 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (s : List τ) → bff get eq s (get s) ≡ just s
165 theorem-1 get eq s = {!!}