now parameterize BFF
[~helmut/bidiragda.git] / Bidir.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Bidir (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
9 open import Data.List using (List)
10 open import Data.List.Any using (Any ; any ; here ; there)
11 open import Data.List.All using (All)
12 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
13 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; fromList ; map ; tabulate) renaming (lookup to lookupVec)
14 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
15 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
16 open import Data.Empty using (⊥-elim)
17 open import Function using (id ; _∘_ ; flip)
18 open import Relation.Nullary using (yes ; no)
19 open import Relation.Nullary.Negation using (contradiction)
20 open import Relation.Binary.Core using (refl)
21 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; _≗_ ; trans)
22 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
23
24 import FreeTheorems
25 open FreeTheorems.VecVec using (get-type ; free-theorem)
26 open import FinMap
27 open import CheckInsert
28 open import BFF using (_>>=_ ; fmap)
29 open BFF.VecBFF Carrier deq using (assoc ; enumerate ; denumerate ; bff)
30
31 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
32 lemma-1 f []        = refl
33 lemma-1 f (i ∷ is′) = begin
34   assoc (i ∷ is′) (map f (i ∷ is′))
35     ≡⟨ refl ⟩
36   assoc is′ (map f is′) >>= checkInsert deq i (f i)
37     ≡⟨ cong (λ m → m >>= checkInsert deq i (f i)) (lemma-1 f is′) ⟩
38   just (restrict f (toList is′)) >>= (checkInsert deq i (f i))
39     ≡⟨ refl ⟩
40   checkInsert deq i (f i) (restrict f (toList is′))
41     ≡⟨ lemma-checkInsert-restrict deq f i (toList is′) ⟩
42   just (restrict f (toList (i ∷ is′))) ∎
43
44 lemma-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
45 lemma-lookupM-assoc i is x xs h    p with assoc is xs
46 lemma-lookupM-assoc i is x xs h    () | nothing
47 lemma-lookupM-assoc i is x xs h    p | just h' = apply-checkInsertProof deq i x h' record
48   { same  = λ lookupM≡justx → begin
49       lookupM i h
50         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-same deq i x h' lookupM≡justx))) ⟩
51       lookupM i h'
52         ≡⟨ lookupM≡justx ⟩
53       just x ∎
54   ; new   = λ lookupM≡nothing → begin
55       lookupM i h
56         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-new deq i x h' lookupM≡nothing))) ⟩
57       lookupM i (insert i x h')
58         ≡⟨ lemma-lookupM-insert i x h' ⟩
59       just x ∎
60   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing (trans (sym p) (lemma-checkInsert-wrong deq i x h' x' x≢x' lookupM≡justx'))
61   }
62
63 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
64 lemma-∉-lookupM-assoc i []         []         h ph i∉is = begin
65   lookupM i h
66     ≡⟨ cong (lookupM i) (sym (lemma-from-just ph)) ⟩
67   lookupM i empty
68     ≡⟨ lemma-lookupM-empty i ⟩
69   nothing ∎
70 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
71 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
72 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = apply-checkInsertProof deq i' x' h' record {
73     same = λ lookupM-i'-h'≡just-x' → begin
74       lookupM i h
75         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym ph) (lemma-checkInsert-same deq i' x' h' lookupM-i'-h'≡just-x'))) ⟩
76       lookupM i h'
77         ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
78       nothing ∎
79   ; new = λ lookupM-i'-h'≡nothing → begin
80       lookupM i h
81         ≡⟨ cong (lookupM i)  (lemma-from-just (trans (sym ph) (lemma-checkInsert-new deq i' x' h' lookupM-i'-h'≡nothing))) ⟩
82       lookupM i (insert i' x' h')
83         ≡⟨ sym (lemma-lookupM-insert-other i i' x' h' (i∉is ∘ here)) ⟩
84       lookupM i h'
85         ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
86       nothing ∎
87   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong deq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
88   }
89
90 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
91 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
92
93 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
94 lemma-assoc-domain []         []         h ph = Data.List.All.[]
95 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
96 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
97 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] = apply-checkInsertProof deq i' x' h' record {
98     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
99       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-same deq i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
100       (lemma-assoc-domain is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same deq i' x' h' lookupM-i'-h'≡just-x')) ph)))
101   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
102       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-new deq i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
103       (Data.List.All.map
104         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert deq i i' (proj₁ p) x' h' h (proj₂ p) ph)
105         (lemma-assoc-domain is' xs' h' ph'))
106   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong deq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
107   }
108
109 lemma-map-lookupM-insert : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (h : FinMapMaybe n Carrier) → i ∉ (toList is) → (toList is) in-domain-of h → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
110 lemma-map-lookupM-insert i []         x h i∉is ph = refl
111 lemma-map-lookupM-insert i (i' ∷ is') x h i∉is ph = begin
112   lookupM i' (insert i x h) ∷ map (flip lookupM (insert i x h)) is'
113     ≡⟨ cong (flip _∷_ (map (flip lookupM (insert i x h)) is')) (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym))) ⟩
114   lookupM i' h ∷ map (flip lookupM (insert i x h)) is'
115     ≡⟨ cong (_∷_ (lookupM i' h)) (lemma-map-lookupM-insert i is' x h (i∉is ∘ there) (Data.List.All.tail ph)) ⟩
116   lookupM i' h ∷ map (flip lookupM h) is' ∎
117
118 lemma-map-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → (h' : FinMapMaybe n Carrier) → assoc is xs ≡ just h' → checkInsert deq i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
119 lemma-map-lookupM-assoc i []         x []         h h' ph' ph = refl
120 lemma-map-lookupM-assoc i (i' ∷ is') x (x' ∷ xs') h h' ph' ph with any (_≟_ i) (toList (i' ∷ is'))
121 lemma-map-lookupM-assoc i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h' ph') p
122 lemma-map-lookupM-assoc i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
123 lemma-map-lookupM-assoc i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , refl) | .(just x'') with deq x x''
124 lemma-map-lookupM-assoc i (i' ∷ is') x (x' ∷ xs') h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
125 lemma-map-lookupM-assoc i (i' ∷ is') x (x' ∷ xs') h h' ph' () | yes p | (x'' , refl) | .(just x'') | no ¬p
126 lemma-map-lookupM-assoc i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p rewrite lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h' ph' ¬p = begin
127   map (flip lookupM h) (i' ∷ is')
128     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (lemma-from-just (sym ph))) (i' ∷ is') ⟩
129   map (flip lookupM (insert i x h')) (i' ∷ is')
130     ≡⟨ lemma-map-lookupM-insert i (i' ∷ is') x h' ¬p (lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h' ph') ⟩
131   map (flip lookupM h') (i' ∷ is') ∎
132
133 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → map (flip lookupM h) is ≡ map just v
134 lemma-2 []       []       h p = refl
135 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
136 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
137 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
138   map (flip lookupM h) (i ∷ is)
139     ≡⟨ refl ⟩
140   lookupM i h ∷ map (flip lookupM h) is
141     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc i is x xs h (begin
142       assoc (i ∷ is) (x ∷ xs)
143         ≡⟨ cong (flip _>>=_ (checkInsert deq i x)) ir ⟩
144       checkInsert deq i x h'
145         ≡⟨ p ⟩
146       just h ∎) ) ⟩
147   just x ∷ map (flip lookupM h) is
148     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i is x xs h h' ir p) ⟩
149   just x ∷ map (flip lookupM h') is
150     ≡⟨ cong (_∷_ (just x)) (lemma-2 is xs h' ir) ⟩
151   just x ∷ map just xs
152     ≡⟨ refl ⟩
153   map just (x ∷ xs) ∎
154
155 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
156 lemma-map-denumerate-enumerate []       = refl
157 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
158   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
159     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
160   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
161     ≡⟨ refl ⟩
162   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
163     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
164   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
165     ≡⟨ refl ⟩
166   map (denumerate as) (enumerate as)
167     ≡⟨ lemma-map-denumerate-enumerate as ⟩
168   as ∎)
169
170 theorem-1 : {getlen : ℕ → ℕ} → (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → bff get s (get s) ≡ just s
171 theorem-1 get s = begin
172   bff get s (get s)
173     ≡⟨ cong (bff get s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
174   bff get s (get (map (denumerate s) (enumerate s)))
175     ≡⟨ cong (bff get s) (free-theorem get (denumerate s) (enumerate s)) ⟩
176   bff get s (map (denumerate s) (get (enumerate s)))
177     ≡⟨ refl ⟩
178   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s)))))
179     ≡⟨ cong (fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
180   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (flip lookupVec s))) (just (restrict (denumerate s) (toList (get (enumerate s))))))
181     ≡⟨ refl ⟩
182   just ((flip map (enumerate s) ∘ flip lookup) (union (restrict (denumerate s) (toList (get (enumerate s)))) (fromFunc (denumerate s))))
183     ≡⟨ cong just (cong (flip map (enumerate s) ∘ flip lookup) (lemma-union-restrict (denumerate s) (toList (get (enumerate s))))) ⟩
184   just ((flip map (enumerate s) ∘ flip lookup) (fromFunc (denumerate s)))
185     ≡⟨ refl ⟩
186   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
187     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
188   just (map (denumerate s) (enumerate s))
189     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
190   just s ∎
191
192 lemma-fmap-just : {A B : Set} → {f : A → B} {b : B} → (ma : Maybe A) → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
193 lemma-fmap-just (just x) fmap-f-ma≡just-b = x , refl
194 lemma-fmap-just nothing  ()
195
196 ∷-injective : {A : Set} {n : ℕ} {x y : A} {xs ys : Vec A n} → (x ∷ xs) ≡ (y ∷ ys) → x ≡ y × xs ≡ ys
197 ∷-injective refl = refl , refl
198
199 lemma-from-map-just : {A : Set} {n : ℕ} → {xs ys : Vec A n} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
200 lemma-from-map-just {xs = []}      {ys = []}       p  = refl
201 lemma-from-map-just {xs = x ∷ xs'} {ys = y ∷ ys'}  p with ∷-injective p
202 lemma-from-map-just {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (lemma-from-map-just p')
203
204 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
205 lemma-union-not-used h h' []        p = refl
206 lemma-union-not-used h h' (i ∷ is') p with Data.List.All.head p
207 lemma-union-not-used h h' (i ∷ is') p | x , lookupM-i-h≡just-x = begin
208   just (lookup i (union h h')) ∷ map just (map (flip lookup (union h h')) is')
209     ≡⟨ cong (flip _∷_ (map just (map (flip lookup (union h h')) is'))) (begin
210       just (lookup i (union h h'))
211         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
212       just (maybe′ id (lookup i h') (lookupM i h))
213         ≡⟨ cong just (cong (maybe′ id (lookup i h')) lookupM-i-h≡just-x) ⟩
214       just (maybe′ id (lookup i h') (just x))
215         ≡⟨ refl ⟩
216       just x
217         ≡⟨ sym lookupM-i-h≡just-x ⟩
218       lookupM i h ∎) ⟩
219   lookupM i h ∷ map just (map (flip lookup (union h h')) is')
220     ≡⟨ cong (_∷_ (lookupM i h)) (lemma-union-not-used h h' is' (Data.List.All.tail p)) ⟩
221   lookupM i h ∷ map (flip lookupM h) is' ∎
222
223 theorem-2 : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (v : Vec Carrier (getlen m)) → (s u : Vec Carrier m) → bff get s v ≡ just u → get u ≡ v
224 theorem-2 get v s u p with lemma-fmap-just (assoc (get (enumerate s)) v) (proj₂ (lemma-fmap-just (fmap (flip union (fromFunc (denumerate s))) (assoc (get (enumerate s)) v)) p))
225 theorem-2 get v s u p | h , ph = begin
226   get u
227     ≡⟨ lemma-from-just (begin
228       just (get u)
229         ≡⟨ refl ⟩
230       fmap get (just u)
231         ≡⟨ cong (fmap get) (sym p) ⟩
232       fmap get (bff get s v)
233         ≡⟨ cong (fmap get ∘ fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) ph ⟩
234       fmap get (fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (just h)))
235        ≡⟨ refl ⟩
236      just (get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s)))
237        ∎) ⟩
238   get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s))
239     ≡⟨ free-theorem get (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s) ⟩
240   map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s))
241      ≡⟨ lemma-from-map-just (begin
242        map just (map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s)))
243          ≡⟨ lemma-union-not-used h (fromFunc (denumerate s)) (get (enumerate s)) (lemma-assoc-domain (get (enumerate s)) v h ph) ⟩
244        map (flip lookupM h) (get (enumerate s))
245          ≡⟨ lemma-2 (get (enumerate s)) v h ph ⟩
246        map just v
247          ∎) ⟩
248   v ∎