introduce >>= on Maybe to improve readability
[~helmut/bidiragda.git] / Bidir.agda
1 module Bidir where
2
3 open import Data.Bool hiding (_≟_)
4 open import Data.Nat
5 open import Data.Fin
6 open import Data.Maybe
7 open import Data.List hiding (replicate)
8 open import Data.Vec hiding (map ; zip ; _>>=_) renaming (lookup to lookupVec)
9 open import Data.Product hiding (zip ; map)
10 open import Function
11 open import Relation.Nullary
12 open import Relation.Binary.Core
13 open import Relation.Binary.PropositionalEquality
14
15 _>>=_ : {A B : Set} → Maybe A → (A → Maybe B) → Maybe B
16 _>>=_ = flip (flip maybe′ nothing)
17
18 module FinMap where
19
20   FinMapMaybe : ℕ → Set → Set
21   FinMapMaybe n A = Vec (Maybe A) n
22
23   lookupM : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → Maybe A
24   lookupM = lookupVec
25
26   insert : {A : Set} {n : ℕ} → Fin n → A → FinMapMaybe n A → FinMapMaybe n A
27   insert f a m = m [ f ]≔ (just a)
28
29   empty : {A : Set} {n : ℕ} → FinMapMaybe n A
30   empty = replicate nothing
31
32   fromAscList : {A : Set} {n : ℕ} → List (Fin n × A) → FinMapMaybe n A
33   fromAscList []             = empty
34   fromAscList ((f , a) ∷ xs) = insert f a (fromAscList xs)
35
36   FinMap : ℕ → Set → Set
37   FinMap n A = Vec A n
38
39   lookup : {A : Set} {n : ℕ} → Fin n → FinMap n A → A
40   lookup = lookupVec
41
42   fromFunc : {A : Set} {n : ℕ} → (Fin n → A) → FinMap n A
43   fromFunc = tabulate
44
45   union : {A : Set} {n : ℕ} → FinMapMaybe n A → FinMap n  A → FinMap n A
46   union m1 m2 = tabulate (λ f → maybe′ id (lookup f m2) (lookupM f m1))
47
48 open FinMap
49
50 EqInst : Set → Set
51 EqInst A = (x y : A) → Dec (x ≡ y)
52
53 checkInsert : {A : Set} {n : ℕ} → EqInst A → Fin n → A → FinMapMaybe n A → Maybe (FinMapMaybe n A)
54 checkInsert eq i b m with lookupM i m
55 checkInsert eq i b m | just c with eq b c
56 checkInsert eq i b m | just .b | yes refl = just m
57 checkInsert eq i b m | just c  | no p    = nothing
58 checkInsert eq i b m | nothing = just (insert i b m)
59
60 assoc : {A : Set} {n : ℕ} → EqInst A → List (Fin n) → List A → Maybe (FinMapMaybe n A)
61 assoc _  []       []       = just empty
62 assoc eq (i ∷ is) (b ∷ bs) = (assoc eq is bs) >>= (checkInsert eq i b)
63 assoc _  _        _        = nothing
64
65 generate : {A : Set} {n : ℕ} → (Fin n → A) → List (Fin n) → FinMapMaybe n A
66 generate f is = fromAscList (zip is (map f is))
67
68 data Is-Just {A : Set} : (Maybe A) → Set where
69   is-just : (x : A) → Is-Just (just x) 
70
71 the : {A : Set} {t : Maybe A} → Is-Just t → A
72 the (is-just x) = x
73
74 lemma-insert-same : {τ : Set} {n : ℕ} → (m : FinMapMaybe n τ) → (f : Fin n) → (a? : Is-Just (lookup f m)) → m ≡ insert f (the a?) m
75 lemma-insert-same [] () a?
76 lemma-insert-same (.(just x) ∷ xs) zero (is-just x) = refl
77 lemma-insert-same (x ∷ xs) (suc f′) a? = cong (_∷_ x) (lemma-insert-same xs f′ a?)
78
79 lemma-1 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (is : List (Fin n)) → assoc eq is (map f is) ≡ just (generate f is)
80 lemma-1 eq f []        = refl
81 lemma-1 eq f (i ∷ is′) with assoc eq is′ (map f is′) | generate f is′ | lemma-1 eq f is′
82 lemma-1 eq f (i ∷ is′) | nothing | _ | ()
83 lemma-1 eq f (i ∷ is′) | just m | .m | refl with lookup i m
84 lemma-1 eq f (i ∷ is′) | just m | .m | refl | nothing = refl
85 lemma-1 eq f (i ∷ is′) | just m | .m | refl | just x with eq (f i) x
86 lemma-1 eq f (i ∷ is′) | just m | .m | refl | just .(f i) | yes refl = cong just (lemma-insert-same m i {!!})
87 lemma-1 eq f (i ∷ is′) | just m | .m | refl | just x | no ¬p = {!!}
88
89 lemma-2 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (is : List (Fin n)) → (v : List τ) → (h : FinMapMaybe n τ) → just h ≡ assoc eq is v → map (flip lookup h) is ≡ map just v
90 lemma-2 eq is v h p = {!!}
91
92 idrange : (n : ℕ) → List (Fin n)
93 idrange n = toList (tabulate id)
94
95 bff : ({A : Set} → List A → List A) → ({B : Set} → EqInst B → List B → List B → Maybe (List B))
96 bff get eq s v = let s′ = idrange (length s)
97                      g  = fromFunc (λ f → lookupVec f (fromList s))
98                      h  = assoc eq (get s′) v
99                      h′ = h >>= (λ jh → just (union jh g))
100                  in h′ >>= (λ jh′ → just (map (flip lookup jh′) s′))
101
102 theorem-1 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (s : List τ) → bff get eq s (get s) ≡ just s
103 theorem-1 get eq s = {!!}