save a with in lemma-\inn-lookupM-assoc
[~helmut/bidiragda.git] / Bidir.agda
1 module Bidir where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Data.Fin.Props using (_≟_)
6 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
7 open import Data.List using (List ; [] ; _∷_ ; map ; length)
8 open import Data.List.Properties using (map-cong ; ∷-injective) renaming (map-compose to map-∘)
9 open import Data.List.Any using (Any ; any ; here ; there)
10 open import Data.List.All using (All)
11 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
12 open import Data.Vec using (toList ; fromList ; tabulate) renaming (lookup to lookupVec ; _∷_ to _∷V_)
13 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate)
14 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
15 open import Data.Empty using (⊥-elim)
16 open import Function using (id ; _∘_ ; flip)
17 open import Relation.Nullary using (yes ; no ; _)
18 open import Relation.Nullary.Negation using (contradiction)
19 open import Relation.Binary.Core using (_≡_ ; refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; Reveal_is_ ; _≗_ ; trans)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 open import FinMap
24 open import CheckInsert
25
26 open import BFF using (_>>=_ ; fmap)
27
28 open BFF.ListBFF using (assoc ; enumerate ; denumerate ; bff)
29
30 lemma-1 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (is : List (Fin n)) → assoc eq is (map f is) ≡ just (restrict f is)
31 lemma-1 eq f []        = refl
32 lemma-1 eq f (i ∷ is′) = begin
33   assoc eq (i ∷ is′) (map f (i ∷ is′))
34     ≡⟨ refl ⟩
35   assoc eq is′ (map f is′) >>= checkInsert eq i (f i)
36     ≡⟨ cong (λ m → m >>= checkInsert eq i (f i)) (lemma-1 eq f is′) ⟩
37   just (restrict f is′) >>= (checkInsert eq i (f i))
38     ≡⟨ refl ⟩
39   checkInsert eq i (f i) (restrict f is′)
40     ≡⟨ lemma-checkInsert-restrict eq f i is′ ⟩
41   just (restrict f (i ∷ is′)) ∎
42
43 lemma-lookupM-assoc : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
44 lemma-lookupM-assoc eq i is x xs h    p with assoc eq is xs
45 lemma-lookupM-assoc eq i is x xs h    () | nothing
46 lemma-lookupM-assoc eq i is x xs h    p | just h' = apply-checkInsertProof eq i x h' record
47   { same  = λ lookupM≡justx → begin
48       lookupM i h
49         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-same eq i x h' lookupM≡justx))) ⟩
50       lookupM i h'
51         ≡⟨ lookupM≡justx ⟩
52       just x ∎
53   ; new   = λ lookupM≡nothing → begin
54       lookupM i h
55         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-new eq i x h' lookupM≡nothing))) ⟩
56       lookupM i (insert i x h')
57         ≡⟨ lemma-lookupM-insert i x h' ⟩
58       just x ∎
59   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing (trans (sym p) (lemma-checkInsert-wrong eq i x h' x' x≢x' lookupM≡justx'))
60   }
61
62 lemma-∉-lookupM-assoc : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → (i ∉ is) → lookupM i h ≡ nothing
63 lemma-∉-lookupM-assoc eq i []         []         h ph i∉is = begin
64   lookupM i h
65     ≡⟨ cong (lookupM i) (sym (lemma-from-just ph)) ⟩
66   lookupM i empty
67     ≡⟨ lemma-lookupM-empty i ⟩
68   nothing ∎
69 lemma-∉-lookupM-assoc eq i []         (x' ∷ xs') h () i∉is
70 lemma-∉-lookupM-assoc eq i (i' ∷ is') []         h () i∉is
71 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc eq is' xs' | inspect (assoc eq is') xs'
72 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | Reveal_is_.[_] ph'
73 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
74     same = λ lookupM-i'-h'≡just-x' → begin
75       lookupM i h
76         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x'))) ⟩
77       lookupM i h'
78         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
79       nothing ∎
80   ; new = λ lookupM-i'-h'≡nothing → begin
81       lookupM i h
82         ≡⟨ cong (lookupM i)  (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing))) ⟩
83       lookupM i (insert i' x' h')
84         ≡⟨ sym (lemma-lookupM-insert-other i i' x' h' (i∉is ∘ here)) ⟩
85       lookupM i h'
86         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
87       nothing ∎
88   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
89   }
90
91 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
92 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
93
94 lemma-assoc-domain : {n : ℕ} {A : Set} → (eq : EqInst A) → (is : List (Fin n)) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → is in-domain-of h
95 lemma-assoc-domain eq []  []  h  ph  = Data.List.All.[]
96 lemma-assoc-domain eq [] (x' ∷ xs') h ()
97 lemma-assoc-domain eq (i' ∷ is') [] h ()
98 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph with assoc eq is' xs' | inspect (assoc eq is') xs'
99 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h () | nothing | ph'
100 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
101     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
102       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
103       (lemma-assoc-domain eq is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')) ph)))
104   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
105       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
106       (Data.List.All.map
107         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert eq i i' (proj₁ p) x' h' h (proj₂ p) ph)
108         (lemma-assoc-domain eq is' xs' h' ph'))
109   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
110   }
111
112 lemma-map-lookupM-insert : {n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (h : FinMapMaybe n A) → ¬(i ∈ is) → is in-domain-of h → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
113 lemma-map-lookupM-insert eq i []         x h i∉is ph = refl
114 lemma-map-lookupM-insert eq i (i' ∷ is') x h i∉is ph = begin
115   lookupM i' (insert i x h) ∷ map (flip lookupM (insert i x h)) is'
116     ≡⟨ cong (flip _∷_ (map (flip lookupM (insert i x h)) is')) (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym))) ⟩
117   lookupM i' h ∷ map (flip lookupM (insert i x h)) is'
118     ≡⟨ cong (_∷_ (lookupM i' h)) (lemma-map-lookupM-insert eq i is' x h (i∉is ∘ there) (Data.List.All.tail ph)) ⟩
119   lookupM i' h ∷ map (flip lookupM h) is' ∎
120
121 lemma-map-lookupM-assoc : {n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (xs : List A) → (h : FinMapMaybe n A) → (h' : FinMapMaybe n A) → assoc eq is xs ≡ just h' → checkInsert eq i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
122 lemma-map-lookupM-assoc eq i []         x []         h h' ph' ph = refl
123 lemma-map-lookupM-assoc eq i []         x (x' ∷ xs') h h' ()  ph
124 lemma-map-lookupM-assoc eq i (i' ∷ is') x []         h h' ()  ph
125 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph with any (_≟_ i) (i' ∷ is')
126 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') p
127 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
128 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , refl) | .(just x'') with eq x x''
129 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
130 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' () | yes p | (x'' , refl) | .(just x'') | no ¬p
131 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p rewrite lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h' ph' ¬p = begin
132   map (flip lookupM h) (i' ∷ is')
133     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (lemma-from-just (sym ph))) (i' ∷ is') ⟩
134   map (flip lookupM (insert i x h')) (i' ∷ is')
135     ≡⟨ lemma-map-lookupM-insert eq i (i' ∷ is') x h' ¬p (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') ⟩
136   map (flip lookupM h') (i' ∷ is') ∎
137
138 lemma-2 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (is : List (Fin n)) → (v : List τ) → (h : FinMapMaybe n τ) → assoc eq is v ≡ just h → map (flip lookupM h) is ≡ map just v
139 lemma-2 eq []       []       h p = refl
140 lemma-2 eq []       (x ∷ xs) h ()
141 lemma-2 eq (x ∷ xs) []       h ()
142 lemma-2 eq (i ∷ is) (x ∷ xs) h p with assoc eq is xs | inspect (assoc eq is) xs
143 lemma-2 eq (i ∷ is) (x ∷ xs) h () | nothing | _
144 lemma-2 eq (i ∷ is) (x ∷ xs) h p | just h' | Reveal_is_.[_] ir = begin
145   map (flip lookupM h) (i ∷ is)
146     ≡⟨ refl ⟩
147   lookupM i h ∷ map (flip lookupM h) is
148     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc eq i is x xs h (begin
149       assoc eq (i ∷ is) (x ∷ xs)
150         ≡⟨ cong (flip _>>=_ (checkInsert eq i x)) ir ⟩
151       checkInsert eq i x h'
152         ≡⟨ p ⟩
153       just h ∎) ) ⟩
154   just x ∷ map (flip lookupM h) is
155     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc eq i is x xs h h' ir p) ⟩
156   just x ∷ map (flip lookupM h') is
157     ≡⟨ cong (_∷_ (just x)) (lemma-2 eq is xs h' ir) ⟩
158   just x ∷ map just xs
159     ≡⟨ refl ⟩
160   map just (x ∷ xs) ∎
161
162 postulate
163   free-theorem-list-list : {β γ : Set} → (get : {α : Set} → List α → List α) → (f : β → γ) → get ∘ map f ≗ map f ∘ get
164
165 toList-map-commutes : {A B : Set} {n : ℕ} → (f : A → B) → (v : Data.Vec.Vec A n) → (toList (Data.Vec.map f v)) ≡ map f (toList v)
166 toList-map-commutes f Data.Vec.[] = refl
167 toList-map-commutes f (x ∷V xs) = cong (_∷_ (f x)) (toList-map-commutes f xs)
168
169 lemma-map-denumerate-enumerate : {A : Set} → (as : List A) → map (denumerate as) (enumerate as) ≡ as
170 lemma-map-denumerate-enumerate [] = refl
171 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
172   map (flip lookupVec (a ∷V (fromList as))) (toList (tabulate Fin.suc))
173     ≡⟨ cong (map (flip lookupVec (a ∷V (fromList as))) ∘ toList) (tabulate-∘ Fin.suc id) ⟩
174   map (flip lookupVec (a ∷V (fromList as))) (toList (Data.Vec.map Fin.suc (tabulate id)))
175     ≡⟨ cong (map (flip lookupVec (a ∷V fromList as))) (toList-map-commutes Data.Fin.suc (tabulate id)) ⟩
176   map (flip lookupVec (a ∷V fromList as)) (map Fin.suc (enumerate as))
177     ≡⟨ sym (map-∘ (enumerate as)) ⟩
178   map (flip lookupVec (a ∷V (fromList as)) ∘ Fin.suc) (enumerate as)
179     ≡⟨ refl ⟩
180   map (denumerate as) (enumerate as)
181     ≡⟨ lemma-map-denumerate-enumerate as ⟩
182   as ∎)
183
184 theorem-1 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (s : List τ) → bff get eq s (get s) ≡ just s
185 theorem-1 get eq s = begin
186   bff get eq s (get s)
187     ≡⟨ cong (bff get eq s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
188   bff get eq s (get (map (denumerate s) (enumerate s)))
189     ≡⟨ cong (bff get eq s) (free-theorem-list-list get (denumerate s) (enumerate s)) ⟩
190   bff get eq s (map (denumerate s) (get (enumerate s)))
191     ≡⟨ refl ⟩
192   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) (map (denumerate s) (get (enumerate s)))))
193     ≡⟨ cong (fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) (lemma-1 eq (denumerate s) (get (enumerate s))) ⟩
194   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (flip lookupVec (fromList s)))) (just (restrict (denumerate s) (get (enumerate s)))))
195     ≡⟨ refl ⟩
196   just ((flip map (enumerate s) ∘ flip lookup) (union (restrict (denumerate s) (get (enumerate s))) (fromFunc (denumerate s))))
197     ≡⟨ cong just (cong (flip map (enumerate s) ∘ flip lookup) (lemma-union-restrict (denumerate s) (get (enumerate s)))) ⟩
198   just ((flip map (enumerate s) ∘ flip lookup) (fromFunc (denumerate s)))
199     ≡⟨ refl ⟩
200   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
201     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
202   just (map (denumerate s) (enumerate s))
203     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
204   just s ∎
205
206 lemma-fmap-just : {A B : Set} → {f : A → B} {b : B} → (ma : Maybe A) → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
207 lemma-fmap-just (just x) fmap-f-ma≡just-b = x , refl
208 lemma-fmap-just nothing  ()
209
210 lemma-from-map-just : {A : Set} → {xs ys : List A} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
211 lemma-from-map-just {xs = []}      {ys = []}      p  = refl
212 lemma-from-map-just {xs = []}      {ys = y ∷ ys'} ()
213 lemma-from-map-just {xs = x ∷ xs'} {ys = []}      ()
214 lemma-from-map-just {xs = x ∷ xs'} {ys = y ∷ ys'} p with ∷-injective p
215 lemma-from-map-just {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (lemma-from-map-just p')
216
217 lemma-union-not-used : {n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : List (Fin n)) → is in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
218 lemma-union-not-used h h' []        p = refl
219 lemma-union-not-used h h' (i ∷ is') p with Data.List.All.head p
220 lemma-union-not-used h h' (i ∷ is') p | x , lookupM-i-h≡just-x = begin
221   just (lookup i (union h h')) ∷ map just (map (flip lookup (union h h')) is')
222     ≡⟨ cong (flip _∷_ (map just (map (flip lookup (union h h')) is'))) (begin
223       just (lookup i (union h h'))
224         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
225       just (maybe′ id (lookup i h') (lookupM i h))
226         ≡⟨ cong just (cong (maybe′ id (lookup i h')) lookupM-i-h≡just-x) ⟩
227       just (maybe′ id (lookup i h') (just x))
228         ≡⟨ refl ⟩
229       just x
230         ≡⟨ sym lookupM-i-h≡just-x ⟩
231       lookupM i h ∎) ⟩
232   lookupM i h ∷ map just (map (flip lookup (union h h')) is')
233     ≡⟨ cong (_∷_ (lookupM i h)) (lemma-union-not-used h h' is' (Data.List.All.tail p)) ⟩
234   lookupM i h ∷ map (flip lookupM h) is' ∎
235
236 theorem-2 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (v s u : List τ) → bff get eq s v ≡ just u → get u ≡ v
237 theorem-2 get eq v s u p with lemma-fmap-just (assoc eq (get (enumerate s)) v) (proj₂ (lemma-fmap-just (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) v)) p))
238 theorem-2 get eq v s u p | h , ph = begin
239   get u
240     ≡⟨ lemma-from-just (begin
241       just (get u)
242         ≡⟨ refl ⟩
243       fmap get (just u)
244         ≡⟨ cong (fmap get) (sym p) ⟩
245       fmap get (bff get eq s v)
246         ≡⟨ cong (fmap get ∘ fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) ph ⟩
247       fmap get (fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (just h)))
248        ≡⟨ refl ⟩
249      just (get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s)))
250        ∎) ⟩
251   get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s))
252     ≡⟨ free-theorem-list-list get (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s) ⟩
253   map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s))
254      ≡⟨ lemma-from-map-just (begin
255        map just (map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s)))
256          ≡⟨ lemma-union-not-used h (fromFunc (denumerate s)) (get (enumerate s)) (lemma-assoc-domain eq (get (enumerate s)) v h ph) ⟩
257        map (flip lookupM h) (get (enumerate s))
258          ≡⟨ lemma-2 eq (get (enumerate s)) v h ph ⟩
259        map just v
260          ∎) ⟩
261   v ∎