Merge branch view2 into master
[~helmut/bidiragda.git] / Bidir.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Bidir (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
9 open import Data.List using (List)
10 open import Data.List.Any using (Any ; any ; here ; there)
11 open import Data.List.All using (All)
12 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
13 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; fromList ; map ; tabulate) renaming (lookup to lookupVec)
14 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
15 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
16 open import Data.Empty using (⊥-elim)
17 open import Function using (id ; _∘_ ; flip)
18 open import Relation.Nullary using (yes ; no)
19 open import Relation.Binary.Core using (refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; _≗_ ; trans ; cong₂)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 import FreeTheorems
24 open FreeTheorems.VecVec using (get-type ; free-theorem)
25 open import FinMap
26 import CheckInsert
27 open CheckInsert Carrier deq
28 open import BFF using (_>>=_ ; fmap)
29 open BFF.VecBFF Carrier deq using (assoc ; enumerate ; denumerate ; bff)
30
31 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
32 lemma-1 f []        = refl
33 lemma-1 f (i ∷ is′) = begin
34   assoc is′ (map f is′) >>= checkInsert i (f i)
35     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
36   checkInsert i (f i) (restrict f (toList is′))
37     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
38   just (restrict f (toList (i ∷ is′))) ∎
39
40 lemma-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
41 lemma-lookupM-assoc i is x xs h    p with assoc is xs
42 lemma-lookupM-assoc i is x xs h    () | nothing
43 lemma-lookupM-assoc i is x xs h    p | just h' with checkInsert i x h' | insertionresult i x h'
44 lemma-lookupM-assoc i is x xs .h refl | just h | ._ | insert-same pl = pl
45 lemma-lookupM-assoc i is x xs ._ refl | just h' | ._ | insert-new _ = lemma-lookupM-insert i x h'
46 lemma-lookupM-assoc i is x xs h () | just h' | ._ | insert-wrong _ _ _
47
48 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
49 lemma-∉-lookupM-assoc i []         []         .empty refl i∉is = lemma-lookupM-empty i
50 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
51 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
52 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = begin
53   lookupM i h
54     ≡⟨ sym (lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' h ph) ⟩
55   lookupM i h'
56     ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
57   nothing ∎
58
59 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
60 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
61
62 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
63 lemma-assoc-domain []         []         h ph = Data.List.All.[]
64 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
65 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
66 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] with checkInsert i' x' h' | inspect (checkInsert i' x') h' | insertionresult i' x' h'
67 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') .h refl | just h | [ ph' ] | ._ | _ | insert-same pl = All._∷_ (x' , pl) (lemma-assoc-domain is' xs' h ph')
68 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') ._ refl | just h' | [ ph' ] | ._ | [ cI≡ ] | insert-new _ = All._∷_
69   (x' , lemma-lookupM-insert i' x' h')
70   (Data.List.All.map
71     (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' (insert i' x' h') (proj₂ p) cI≡)
72     (lemma-assoc-domain is' xs' h' ph'))
73 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | just h' | [ ph' ] | ._ | _ | insert-wrong _ _ _
74
75 lemma-map-lookupM-insert : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (h : FinMapMaybe n Carrier) → i ∉ (toList is) → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
76 lemma-map-lookupM-insert i []         x h i∉is = refl
77 lemma-map-lookupM-insert i (i' ∷ is') x h i∉is = cong₂ _∷_
78   (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym)))
79   (lemma-map-lookupM-insert i is' x h (i∉is ∘ there))
80
81 lemma-map-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → (h' : FinMapMaybe n Carrier) → assoc is xs ≡ just h' → checkInsert i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
82 lemma-map-lookupM-assoc i is x xs h h' ph' ph with any (_≟_ i) (toList is)
83 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain is xs h' ph') p
84 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
85 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p | (x'' , refl) | .(just x'') with deq x x''
86 lemma-map-lookupM-assoc i is x xs h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
87 lemma-map-lookupM-assoc i is x xs h h' ph' () | yes p | (x'' , refl) | .(just x'') | no p
88 lemma-map-lookupM-assoc i is x xs h h' ph' ph | no ¬p rewrite lemma-∉-lookupM-assoc i is xs h' ph' ¬p = begin
89   map (flip lookupM h) is
90     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (just-injective (sym ph))) is ⟩
91   map (flip lookupM (insert i x h')) is
92     ≡⟨ lemma-map-lookupM-insert i is x h' ¬p ⟩
93   map (flip lookupM h') is ∎
94
95 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → map (flip lookupM h) is ≡ map just v
96 lemma-2 []       []       h p = refl
97 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
98 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
99 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
100   lookupM i h ∷ map (flip lookupM h) is
101     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc i is x xs h (begin
102       assoc (i ∷ is) (x ∷ xs)
103         ≡⟨ cong (flip _>>=_ (checkInsert i x)) ir ⟩
104       checkInsert i x h'
105         ≡⟨ p ⟩
106       just h ∎) ) ⟩
107   just x ∷ map (flip lookupM h) is
108     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i is x xs h h' ir p) ⟩
109   just x ∷ map (flip lookupM h') is
110     ≡⟨ cong (_∷_ (just x)) (lemma-2 is xs h' ir) ⟩
111   just x ∷ map just xs ∎
112
113 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
114 lemma-map-denumerate-enumerate []       = refl
115 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
116   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
117     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
118   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
119     ≡⟨ refl ⟩
120   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
121     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
122   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
123     ≡⟨ refl ⟩
124   map (denumerate as) (enumerate as)
125     ≡⟨ lemma-map-denumerate-enumerate as ⟩
126   as ∎)
127
128 theorem-1 : {getlen : ℕ → ℕ} → (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → bff get s (get s) ≡ just s
129 theorem-1 get s = begin
130   bff get s (get s)
131     ≡⟨ cong (bff get s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
132   bff get s (get (map (denumerate s) (enumerate s)))
133     ≡⟨ cong (bff get s) (free-theorem get (denumerate s) (enumerate s)) ⟩
134   bff get s (map (denumerate s) (get (enumerate s)))
135     ≡⟨ refl ⟩
136   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
137     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
138   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
139     ≡⟨ refl ⟩
140   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (fromFunc (denumerate s)))
141     ≡⟨ cong (h′↦r ∘ just) (lemma-union-restrict (denumerate s) (toList (get (enumerate s)))) ⟩
142   (h′↦r ∘ just) (fromFunc (denumerate s))
143     ≡⟨ refl ⟩
144   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
145     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
146   just (map (denumerate s) (enumerate s))
147     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
148   just s ∎
149     where h↦h′ = fmap (flip union (fromFunc (denumerate s)))
150           h′↦r = fmap (flip map (enumerate s) ∘ flip lookupVec)
151
152 lemma-fmap-just : {A B : Set} {f : A → B} {b : B} {ma : Maybe A} → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
153 lemma-fmap-just {ma = just x}  fmap-f-ma≡just-b = x , refl
154 lemma-fmap-just {ma = nothing} ()
155
156 ∷-injective : {A : Set} {n : ℕ} {x y : A} {xs ys : Vec A n} → (x ∷ xs) ≡ (y ∷ ys) → x ≡ y × xs ≡ ys
157 ∷-injective refl = refl , refl
158
159 map-just-injective : {A : Set} {n : ℕ} {xs ys : Vec A n} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
160 map-just-injective {xs = []}      {ys = []}       p  = refl
161 map-just-injective {xs = x ∷ xs'} {ys = y ∷ ys'}  p with ∷-injective p
162 map-just-injective {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (map-just-injective p')
163
164 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
165 lemma-union-not-used h h' []        p = refl
166 lemma-union-not-used h h' (i ∷ is') (All._∷_ (x , px) p') = cong₂ _∷_ (begin
167       just (lookup i (union h h'))
168         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
169       just (maybe′ id (lookup i h') (lookupM i h))
170         ≡⟨ cong just (cong (maybe′ id (lookup i h')) px) ⟩
171       just (maybe′ id (lookup i h') (just x))
172         ≡⟨ sym px ⟩
173       lookupM i h ∎)
174   (lemma-union-not-used h h' is' p')
175
176 theorem-2 : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (v : Vec Carrier (getlen m)) → (s u : Vec Carrier m) → bff get s v ≡ just u → get u ≡ v
177 theorem-2 get v s u p with lemma-fmap-just (proj₂ (lemma-fmap-just p))
178 theorem-2 get v s u p | h , ph = begin
179   get u
180     ≡⟨ just-injective (begin
181       fmap get (just u)
182         ≡⟨ cong (fmap get) (sym p) ⟩
183       fmap get (bff get s v)
184         ≡⟨ cong (fmap get ∘ fmap h′↦r ∘ fmap h↦h′) ph ⟩
185       fmap get (fmap h′↦r (fmap h↦h′ (just h))) ∎) ⟩
186   get (map (flip lookup (h↦h′ h)) s′)
187     ≡⟨ free-theorem get (flip lookup (h↦h′ h)) s′ ⟩
188   map (flip lookup (h↦h′ h)) (get s′)
189      ≡⟨ map-just-injective (begin
190        map just (map (flip lookup (union h g)) (get s′))
191          ≡⟨ lemma-union-not-used h g (get s′) (lemma-assoc-domain (get s′) v h ph) ⟩
192        map (flip lookupM h) (get s′)
193          ≡⟨ lemma-2 (get s′) v h ph ⟩
194        map just v
195          ∎) ⟩
196   v ∎
197     where s′   = enumerate s
198           g    = fromFunc (denumerate s)
199           h↦h′ = flip union g
200           h′↦r = flip map s′ ∘ flip lookupVec