define a more useful version of lemma-just\==nnothing
[~helmut/bidiragda.git] / Bidir.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Bidir (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
9 open import Data.List using (List)
10 open import Data.List.Any using (Any ; any ; here ; there)
11 open import Data.List.All using (All)
12 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
13 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; fromList ; map ; tabulate) renaming (lookup to lookupVec)
14 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
15 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
16 open import Data.Empty using (⊥-elim)
17 open import Function using (id ; _∘_ ; flip)
18 open import Relation.Nullary using (yes ; no)
19 open import Relation.Binary.Core using (refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; _≗_ ; trans ; cong₂)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 import FreeTheorems
24 open FreeTheorems.VecVec using (get-type ; free-theorem)
25 open import FinMap
26 import CheckInsert
27 open CheckInsert Carrier deq
28 open import BFF using (_>>=_ ; fmap)
29 open BFF.VecBFF Carrier deq using (assoc ; enumerate ; denumerate ; bff)
30
31 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
32 lemma-1 f []        = refl
33 lemma-1 f (i ∷ is′) = begin
34   assoc is′ (map f is′) >>= checkInsert i (f i)
35     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
36   checkInsert i (f i) (restrict f (toList is′))
37     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
38   just (restrict f (toList (i ∷ is′))) ∎
39
40 lemma-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
41 lemma-lookupM-assoc i is x xs h    p with assoc is xs
42 lemma-lookupM-assoc i is x xs h    () | nothing
43 lemma-lookupM-assoc i is x xs h    p | just h' = apply-checkInsertProof i x h' record
44   { same  = λ lookupM≡justx → begin
45       lookupM i h
46         ≡⟨ cong (lookupM i) (just-injective (trans (sym p) (lemma-checkInsert-same i x h' lookupM≡justx))) ⟩
47       lookupM i h'
48         ≡⟨ lookupM≡justx ⟩
49       just x ∎
50   ; new   = λ lookupM≡nothing → begin
51       lookupM i h
52         ≡⟨ cong (lookupM i) (just-injective (trans (sym p) (lemma-checkInsert-new i x h' lookupM≡nothing))) ⟩
53       lookupM i (insert i x h')
54         ≡⟨ lemma-lookupM-insert i x h' ⟩
55       just x ∎
56   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing p (lemma-checkInsert-wrong i x h' x' x≢x' lookupM≡justx')
57   }
58
59 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
60 lemma-∉-lookupM-assoc i []         []         .empty refl i∉is = lemma-lookupM-empty i
61 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
62 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
63 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = begin
64   lookupM i h
65     ≡⟨ sym (lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' h ph) ⟩
66   lookupM i h'
67     ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
68   nothing ∎
69
70 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
71 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
72
73 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
74 lemma-assoc-domain []         []         h ph = Data.List.All.[]
75 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
76 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
77 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] = apply-checkInsertProof i' x' h' record {
78     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
79       (x' , (trans (cong (lookupM i') (just-injective (trans (sym ph) (lemma-checkInsert-same i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
80       (lemma-assoc-domain is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same i' x' h' lookupM-i'-h'≡just-x')) ph)))
81   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
82       (x' , (trans (cong (lookupM i') (just-injective (trans (sym ph) (lemma-checkInsert-new i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
83       (Data.List.All.map
84         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' h (proj₂ p) ph)
85         (lemma-assoc-domain is' xs' h' ph'))
86   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing ph (lemma-checkInsert-wrong i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x'')
87   }
88
89 lemma-map-lookupM-insert : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (h : FinMapMaybe n Carrier) → i ∉ (toList is) → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
90 lemma-map-lookupM-insert i []         x h i∉is = refl
91 lemma-map-lookupM-insert i (i' ∷ is') x h i∉is = cong₂ _∷_
92   (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym)))
93   (lemma-map-lookupM-insert i is' x h (i∉is ∘ there))
94
95 lemma-map-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → (h' : FinMapMaybe n Carrier) → assoc is xs ≡ just h' → checkInsert i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
96 lemma-map-lookupM-assoc i is x xs h h' ph' ph with any (_≟_ i) (toList is)
97 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain is xs h' ph') p
98 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
99 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p | (x'' , refl) | .(just x'') with deq x x''
100 lemma-map-lookupM-assoc i is x xs h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
101 lemma-map-lookupM-assoc i is x xs h h' ph' () | yes p | (x'' , refl) | .(just x'') | no p
102 lemma-map-lookupM-assoc i is x xs h h' ph' ph | no ¬p rewrite lemma-∉-lookupM-assoc i is xs h' ph' ¬p = begin
103   map (flip lookupM h) is
104     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (just-injective (sym ph))) is ⟩
105   map (flip lookupM (insert i x h')) is
106     ≡⟨ lemma-map-lookupM-insert i is x h' ¬p ⟩
107   map (flip lookupM h') is ∎
108
109 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → map (flip lookupM h) is ≡ map just v
110 lemma-2 []       []       h p = refl
111 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
112 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
113 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
114   lookupM i h ∷ map (flip lookupM h) is
115     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc i is x xs h (begin
116       assoc (i ∷ is) (x ∷ xs)
117         ≡⟨ cong (flip _>>=_ (checkInsert i x)) ir ⟩
118       checkInsert i x h'
119         ≡⟨ p ⟩
120       just h ∎) ) ⟩
121   just x ∷ map (flip lookupM h) is
122     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i is x xs h h' ir p) ⟩
123   just x ∷ map (flip lookupM h') is
124     ≡⟨ cong (_∷_ (just x)) (lemma-2 is xs h' ir) ⟩
125   just x ∷ map just xs ∎
126
127 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
128 lemma-map-denumerate-enumerate []       = refl
129 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
130   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
131     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
132   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
133     ≡⟨ refl ⟩
134   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
135     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
136   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
137     ≡⟨ refl ⟩
138   map (denumerate as) (enumerate as)
139     ≡⟨ lemma-map-denumerate-enumerate as ⟩
140   as ∎)
141
142 theorem-1 : {getlen : ℕ → ℕ} → (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → bff get s (get s) ≡ just s
143 theorem-1 get s = begin
144   bff get s (get s)
145     ≡⟨ cong (bff get s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
146   bff get s (get (map (denumerate s) (enumerate s)))
147     ≡⟨ cong (bff get s) (free-theorem get (denumerate s) (enumerate s)) ⟩
148   bff get s (map (denumerate s) (get (enumerate s)))
149     ≡⟨ refl ⟩
150   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
151     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
152   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
153     ≡⟨ refl ⟩
154   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (fromFunc (denumerate s)))
155     ≡⟨ cong (h′↦r ∘ just) (lemma-union-restrict (denumerate s) (toList (get (enumerate s)))) ⟩
156   (h′↦r ∘ just) (fromFunc (denumerate s))
157     ≡⟨ refl ⟩
158   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
159     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
160   just (map (denumerate s) (enumerate s))
161     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
162   just s ∎
163     where h↦h′ = fmap (flip union (fromFunc (denumerate s)))
164           h′↦r = fmap (flip map (enumerate s) ∘ flip lookupVec)
165
166 lemma-fmap-just : {A B : Set} {f : A → B} {b : B} {ma : Maybe A} → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
167 lemma-fmap-just {ma = just x}  fmap-f-ma≡just-b = x , refl
168 lemma-fmap-just {ma = nothing} ()
169
170 ∷-injective : {A : Set} {n : ℕ} {x y : A} {xs ys : Vec A n} → (x ∷ xs) ≡ (y ∷ ys) → x ≡ y × xs ≡ ys
171 ∷-injective refl = refl , refl
172
173 map-just-injective : {A : Set} {n : ℕ} {xs ys : Vec A n} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
174 map-just-injective {xs = []}      {ys = []}       p  = refl
175 map-just-injective {xs = x ∷ xs'} {ys = y ∷ ys'}  p with ∷-injective p
176 map-just-injective {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (map-just-injective p')
177
178 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
179 lemma-union-not-used h h' []        p = refl
180 lemma-union-not-used h h' (i ∷ is') p with Data.List.All.head p
181 lemma-union-not-used h h' (i ∷ is') p | x , lookupM-i-h≡just-x = cong₂ _∷_ (begin
182       just (lookup i (union h h'))
183         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
184       just (maybe′ id (lookup i h') (lookupM i h))
185         ≡⟨ cong just (cong (maybe′ id (lookup i h')) lookupM-i-h≡just-x) ⟩
186       just (maybe′ id (lookup i h') (just x))
187         ≡⟨ refl ⟩
188       just x
189         ≡⟨ sym lookupM-i-h≡just-x ⟩
190       lookupM i h ∎)
191   (lemma-union-not-used h h' is' (Data.List.All.tail p))
192
193 theorem-2 : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (v : Vec Carrier (getlen m)) → (s u : Vec Carrier m) → bff get s v ≡ just u → get u ≡ v
194 theorem-2 get v s u p with lemma-fmap-just (proj₂ (lemma-fmap-just p))
195 theorem-2 get v s u p | h , ph = begin
196   get u
197     ≡⟨ just-injective (begin
198       fmap get (just u)
199         ≡⟨ cong (fmap get) (sym p) ⟩
200       fmap get (bff get s v)
201         ≡⟨ cong (fmap get ∘ fmap h′↦r ∘ fmap h↦h′) ph ⟩
202       fmap get (fmap h′↦r (fmap h↦h′ (just h))) ∎) ⟩
203   get (map (flip lookup (h↦h′ h)) s′)
204     ≡⟨ free-theorem get (flip lookup (h↦h′ h)) s′ ⟩
205   map (flip lookup (h↦h′ h)) (get s′)
206      ≡⟨ map-just-injective (begin
207        map just (map (flip lookup (union h g)) (get s′))
208          ≡⟨ lemma-union-not-used h g (get s′) (lemma-assoc-domain (get s′) v h ph) ⟩
209        map (flip lookupM h) (get s′)
210          ≡⟨ lemma-2 (get s′) v h ph ⟩
211        map just v
212          ∎) ⟩
213   v ∎
214     where s′   = enumerate s
215           g    = fromFunc (denumerate s)
216           h↦h′ = flip union g
217           h′↦r = flip map s′ ∘ flip lookupVec