move checkInsert and related properties to CheckInsert.agda
[~helmut/bidiragda.git] / Bidir.agda
1 module Bidir where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Data.Fin.Props using (_≟_)
6 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
7 open import Data.List using (List ; [] ; _∷_ ; map ; length)
8 open import Data.List.Properties using (map-cong ; ∷-injective) renaming (map-compose to map-∘)
9 open import Data.List.Any using (Any ; any ; here ; there)
10 open import Data.List.All using (All)
11 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
12 open import Data.Vec using (toList ; fromList ; tabulate) renaming (lookup to lookupVec ; _∷_ to _∷V_)
13 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate)
14 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
15 open import Data.Empty using (⊥-elim)
16 open import Function using (id ; _∘_ ; flip)
17 open import Relation.Nullary using (yes ; no ; _)
18 open import Relation.Nullary.Negation using (contradiction)
19 open import Relation.Binary.Core using (_≡_ ; refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; Reveal_is_ ; _≗_ ; trans)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 open import FinMap
24 open import CheckInsert
25
26 _>>=_ : {A B : Set} → Maybe A → (A → Maybe B) → Maybe B
27 _>>=_ = flip (flip maybe′ nothing)
28
29 fmap : {A B : Set} → (A → B) → Maybe A → Maybe B
30 fmap f = maybe′ (λ a → just (f a)) nothing
31
32 assoc : {A : Set} {n : ℕ} → EqInst A → List (Fin n) → List A → Maybe (FinMapMaybe n A)
33 assoc _  []       []       = just empty
34 assoc eq (i ∷ is) (b ∷ bs) = (assoc eq is bs) >>= (checkInsert eq i b)
35 assoc _  _        _        = nothing
36
37 lemma-1 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (is : List (Fin n)) → assoc eq is (map f is) ≡ just (restrict f is)
38 lemma-1 eq f []        = refl
39 lemma-1 eq f (i ∷ is′) = begin
40   assoc eq (i ∷ is′) (map f (i ∷ is′))
41     ≡⟨ refl ⟩
42   assoc eq is′ (map f is′) >>= checkInsert eq i (f i)
43     ≡⟨ cong (λ m → m >>= checkInsert eq i (f i)) (lemma-1 eq f is′) ⟩
44   just (restrict f is′) >>= (checkInsert eq i (f i))
45     ≡⟨ refl ⟩
46   checkInsert eq i (f i) (restrict f is′)
47     ≡⟨ lemma-checkInsert-restrict eq f i is′ ⟩
48   just (restrict f (i ∷ is′)) ∎
49
50 lemma-lookupM-assoc : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
51 lemma-lookupM-assoc eq i is x xs h    p with assoc eq is xs
52 lemma-lookupM-assoc eq i is x xs h    () | nothing
53 lemma-lookupM-assoc eq i is x xs h    p | just h' = apply-checkInsertProof eq i x h' record
54   { same  = λ lookupM≡justx → begin
55       lookupM i h
56         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-same eq i x h' lookupM≡justx))) ⟩
57       lookupM i h'
58         ≡⟨ lookupM≡justx ⟩
59       just x ∎
60   ; new   = λ lookupM≡nothing → begin
61       lookupM i h
62         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-new eq i x h' lookupM≡nothing))) ⟩
63       lookupM i (insert i x h')
64         ≡⟨ lemma-lookupM-insert i x h' ⟩
65       just x ∎
66   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing (trans (sym p) (lemma-checkInsert-wrong eq i x h' x' x≢x' lookupM≡justx'))
67   }
68
69 lemma-∉-lookupM-assoc : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → (i ∉ is) → lookupM i h ≡ nothing
70 lemma-∉-lookupM-assoc eq i []         []         h ph i∉is = begin
71   lookupM i h
72     ≡⟨ cong (lookupM i) (sym (lemma-from-just ph)) ⟩
73   lookupM i empty
74     ≡⟨ lemma-lookupM-empty i ⟩
75   nothing ∎
76 lemma-∉-lookupM-assoc eq i []         (x' ∷ xs') h () i∉is
77 lemma-∉-lookupM-assoc eq i (i' ∷ is') []         h () i∉is
78 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is with i ≟ i'
79 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | yes p = contradiction (here p) i∉is
80 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | no ¬p with assoc eq is' xs' | inspect (assoc eq is') xs'
81 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h () i∉is | no ¬p | nothing | Reveal_is_.[_] ph'
82 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | no ¬p | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
83     same = λ lookupM-i'-h'≡just-x' → begin
84       lookupM i h
85         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x'))) ⟩
86       lookupM i h'
87         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
88       nothing ∎
89   ; new = λ lookupM-i'-h'≡nothing → begin
90       lookupM i h
91         ≡⟨ cong (lookupM i)  (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing))) ⟩
92       lookupM i (insert i' x' h')
93         ≡⟨ sym (lemma-lookupM-insert-other i i' x' h' ¬p) ⟩
94       lookupM i h'
95         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
96       nothing ∎
97   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
98   }
99
100 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
101 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
102
103 lemma-assoc-domain : {n : ℕ} {A : Set} → (eq : EqInst A) → (is : List (Fin n)) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → is in-domain-of h
104 lemma-assoc-domain eq []  []  h  ph  = Data.List.All.[]
105 lemma-assoc-domain eq [] (x' ∷ xs') h ()
106 lemma-assoc-domain eq (i' ∷ is') [] h ()
107 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph with assoc eq is' xs' | inspect (assoc eq is') xs'
108 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h () | nothing | ph'
109 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
110     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
111       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
112       (lemma-assoc-domain eq is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')) ph)))
113   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
114       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
115       (Data.List.All.map
116         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert eq i i' (proj₁ p) x' h' h (proj₂ p) ph)
117         (lemma-assoc-domain eq is' xs' h' ph'))
118   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
119   }
120
121 lemma-map-lookupM-insert : {n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (h : FinMapMaybe n A) → ¬(i ∈ is) → is in-domain-of h → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
122 lemma-map-lookupM-insert eq i []         x h i∉is ph = refl
123 lemma-map-lookupM-insert eq i (i' ∷ is') x h i∉is ph = begin
124   lookupM i' (insert i x h) ∷ map (flip lookupM (insert i x h)) is'
125     ≡⟨ cong (flip _∷_ (map (flip lookupM (insert i x h)) is')) (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym))) ⟩
126   lookupM i' h ∷ map (flip lookupM (insert i x h)) is'
127     ≡⟨ cong (_∷_ (lookupM i' h)) (lemma-map-lookupM-insert eq i is' x h (i∉is ∘ there) (Data.List.All.tail ph)) ⟩
128   lookupM i' h ∷ map (flip lookupM h) is' ∎
129
130 lemma-map-lookupM-assoc : {n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (xs : List A) → (h : FinMapMaybe n A) → (h' : FinMapMaybe n A) → assoc eq is xs ≡ just h' → checkInsert eq i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
131 lemma-map-lookupM-assoc eq i []         x []         h h' ph' ph = refl
132 lemma-map-lookupM-assoc eq i []         x (x' ∷ xs') h h' ()  ph
133 lemma-map-lookupM-assoc eq i (i' ∷ is') x []         h h' ()  ph
134 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph with any (_≟_ i) (i' ∷ is')
135 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') p
136 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
137 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , refl) | .(just x'') with eq x x''
138 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
139 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' () | yes p | (x'' , refl) | .(just x'') | no ¬p
140 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p with lookupM i h' | lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h' ph' ¬p
141 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p | .nothing | refl = begin
142   map (flip lookupM h) (i' ∷ is')
143     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (lemma-from-just (sym ph))) (i' ∷ is') ⟩
144   map (flip lookupM (insert i x h')) (i' ∷ is')
145     ≡⟨ lemma-map-lookupM-insert eq i (i' ∷ is') x h' ¬p (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') ⟩
146   map (flip lookupM h') (i' ∷ is') ∎
147
148 lemma-2 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (is : List (Fin n)) → (v : List τ) → (h : FinMapMaybe n τ) → assoc eq is v ≡ just h → map (flip lookupM h) is ≡ map just v
149 lemma-2 eq []       []       h p = refl
150 lemma-2 eq []       (x ∷ xs) h ()
151 lemma-2 eq (x ∷ xs) []       h ()
152 lemma-2 eq (i ∷ is) (x ∷ xs) h p with assoc eq is xs | inspect (assoc eq is) xs
153 lemma-2 eq (i ∷ is) (x ∷ xs) h () | nothing | _
154 lemma-2 eq (i ∷ is) (x ∷ xs) h p | just h' | Reveal_is_.[_] ir = begin
155   map (flip lookupM h) (i ∷ is)
156     ≡⟨ refl ⟩
157   lookupM i h ∷ map (flip lookupM h) is
158     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc eq i is x xs h (begin
159       assoc eq (i ∷ is) (x ∷ xs)
160         ≡⟨ cong (flip _>>=_ (checkInsert eq i x)) ir ⟩
161       checkInsert eq i x h'
162         ≡⟨ p ⟩
163       just h ∎) ) ⟩
164   just x ∷ map (flip lookupM h) is
165     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc eq i is x xs h h' ir p) ⟩
166   just x ∷ map (flip lookupM h') is
167     ≡⟨ cong (_∷_ (just x)) (lemma-2 eq is xs h' ir) ⟩
168   just x ∷ map just xs
169     ≡⟨ refl ⟩
170   map just (x ∷ xs) ∎
171
172 enumerate : {A : Set} → (l : List A) → List (Fin (length l))
173 enumerate l = toList (tabulate id)
174
175 denumerate : {A : Set} (l : List A) → Fin (length l) → A
176 denumerate l = flip lookupVec (fromList l)
177
178 bff : ({A : Set} → List A → List A) → ({B : Set} → EqInst B → List B → List B → Maybe (List B))
179 bff get eq s v = let s′ = enumerate s
180                      g  = fromFunc (denumerate s)
181                      h  = assoc eq (get s′) v
182                      h′ = fmap (flip union g) h
183                  in fmap (flip map s′ ∘ flip lookup) h′
184
185 postulate
186   free-theorem-list-list : {β γ : Set} → (get : {α : Set} → List α → List α) → (f : β → γ) → get ∘ map f ≗ map f ∘ get
187
188 toList-map-commutes : {A B : Set} {n : ℕ} → (f : A → B) → (v : Data.Vec.Vec A n) → (toList (Data.Vec.map f v)) ≡ map f (toList v)
189 toList-map-commutes f Data.Vec.[] = refl
190 toList-map-commutes f (x ∷V xs) = cong (_∷_ (f x)) (toList-map-commutes f xs)
191
192 lemma-map-denumerate-enumerate : {A : Set} → (as : List A) → map (denumerate as) (enumerate as) ≡ as
193 lemma-map-denumerate-enumerate [] = refl
194 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
195   map (flip lookupVec (a ∷V (fromList as))) (toList (tabulate Fin.suc))
196     ≡⟨ cong (map (flip lookupVec (a ∷V (fromList as))) ∘ toList) (tabulate-∘ Fin.suc id) ⟩
197   map (flip lookupVec (a ∷V (fromList as))) (toList (Data.Vec.map Fin.suc (tabulate id)))
198     ≡⟨ cong (map (flip lookupVec (a ∷V fromList as))) (toList-map-commutes Data.Fin.suc (tabulate id)) ⟩
199   map (flip lookupVec (a ∷V fromList as)) (map Fin.suc (enumerate as))
200     ≡⟨ sym (map-∘ (enumerate as)) ⟩
201   map (flip lookupVec (a ∷V (fromList as)) ∘ Fin.suc) (enumerate as)
202     ≡⟨ refl ⟩
203   map (denumerate as) (enumerate as)
204     ≡⟨ lemma-map-denumerate-enumerate as ⟩
205   as ∎)
206
207 theorem-1 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (s : List τ) → bff get eq s (get s) ≡ just s
208 theorem-1 get eq s = begin
209   bff get eq s (get s)
210     ≡⟨ cong (bff get eq s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
211   bff get eq s (get (map (denumerate s) (enumerate s)))
212     ≡⟨ cong (bff get eq s) (free-theorem-list-list get (denumerate s) (enumerate s)) ⟩
213   bff get eq s (map (denumerate s) (get (enumerate s)))
214     ≡⟨ refl ⟩
215   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) (map (denumerate s) (get (enumerate s)))))
216     ≡⟨ cong (fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) (lemma-1 eq (denumerate s) (get (enumerate s))) ⟩
217   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (flip lookupVec (fromList s)))) (just (restrict (denumerate s) (get (enumerate s)))))
218     ≡⟨ refl ⟩
219   just ((flip map (enumerate s) ∘ flip lookup) (union (restrict (denumerate s) (get (enumerate s))) (fromFunc (denumerate s))))
220     ≡⟨ cong just (cong (flip map (enumerate s) ∘ flip lookup) (lemma-union-restrict (denumerate s) (get (enumerate s)))) ⟩
221   just ((flip map (enumerate s) ∘ flip lookup) (fromFunc (denumerate s)))
222     ≡⟨ refl ⟩
223   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
224     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
225   just (map (denumerate s) (enumerate s))
226     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
227   just s ∎
228
229 lemma-fmap-just : {A B : Set} → {f : A → B} {b : B} → (ma : Maybe A) → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
230 lemma-fmap-just (just x) fmap-f-ma≡just-b = x , refl
231 lemma-fmap-just nothing  ()
232
233 lemma-from-map-just : {A : Set} → {xs ys : List A} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
234 lemma-from-map-just {xs = []}      {ys = []}      p  = refl
235 lemma-from-map-just {xs = []}      {ys = y ∷ ys'} ()
236 lemma-from-map-just {xs = x ∷ xs'} {ys = []}      ()
237 lemma-from-map-just {xs = x ∷ xs'} {ys = y ∷ ys'} p with ∷-injective p
238 lemma-from-map-just {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (lemma-from-map-just p')
239
240 lemma-union-not-used : {n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : List (Fin n)) → is in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
241 lemma-union-not-used h h' []        p = refl
242 lemma-union-not-used h h' (i ∷ is') p with Data.List.All.head p
243 lemma-union-not-used h h' (i ∷ is') p | x , lookupM-i-h≡just-x = begin
244   just (lookup i (union h h')) ∷ map just (map (flip lookup (union h h')) is')
245     ≡⟨ cong (flip _∷_ (map just (map (flip lookup (union h h')) is'))) (begin
246       just (lookup i (union h h'))
247         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
248       just (maybe′ id (lookup i h') (lookupM i h))
249         ≡⟨ cong just (cong (maybe′ id (lookup i h')) lookupM-i-h≡just-x) ⟩
250       just (maybe′ id (lookup i h') (just x))
251         ≡⟨ refl ⟩
252       just x
253         ≡⟨ sym lookupM-i-h≡just-x ⟩
254       lookupM i h ∎) ⟩
255   lookupM i h ∷ map just (map (flip lookup (union h h')) is')
256     ≡⟨ cong (_∷_ (lookupM i h)) (lemma-union-not-used h h' is' (Data.List.All.tail p)) ⟩
257   lookupM i h ∷ map (flip lookupM h) is' ∎
258
259 theorem-2 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (v s u : List τ) → bff get eq s v ≡ just u → get u ≡ v
260 theorem-2 get eq v s u p with lemma-fmap-just (assoc eq (get (enumerate s)) v) (proj₂ (lemma-fmap-just (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) v)) p))
261 theorem-2 get eq v s u p | h , ph = begin
262   get u
263     ≡⟨ lemma-from-just (begin
264       just (get u)
265         ≡⟨ refl ⟩
266       fmap get (just u)
267         ≡⟨ cong (fmap get) (sym p) ⟩
268       fmap get (bff get eq s v)
269         ≡⟨ cong (fmap get ∘ fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) ph ⟩
270       fmap get (fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (just h)))
271        ≡⟨ refl ⟩
272      just (get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s)))
273        ∎) ⟩
274   get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s))
275     ≡⟨ free-theorem-list-list get (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s) ⟩
276   map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s))
277      ≡⟨ lemma-from-map-just (begin
278        map just (map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s)))
279          ≡⟨ lemma-union-not-used h (fromFunc (denumerate s)) (get (enumerate s)) (lemma-assoc-domain eq (get (enumerate s)) v h ph) ⟩
280        map (flip lookupM h) (get (enumerate s))
281          ≡⟨ lemma-2 eq (get (enumerate s)) v h ph ⟩
282        map just v
283          ∎) ⟩
284   v ∎