move bff and friends to submodule ListBFF
[~helmut/bidiragda.git] / Bidir.agda
1 module Bidir where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Data.Fin.Props using (_≟_)
6 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
7 open import Data.List using (List ; [] ; _∷_ ; map ; length)
8 open import Data.List.Properties using (map-cong ; ∷-injective) renaming (map-compose to map-∘)
9 open import Data.List.Any using (Any ; any ; here ; there)
10 open import Data.List.All using (All)
11 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
12 open import Data.Vec using (toList ; fromList ; tabulate) renaming (lookup to lookupVec ; _∷_ to _∷V_)
13 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate)
14 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
15 open import Data.Empty using (⊥-elim)
16 open import Function using (id ; _∘_ ; flip)
17 open import Relation.Nullary using (yes ; no ; _)
18 open import Relation.Nullary.Negation using (contradiction)
19 open import Relation.Binary.Core using (_≡_ ; refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; Reveal_is_ ; _≗_ ; trans)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 open import FinMap
24 open import CheckInsert
25
26 open import BFF using (_>>=_ ; fmap)
27
28 open BFF.ListBFF using (assoc ; enumerate ; denumerate ; bff)
29
30 lemma-1 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (is : List (Fin n)) → assoc eq is (map f is) ≡ just (restrict f is)
31 lemma-1 eq f []        = refl
32 lemma-1 eq f (i ∷ is′) = begin
33   assoc eq (i ∷ is′) (map f (i ∷ is′))
34     ≡⟨ refl ⟩
35   assoc eq is′ (map f is′) >>= checkInsert eq i (f i)
36     ≡⟨ cong (λ m → m >>= checkInsert eq i (f i)) (lemma-1 eq f is′) ⟩
37   just (restrict f is′) >>= (checkInsert eq i (f i))
38     ≡⟨ refl ⟩
39   checkInsert eq i (f i) (restrict f is′)
40     ≡⟨ lemma-checkInsert-restrict eq f i is′ ⟩
41   just (restrict f (i ∷ is′)) ∎
42
43 lemma-lookupM-assoc : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
44 lemma-lookupM-assoc eq i is x xs h    p with assoc eq is xs
45 lemma-lookupM-assoc eq i is x xs h    () | nothing
46 lemma-lookupM-assoc eq i is x xs h    p | just h' = apply-checkInsertProof eq i x h' record
47   { same  = λ lookupM≡justx → begin
48       lookupM i h
49         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-same eq i x h' lookupM≡justx))) ⟩
50       lookupM i h'
51         ≡⟨ lookupM≡justx ⟩
52       just x ∎
53   ; new   = λ lookupM≡nothing → begin
54       lookupM i h
55         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-new eq i x h' lookupM≡nothing))) ⟩
56       lookupM i (insert i x h')
57         ≡⟨ lemma-lookupM-insert i x h' ⟩
58       just x ∎
59   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing (trans (sym p) (lemma-checkInsert-wrong eq i x h' x' x≢x' lookupM≡justx'))
60   }
61
62 lemma-∉-lookupM-assoc : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → (i ∉ is) → lookupM i h ≡ nothing
63 lemma-∉-lookupM-assoc eq i []         []         h ph i∉is = begin
64   lookupM i h
65     ≡⟨ cong (lookupM i) (sym (lemma-from-just ph)) ⟩
66   lookupM i empty
67     ≡⟨ lemma-lookupM-empty i ⟩
68   nothing ∎
69 lemma-∉-lookupM-assoc eq i []         (x' ∷ xs') h () i∉is
70 lemma-∉-lookupM-assoc eq i (i' ∷ is') []         h () i∉is
71 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is with i ≟ i'
72 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | yes p = contradiction (here p) i∉is
73 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | no ¬p with assoc eq is' xs' | inspect (assoc eq is') xs'
74 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h () i∉is | no ¬p | nothing | Reveal_is_.[_] ph'
75 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | no ¬p | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
76     same = λ lookupM-i'-h'≡just-x' → begin
77       lookupM i h
78         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x'))) ⟩
79       lookupM i h'
80         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
81       nothing ∎
82   ; new = λ lookupM-i'-h'≡nothing → begin
83       lookupM i h
84         ≡⟨ cong (lookupM i)  (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing))) ⟩
85       lookupM i (insert i' x' h')
86         ≡⟨ sym (lemma-lookupM-insert-other i i' x' h' ¬p) ⟩
87       lookupM i h'
88         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
89       nothing ∎
90   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
91   }
92
93 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
94 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
95
96 lemma-assoc-domain : {n : ℕ} {A : Set} → (eq : EqInst A) → (is : List (Fin n)) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → is in-domain-of h
97 lemma-assoc-domain eq []  []  h  ph  = Data.List.All.[]
98 lemma-assoc-domain eq [] (x' ∷ xs') h ()
99 lemma-assoc-domain eq (i' ∷ is') [] h ()
100 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph with assoc eq is' xs' | inspect (assoc eq is') xs'
101 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h () | nothing | ph'
102 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
103     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
104       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
105       (lemma-assoc-domain eq is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')) ph)))
106   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
107       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
108       (Data.List.All.map
109         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert eq i i' (proj₁ p) x' h' h (proj₂ p) ph)
110         (lemma-assoc-domain eq is' xs' h' ph'))
111   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
112   }
113
114 lemma-map-lookupM-insert : {n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (h : FinMapMaybe n A) → ¬(i ∈ is) → is in-domain-of h → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
115 lemma-map-lookupM-insert eq i []         x h i∉is ph = refl
116 lemma-map-lookupM-insert eq i (i' ∷ is') x h i∉is ph = begin
117   lookupM i' (insert i x h) ∷ map (flip lookupM (insert i x h)) is'
118     ≡⟨ cong (flip _∷_ (map (flip lookupM (insert i x h)) is')) (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym))) ⟩
119   lookupM i' h ∷ map (flip lookupM (insert i x h)) is'
120     ≡⟨ cong (_∷_ (lookupM i' h)) (lemma-map-lookupM-insert eq i is' x h (i∉is ∘ there) (Data.List.All.tail ph)) ⟩
121   lookupM i' h ∷ map (flip lookupM h) is' ∎
122
123 lemma-map-lookupM-assoc : {n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (xs : List A) → (h : FinMapMaybe n A) → (h' : FinMapMaybe n A) → assoc eq is xs ≡ just h' → checkInsert eq i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
124 lemma-map-lookupM-assoc eq i []         x []         h h' ph' ph = refl
125 lemma-map-lookupM-assoc eq i []         x (x' ∷ xs') h h' ()  ph
126 lemma-map-lookupM-assoc eq i (i' ∷ is') x []         h h' ()  ph
127 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph with any (_≟_ i) (i' ∷ is')
128 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') p
129 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
130 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , refl) | .(just x'') with eq x x''
131 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
132 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' () | yes p | (x'' , refl) | .(just x'') | no ¬p
133 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p with lookupM i h' | lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h' ph' ¬p
134 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p | .nothing | refl = begin
135   map (flip lookupM h) (i' ∷ is')
136     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (lemma-from-just (sym ph))) (i' ∷ is') ⟩
137   map (flip lookupM (insert i x h')) (i' ∷ is')
138     ≡⟨ lemma-map-lookupM-insert eq i (i' ∷ is') x h' ¬p (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') ⟩
139   map (flip lookupM h') (i' ∷ is') ∎
140
141 lemma-2 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (is : List (Fin n)) → (v : List τ) → (h : FinMapMaybe n τ) → assoc eq is v ≡ just h → map (flip lookupM h) is ≡ map just v
142 lemma-2 eq []       []       h p = refl
143 lemma-2 eq []       (x ∷ xs) h ()
144 lemma-2 eq (x ∷ xs) []       h ()
145 lemma-2 eq (i ∷ is) (x ∷ xs) h p with assoc eq is xs | inspect (assoc eq is) xs
146 lemma-2 eq (i ∷ is) (x ∷ xs) h () | nothing | _
147 lemma-2 eq (i ∷ is) (x ∷ xs) h p | just h' | Reveal_is_.[_] ir = begin
148   map (flip lookupM h) (i ∷ is)
149     ≡⟨ refl ⟩
150   lookupM i h ∷ map (flip lookupM h) is
151     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc eq i is x xs h (begin
152       assoc eq (i ∷ is) (x ∷ xs)
153         ≡⟨ cong (flip _>>=_ (checkInsert eq i x)) ir ⟩
154       checkInsert eq i x h'
155         ≡⟨ p ⟩
156       just h ∎) ) ⟩
157   just x ∷ map (flip lookupM h) is
158     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc eq i is x xs h h' ir p) ⟩
159   just x ∷ map (flip lookupM h') is
160     ≡⟨ cong (_∷_ (just x)) (lemma-2 eq is xs h' ir) ⟩
161   just x ∷ map just xs
162     ≡⟨ refl ⟩
163   map just (x ∷ xs) ∎
164
165 postulate
166   free-theorem-list-list : {β γ : Set} → (get : {α : Set} → List α → List α) → (f : β → γ) → get ∘ map f ≗ map f ∘ get
167
168 toList-map-commutes : {A B : Set} {n : ℕ} → (f : A → B) → (v : Data.Vec.Vec A n) → (toList (Data.Vec.map f v)) ≡ map f (toList v)
169 toList-map-commutes f Data.Vec.[] = refl
170 toList-map-commutes f (x ∷V xs) = cong (_∷_ (f x)) (toList-map-commutes f xs)
171
172 lemma-map-denumerate-enumerate : {A : Set} → (as : List A) → map (denumerate as) (enumerate as) ≡ as
173 lemma-map-denumerate-enumerate [] = refl
174 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
175   map (flip lookupVec (a ∷V (fromList as))) (toList (tabulate Fin.suc))
176     ≡⟨ cong (map (flip lookupVec (a ∷V (fromList as))) ∘ toList) (tabulate-∘ Fin.suc id) ⟩
177   map (flip lookupVec (a ∷V (fromList as))) (toList (Data.Vec.map Fin.suc (tabulate id)))
178     ≡⟨ cong (map (flip lookupVec (a ∷V fromList as))) (toList-map-commutes Data.Fin.suc (tabulate id)) ⟩
179   map (flip lookupVec (a ∷V fromList as)) (map Fin.suc (enumerate as))
180     ≡⟨ sym (map-∘ (enumerate as)) ⟩
181   map (flip lookupVec (a ∷V (fromList as)) ∘ Fin.suc) (enumerate as)
182     ≡⟨ refl ⟩
183   map (denumerate as) (enumerate as)
184     ≡⟨ lemma-map-denumerate-enumerate as ⟩
185   as ∎)
186
187 theorem-1 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (s : List τ) → bff get eq s (get s) ≡ just s
188 theorem-1 get eq s = begin
189   bff get eq s (get s)
190     ≡⟨ cong (bff get eq s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
191   bff get eq s (get (map (denumerate s) (enumerate s)))
192     ≡⟨ cong (bff get eq s) (free-theorem-list-list get (denumerate s) (enumerate s)) ⟩
193   bff get eq s (map (denumerate s) (get (enumerate s)))
194     ≡⟨ refl ⟩
195   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) (map (denumerate s) (get (enumerate s)))))
196     ≡⟨ cong (fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) (lemma-1 eq (denumerate s) (get (enumerate s))) ⟩
197   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (flip lookupVec (fromList s)))) (just (restrict (denumerate s) (get (enumerate s)))))
198     ≡⟨ refl ⟩
199   just ((flip map (enumerate s) ∘ flip lookup) (union (restrict (denumerate s) (get (enumerate s))) (fromFunc (denumerate s))))
200     ≡⟨ cong just (cong (flip map (enumerate s) ∘ flip lookup) (lemma-union-restrict (denumerate s) (get (enumerate s)))) ⟩
201   just ((flip map (enumerate s) ∘ flip lookup) (fromFunc (denumerate s)))
202     ≡⟨ refl ⟩
203   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
204     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
205   just (map (denumerate s) (enumerate s))
206     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
207   just s ∎
208
209 lemma-fmap-just : {A B : Set} → {f : A → B} {b : B} → (ma : Maybe A) → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
210 lemma-fmap-just (just x) fmap-f-ma≡just-b = x , refl
211 lemma-fmap-just nothing  ()
212
213 lemma-from-map-just : {A : Set} → {xs ys : List A} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
214 lemma-from-map-just {xs = []}      {ys = []}      p  = refl
215 lemma-from-map-just {xs = []}      {ys = y ∷ ys'} ()
216 lemma-from-map-just {xs = x ∷ xs'} {ys = []}      ()
217 lemma-from-map-just {xs = x ∷ xs'} {ys = y ∷ ys'} p with ∷-injective p
218 lemma-from-map-just {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (lemma-from-map-just p')
219
220 lemma-union-not-used : {n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : List (Fin n)) → is in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
221 lemma-union-not-used h h' []        p = refl
222 lemma-union-not-used h h' (i ∷ is') p with Data.List.All.head p
223 lemma-union-not-used h h' (i ∷ is') p | x , lookupM-i-h≡just-x = begin
224   just (lookup i (union h h')) ∷ map just (map (flip lookup (union h h')) is')
225     ≡⟨ cong (flip _∷_ (map just (map (flip lookup (union h h')) is'))) (begin
226       just (lookup i (union h h'))
227         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
228       just (maybe′ id (lookup i h') (lookupM i h))
229         ≡⟨ cong just (cong (maybe′ id (lookup i h')) lookupM-i-h≡just-x) ⟩
230       just (maybe′ id (lookup i h') (just x))
231         ≡⟨ refl ⟩
232       just x
233         ≡⟨ sym lookupM-i-h≡just-x ⟩
234       lookupM i h ∎) ⟩
235   lookupM i h ∷ map just (map (flip lookup (union h h')) is')
236     ≡⟨ cong (_∷_ (lookupM i h)) (lemma-union-not-used h h' is' (Data.List.All.tail p)) ⟩
237   lookupM i h ∷ map (flip lookupM h) is' ∎
238
239 theorem-2 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (v s u : List τ) → bff get eq s v ≡ just u → get u ≡ v
240 theorem-2 get eq v s u p with lemma-fmap-just (assoc eq (get (enumerate s)) v) (proj₂ (lemma-fmap-just (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) v)) p))
241 theorem-2 get eq v s u p | h , ph = begin
242   get u
243     ≡⟨ lemma-from-just (begin
244       just (get u)
245         ≡⟨ refl ⟩
246       fmap get (just u)
247         ≡⟨ cong (fmap get) (sym p) ⟩
248       fmap get (bff get eq s v)
249         ≡⟨ cong (fmap get ∘ fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) ph ⟩
250       fmap get (fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (just h)))
251        ≡⟨ refl ⟩
252      just (get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s)))
253        ∎) ⟩
254   get (map (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s))
255     ≡⟨ free-theorem-list-list get (flip lookup (union h (fromFunc (denumerate s)))) (enumerate s) ⟩
256   map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s))
257      ≡⟨ lemma-from-map-just (begin
258        map just (map (flip lookup (union h (fromFunc (denumerate s)))) (get (enumerate s)))
259          ≡⟨ lemma-union-not-used h (fromFunc (denumerate s)) (get (enumerate s)) (lemma-assoc-domain eq (get (enumerate s)) v h ph) ⟩
260        map (flip lookupM h) (get (enumerate s))
261          ≡⟨ lemma-2 eq (get (enumerate s)) v h ph ⟩
262        map just v
263          ∎) ⟩
264   v ∎