complete lemma-2 using new property _in-domain-of_
[~helmut/bidiragda.git] / Bidir.agda
1 module Bidir where
2
3 open import Data.Nat using (ℕ)
4 open import Data.Fin using (Fin)
5 open import Data.Fin.Props using (_≟_)
6 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
7 open import Data.List using (List ; [] ; _∷_ ; map ; length)
8 open import Data.List.Properties using (map-cong) renaming (map-compose to map-∘)
9 open import Data.List.Any using (Any ; any ; here ; there)
10 open import Data.List.All using (All)
11 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
12 open import Data.Vec using (toList ; fromList ; tabulate) renaming (lookup to lookupVec ; _∷_ to _∷V_)
13 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate)
14 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
15 open import Data.Empty using (⊥-elim)
16 open import Function using (id ; _∘_ ; flip)
17 open import Relation.Nullary using (Dec ; yes ; no ; _)
18 open import Relation.Nullary.Negation using (contradiction)
19 open import Relation.Binary.Core using (_≡_ ; refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; Reveal_is_ ; _≗_ ; trans)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 open import FinMap
24
25 _>>=_ : {A B : Set} → Maybe A → (A → Maybe B) → Maybe B
26 _>>=_ = flip (flip maybe′ nothing)
27
28 fmap : {A B : Set} → (A → B) → Maybe A → Maybe B
29 fmap f = maybe′ (λ a → just (f a)) nothing
30
31 EqInst : Set → Set
32 EqInst A = (x y : A) → Dec (x ≡ y)
33
34 checkInsert : {A : Set} {n : ℕ} → EqInst A → Fin n → A → FinMapMaybe n A → Maybe (FinMapMaybe n A)
35 checkInsert eq i b m with lookupM i m
36 checkInsert eq i b m | just c with eq b c
37 checkInsert eq i b m | just .b | yes refl = just m
38 checkInsert eq i b m | just c  | no p    = nothing
39 checkInsert eq i b m | nothing = just (insert i b m)
40 assoc : {A : Set} {n : ℕ} → EqInst A → List (Fin n) → List A → Maybe (FinMapMaybe n A)
41 assoc _  []       []       = just empty
42 assoc eq (i ∷ is) (b ∷ bs) = (assoc eq is bs) >>= (checkInsert eq i b)
43 assoc _  _        _        = nothing
44
45 record checkInsertProof {A : Set} {n : ℕ} (eq : EqInst A) (i : Fin n) (x : A) (m : FinMapMaybe n A) (P : Set) : Set where
46   field
47      same : lookupM i m ≡ just x → P
48      new : lookupM i m ≡ nothing → P
49      wrong : (x' : A) → ¬(x ≡ x') → lookupM i m ≡ just x'  → P
50
51 apply-checkInsertProof : {A P : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (x : A) → (m : FinMapMaybe n A) → checkInsertProof eq i x m P → P
52 apply-checkInsertProof eq i x m rp with lookupM i m | inspect (lookupM i) m
53 apply-checkInsertProof eq i x m rp | just x' | il with eq x x'
54 apply-checkInsertProof eq i x m rp | just .x | Reveal_is_.[_] il | yes refl = checkInsertProof.same rp il
55 apply-checkInsertProof eq i x m rp | just x' | Reveal_is_.[_] il | no x≢x' = checkInsertProof.wrong rp x' x≢x' il
56 apply-checkInsertProof eq i x m rp | nothing | Reveal_is_.[_] il = checkInsertProof.new rp il
57
58 lemma-checkInsert-same : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (x : A) → (m : FinMapMaybe n A) → lookupM i m ≡ just x → checkInsert eq i x m ≡ just m
59 lemma-checkInsert-same eq i x m p with lookupM i m
60 lemma-checkInsert-same eq i x m refl | .(just x) with eq x x
61 lemma-checkInsert-same eq i x m refl | .(just x) | yes refl = refl
62 lemma-checkInsert-same eq i x m refl | .(just x) | no x≢x = contradiction refl x≢x
63
64 lemma-checkInsert-new : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (x : A) → (m : FinMapMaybe n A) → lookupM i m ≡ nothing → checkInsert eq i x m ≡ just (insert i x m)
65 lemma-checkInsert-new eq i x m p with lookupM i m
66 lemma-checkInsert-new eq i x m refl | .nothing = refl
67
68 lemma-checkInsert-wrong : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (x : A) → (m : FinMapMaybe n A) → (x' : A) → ¬(x ≡ x') → lookupM i m ≡ just x' → checkInsert eq i x m ≡ nothing
69 lemma-checkInsert-wrong eq i x m x' d p with lookupM i m
70 lemma-checkInsert-wrong eq i x m x' d refl | .(just x') with eq x x'
71 lemma-checkInsert-wrong eq i x m x' d refl | .(just x') | yes q = contradiction q d
72 lemma-checkInsert-wrong eq i x m x' d refl | .(just x') | no q = refl
73
74 record checkInsertEqualProof {A : Set} {n : ℕ} (eq : EqInst A) (i : Fin n) (x : A) (m : FinMapMaybe n A) (e : Maybe (FinMapMaybe n A)) : Set where
75   field
76      same : lookupM i m ≡ just x → just m ≡ e
77      new : lookupM i m ≡ nothing → just (insert i x m) ≡ e
78      wrong : (x' : A) → ¬(x ≡ x') → lookupM i m ≡ just x' → nothing ≡ e
79
80 lift-checkInsertProof : {A : Set} {n : ℕ} {eq : EqInst A} {i : Fin n} {x : A} {m : FinMapMaybe n A} {e : Maybe (FinMapMaybe n A)} → checkInsertEqualProof eq i x m e → checkInsertProof eq i x m (checkInsert eq i x m ≡ e)
81 lift-checkInsertProof {_} {_} {eq} {i} {x} {m} o = record
82   { same  = λ p → trans (lemma-checkInsert-same eq i x m p) (checkInsertEqualProof.same o p)
83   ; new   = λ p → trans (lemma-checkInsert-new eq i x m p) (checkInsertEqualProof.new o p)
84   ; wrong = λ x' q p → trans (lemma-checkInsert-wrong eq i x m x' q p) (checkInsertEqualProof.wrong o x' q p)
85   }
86
87 lemma-checkInsert-restrict : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (i : Fin n) → (is : List (Fin n)) → checkInsert eq i (f i) (restrict f is) ≡ just (restrict f (i ∷ is))
88 lemma-checkInsert-restrict {τ} eq f i is = apply-checkInsertProof eq i (f i) (restrict f is) (lift-checkInsertProof record
89   { same  = λ lookupM≡justx → cong just (lemma-insert-same (restrict f is) i (f i) lookupM≡justx)
90   ; new   = λ lookupM≡nothing → refl
91   ; wrong = λ x' x≢x' lookupM≡justx' → contradiction (lemma-lookupM-restrict i f is x' lookupM≡justx') x≢x'
92   })
93
94 lemma-1 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (f : Fin n → τ) → (is : List (Fin n)) → assoc eq is (map f is) ≡ just (restrict f is)
95 lemma-1 eq f []        = refl
96 lemma-1 eq f (i ∷ is′) = begin
97   assoc eq (i ∷ is′) (map f (i ∷ is′))
98     ≡⟨ refl ⟩
99   assoc eq is′ (map f is′) >>= checkInsert eq i (f i)
100     ≡⟨ cong (λ m → m >>= checkInsert eq i (f i)) (lemma-1 eq f is′) ⟩
101   just (restrict f is′) >>= (checkInsert eq i (f i))
102     ≡⟨ refl ⟩
103   checkInsert eq i (f i) (restrict f is′)
104     ≡⟨ lemma-checkInsert-restrict eq f i is′ ⟩
105   just (restrict f (i ∷ is′)) ∎
106
107 lemma-lookupM-assoc : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
108 lemma-lookupM-assoc eq i is x xs h    p with assoc eq is xs
109 lemma-lookupM-assoc eq i is x xs h    () | nothing
110 lemma-lookupM-assoc eq i is x xs h    p | just h' = apply-checkInsertProof eq i x h' record
111   { same  = λ lookupM≡justx → begin
112       lookupM i h
113         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-same eq i x h' lookupM≡justx))) ⟩
114       lookupM i h'
115         ≡⟨ lookupM≡justx ⟩
116       just x ∎
117   ; new   = λ lookupM≡nothing → begin
118       lookupM i h
119         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym p) (lemma-checkInsert-new eq i x h' lookupM≡nothing))) ⟩
120       lookupM i (insert i x h')
121         ≡⟨ lemma-lookupM-insert i x h' ⟩
122       just x ∎
123   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing (trans (sym p) (lemma-checkInsert-wrong eq i x h' x' x≢x' lookupM≡justx'))
124   }
125
126 lemma-lookupM-checkInsert : {A : Set} {n : ℕ} → (eq : EqInst A) → (i j : Fin n) → (x y : A) → (h h' : FinMapMaybe n A) → lookupM i h ≡ just x → checkInsert eq j y h ≡ just h' → lookupM i h' ≡ just x
127 lemma-lookupM-checkInsert eq i j x y h h' pl ph' with lookupM j h | inspect (lookupM j) h
128 lemma-lookupM-checkInsert eq i j x y h .(insert j y h) pl refl | nothing | pl' with i ≟ j
129 lemma-lookupM-checkInsert eq i .i x y h .(insert i y h) pl refl | nothing | Reveal_is_.[_] pl' | yes refl with begin just x ≡⟨ sym pl ⟩ lookupM i h ≡⟨ pl' ⟩ nothing ∎
130 ... | ()
131 lemma-lookupM-checkInsert eq i j x y h .(insert j y h) pl refl | nothing | pl' | no p = begin
132   lookupM i (insert j y h)
133     ≡⟨ sym (lemma-lookupM-insert-other i j y h ¬p) ⟩
134   lookupM i h
135     ≡⟨ pl ⟩
136   just x ∎
137 lemma-lookupM-checkInsert eq i j x y h h' pl ph' | just z | pl' with eq y z
138 lemma-lookupM-checkInsert eq i j x y h h' pl ph' | just .y | pl' | yes refl = begin
139   lookupM i h'
140     ≡⟨ cong (lookupM i) (lemma-from-just (sym ph')) ⟩
141   lookupM i h
142     ≡⟨ pl ⟩
143   just x ∎
144 lemma-lookupM-checkInsert eq i j x y h h' pl () | just z | pl' | no p
145
146 lemma-∈-lookupM-assoc : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → (i ∈ is) → (∃ λ x → lookupM i h ≡ just x)
147 lemma-∈-lookupM-assoc eq i [] [] h ph ()
148 lemma-∈-lookupM-assoc eq i (i' ∷ is) [] h () i∈is
149 lemma-∈-lookupM-assoc eq i [] (x ∷ xs) h () i∈is
150 lemma-∈-lookupM-assoc eq i (i' ∷ is) (x ∷ xs) h ph i∈is with assoc eq is xs | inspect (assoc eq is) xs
151 lemma-∈-lookupM-assoc eq i (i' ∷ is) (x ∷ xs) h () i∈is | nothing | ph'
152 lemma-∈-lookupM-assoc eq i (.i ∷ is) (x ∷ xs) h ph (here refl) | just h' | ph' with lookupM i h' | inspect (lookupM i) h'
153 lemma-∈-lookupM-assoc eq i (.i ∷ is) (x ∷ xs) h ph (here refl) | just h' | ph' | just x' | px with eq x x' 
154 lemma-∈-lookupM-assoc eq i (.i ∷ is) (x ∷ xs) h refl (here refl) | just .h | ph' | just .x | Reveal_is_.[_] px | yes refl = x , px
155 lemma-∈-lookupM-assoc eq i (.i ∷ is) (x ∷ xs) h () (here refl) | just h' | ph' | just x' | px | no ¬p
156 lemma-∈-lookupM-assoc eq i (.i ∷ is) (x ∷ xs) .(insert i x h') refl (here refl) | just h' | ph' | nothing | px = x , lemma-lookupM-insert i x h'
157 lemma-∈-lookupM-assoc eq i (i' ∷ is) (x ∷ xs) h ph (there pxs) | just h' | Reveal_is_.[_] ph' with lemma-∈-lookupM-assoc eq i is xs h' ph' pxs
158 lemma-∈-lookupM-assoc eq i (i' ∷ is) (x ∷ xs) h ph (there pxs) | just h' | Reveal_is_.[_] ph' | x' , px' = x' , lemma-lookupM-checkInsert eq i i' x' x h' h px' ph
159
160 lemma-∉-lookupM-assoc : {A : Set} {n : ℕ} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → (i ∉ is) → lookupM i h ≡ nothing
161 lemma-∉-lookupM-assoc eq i []         []         h ph i∉is = begin
162   lookupM i h
163     ≡⟨ cong (lookupM i) (sym (lemma-from-just ph)) ⟩
164   lookupM i empty
165     ≡⟨ lemma-lookupM-empty i ⟩
166   nothing ∎
167 lemma-∉-lookupM-assoc eq i []         (x' ∷ xs') h () i∉is
168 lemma-∉-lookupM-assoc eq i (i' ∷ is') []         h () i∉is
169 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is with i ≟ i'
170 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | yes p = contradiction (here p) i∉is
171 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | no ¬p with assoc eq is' xs' | inspect (assoc eq is') xs'
172 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h () i∉is | no ¬p | nothing | Reveal_is_.[_] ph'
173 lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h ph i∉is | no ¬p | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
174     same = λ lookupM-i'-h'≡just-x' → begin
175       lookupM i h
176         ≡⟨ cong (lookupM i) (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x'))) ⟩
177       lookupM i h'
178         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
179       nothing ∎
180   ; new = λ lookupM-i'-h'≡nothing → begin
181       lookupM i h
182         ≡⟨ cong (lookupM i)  (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing))) ⟩
183       lookupM i (insert i' x' h')
184         ≡⟨ sym (lemma-lookupM-insert-other i i' x' h' ¬p) ⟩
185       lookupM i h'
186         ≡⟨ lemma-∉-lookupM-assoc eq i is' xs' h' ph' (i∉is ∘ there) ⟩
187       nothing ∎
188   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
189   }
190
191 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
192 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
193
194 lemma-assoc-domain : {n : ℕ} {A : Set} → (eq : EqInst A) → (is : List (Fin n)) → (xs : List A) → (h : FinMapMaybe n A) → assoc eq is xs ≡ just h → is in-domain-of h
195 lemma-assoc-domain eq []  []  h  ph  = Data.List.All.[]
196 lemma-assoc-domain eq [] (x' ∷ xs') h ()
197 lemma-assoc-domain eq (i' ∷ is') [] h ()
198 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph with assoc eq is' xs' | inspect (assoc eq is') xs'
199 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h () | nothing | ph'
200 lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h ph | just h' | Reveal_is_.[_] ph' = apply-checkInsertProof eq i' x' h' record {
201     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
202       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
203       (lemma-assoc-domain eq is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same eq i' x' h' lookupM-i'-h'≡just-x')) ph)))
204   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
205       (x' , (trans (cong (lookupM i') (lemma-from-just (trans (sym ph) (lemma-checkInsert-new eq i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
206       (Data.List.All.map
207         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert eq i i' (proj₁ p) x' h' h (proj₂ p) ph)
208         (lemma-assoc-domain eq is' xs' h' ph'))
209   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong eq i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
210   }
211
212 lemma-map-lookupM-insert : {n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (h : FinMapMaybe n A) → ¬(i ∈ is) → is in-domain-of h → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
213 lemma-map-lookupM-insert eq i []         x h i∉is ph = refl
214 lemma-map-lookupM-insert eq i (i' ∷ is') x h i∉is ph = begin
215   lookupM i' (insert i x h) ∷ map (flip lookupM (insert i x h)) is'
216     ≡⟨ cong (flip _∷_ (map (flip lookupM (insert i x h)) is')) (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym))) ⟩
217   lookupM i' h ∷ map (flip lookupM (insert i x h)) is'
218     ≡⟨ cong (_∷_ (lookupM i' h)) (lemma-map-lookupM-insert eq i is' x h (i∉is ∘ there) (Data.List.All.tail ph)) ⟩
219   lookupM i' h ∷ map (flip lookupM h) is' ∎
220
221 lemma-map-lookupM-assoc : {n : ℕ} {A : Set} → (eq : EqInst A) → (i : Fin n) → (is : List (Fin n)) → (x : A) → (xs : List A) → (h : FinMapMaybe n A) → (h' : FinMapMaybe n A) → assoc eq is xs ≡ just h' → checkInsert eq i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
222 lemma-map-lookupM-assoc eq i []         x []         h h' ph' ph = refl
223 lemma-map-lookupM-assoc eq i []         x (x' ∷ xs') h h' ()  ph
224 lemma-map-lookupM-assoc eq i (i' ∷ is') x []         h h' ()  ph
225 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph with any (_≟_ i) (i' ∷ is')
226 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p with lemma-∈-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h' ph' p
227 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
228 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | yes p | (x'' , refl) | .(just x'') with eq x x''
229 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
230 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' () | yes p | (x'' , refl) | .(just x'') | no ¬p
231 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p with lookupM i h' | lemma-∉-lookupM-assoc eq i (i' ∷ is') (x' ∷ xs') h' ph' ¬p
232 lemma-map-lookupM-assoc eq i (i' ∷ is') x (x' ∷ xs') h h' ph' ph | no ¬p | .nothing | refl = begin
233   map (flip lookupM h) (i' ∷ is')
234     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (lemma-from-just (sym ph))) (i' ∷ is') ⟩
235   map (flip lookupM (insert i x h')) (i' ∷ is')
236     ≡⟨ lemma-map-lookupM-insert eq i (i' ∷ is') x h' ¬p (lemma-assoc-domain eq (i' ∷ is') (x' ∷ xs') h' ph') ⟩
237   map (flip lookupM h') (i' ∷ is') ∎
238
239 lemma-2 : {τ : Set} {n : ℕ} → (eq : EqInst τ) → (is : List (Fin n)) → (v : List τ) → (h : FinMapMaybe n τ) → assoc eq is v ≡ just h → map (flip lookupM h) is ≡ map just v
240 lemma-2 eq []       []       h p = refl
241 lemma-2 eq []       (x ∷ xs) h ()
242 lemma-2 eq (x ∷ xs) []       h ()
243 lemma-2 eq (i ∷ is) (x ∷ xs) h p with assoc eq is xs | inspect (assoc eq is) xs
244 lemma-2 eq (i ∷ is) (x ∷ xs) h () | nothing | _
245 lemma-2 eq (i ∷ is) (x ∷ xs) h p | just h' | Reveal_is_.[_] ir = begin
246   map (flip lookupM h) (i ∷ is)
247     ≡⟨ refl ⟩
248   lookupM i h ∷ map (flip lookupM h) is
249     ≡⟨ cong (flip _∷_ (map (flip lookup h) is)) (lemma-lookupM-assoc eq i is x xs h (begin
250       assoc eq (i ∷ is) (x ∷ xs)
251         ≡⟨ cong (flip _>>=_ (checkInsert eq i x)) ir ⟩
252       checkInsert eq i x h'
253         ≡⟨ p ⟩
254       just h ∎) ) ⟩
255   just x ∷ map (flip lookupM h) is
256     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc eq i is x xs h h' ir p) ⟩
257   just x ∷ map (flip lookupM h') is
258     ≡⟨ cong (_∷_ (just x)) (lemma-2 eq is xs h' ir) ⟩
259   just x ∷ map just xs
260     ≡⟨ refl ⟩
261   map just (x ∷ xs) ∎
262
263 enumerate : {A : Set} → (l : List A) → List (Fin (length l))
264 enumerate l = toList (tabulate id)
265
266 denumerate : {A : Set} (l : List A) → Fin (length l) → A
267 denumerate l = flip lookupVec (fromList l)
268
269 bff : ({A : Set} → List A → List A) → ({B : Set} → EqInst B → List B → List B → Maybe (List B))
270 bff get eq s v = let s′ = enumerate s
271                      g  = fromFunc (denumerate s)
272                      h  = assoc eq (get s′) v
273                      h′ = fmap (flip union g) h
274                  in fmap (flip map s′ ∘ flip lookup) h′
275
276 postulate
277   free-theorem-list-list : {β γ : Set} → (get : {α : Set} → List α → List α) → (f : β → γ) → get ∘ map f ≗ map f ∘ get
278
279 toList-map-commutes : {A B : Set} {n : ℕ} → (f : A → B) → (v : Data.Vec.Vec A n) → (toList (Data.Vec.map f v)) ≡ map f (toList v)
280 toList-map-commutes f Data.Vec.[] = refl
281 toList-map-commutes f (x ∷V xs) = cong (_∷_ (f x)) (toList-map-commutes f xs)
282
283 lemma-map-denumerate-enumerate : {A : Set} → (as : List A) → map (denumerate as) (enumerate as) ≡ as
284 lemma-map-denumerate-enumerate [] = refl
285 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
286   map (flip lookupVec (a ∷V (fromList as))) (toList (tabulate Fin.suc))
287     ≡⟨ cong (map (flip lookupVec (a ∷V (fromList as))) ∘ toList) (tabulate-∘ Fin.suc id) ⟩
288   map (flip lookupVec (a ∷V (fromList as))) (toList (Data.Vec.map Fin.suc (tabulate id)))
289     ≡⟨ cong (map (flip lookupVec (a ∷V fromList as))) (toList-map-commutes Data.Fin.suc (tabulate id)) ⟩
290   map (flip lookupVec (a ∷V fromList as)) (map Fin.suc (enumerate as))
291     ≡⟨ sym (map-∘ (enumerate as)) ⟩
292   map (flip lookupVec (a ∷V (fromList as)) ∘ Fin.suc) (enumerate as)
293     ≡⟨ refl ⟩
294   map (denumerate as) (enumerate as)
295     ≡⟨ lemma-map-denumerate-enumerate as ⟩
296   as ∎)
297
298 theorem-1 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (s : List τ) → bff get eq s (get s) ≡ just s
299 theorem-1 get eq s = begin
300   bff get eq s (get s)
301     ≡⟨ cong (bff get eq s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
302   bff get eq s (get (map (denumerate s) (enumerate s)))
303     ≡⟨ cong (bff get eq s) (free-theorem-list-list get (denumerate s) (enumerate s)) ⟩
304   bff get eq s (map (denumerate s) (get (enumerate s)))
305     ≡⟨ refl ⟩
306   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (denumerate s))) (assoc eq (get (enumerate s)) (map (denumerate s) (get (enumerate s)))))
307     ≡⟨ cong (fmap (flip map (enumerate s) ∘ flip lookup) ∘ fmap (flip union (fromFunc (denumerate s)))) (lemma-1 eq (denumerate s) (get (enumerate s))) ⟩
308   fmap (flip map (enumerate s) ∘ flip lookup) (fmap (flip union (fromFunc (flip lookupVec (fromList s)))) (just (restrict (denumerate s) (get (enumerate s)))))
309     ≡⟨ refl ⟩
310   just ((flip map (enumerate s) ∘ flip lookup) (union (restrict (denumerate s) (get (enumerate s))) (fromFunc (denumerate s))))
311     ≡⟨ cong just (cong (flip map (enumerate s) ∘ flip lookup) (lemma-union-restrict (denumerate s) (get (enumerate s)))) ⟩
312   just ((flip map (enumerate s) ∘ flip lookup) (fromFunc (denumerate s)))
313     ≡⟨ refl ⟩
314   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
315     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
316   just (map (denumerate s) (enumerate s))
317     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
318   just s ∎
319
320 theorem-2 : (get : {α : Set} → List α → List α) → {τ : Set} → (eq : EqInst τ) → (v s u : List τ) → bff get eq s v ≡ just u → get u ≡ v
321 theorem-2 get eq v s u p = {!!}