drop unused import
[~helmut/bidiragda.git] / Bidir.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Bidir (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
9 open import Data.List using (List)
10 open import Data.List.Any using (Any ; any ; here ; there)
11 open import Data.List.All using (All)
12 open Data.List.Any.Membership-≡ using (_∈_ ; _∉_)
13 open import Data.Vec using (Vec ; [] ; _∷_ ; toList ; fromList ; map ; tabulate) renaming (lookup to lookupVec)
14 open import Data.Vec.Properties using (tabulate-∘ ; lookup∘tabulate ; map-cong ; map-∘)
15 open import Data.Product using (∃ ; _×_ ; _,_ ; proj₁ ; proj₂)
16 open import Data.Empty using (⊥-elim)
17 open import Function using (id ; _∘_ ; flip)
18 open import Relation.Nullary using (yes ; no)
19 open import Relation.Binary.Core using (refl)
20 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; _≗_ ; trans)
21 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
22
23 import FreeTheorems
24 open FreeTheorems.VecVec using (get-type ; free-theorem)
25 open import FinMap
26 import CheckInsert
27 open CheckInsert Carrier deq
28 open import BFF using (_>>=_ ; fmap)
29 open BFF.VecBFF Carrier deq using (assoc ; enumerate ; denumerate ; bff)
30
31 lemma-1 : {m n : ℕ} → (f : Fin n → Carrier) → (is : Vec (Fin n) m) → assoc is (map f is) ≡ just (restrict f (toList is))
32 lemma-1 f []        = refl
33 lemma-1 f (i ∷ is′) = begin
34   assoc is′ (map f is′) >>= checkInsert i (f i)
35     ≡⟨ cong (λ m → m >>= checkInsert i (f i)) (lemma-1 f is′) ⟩
36   checkInsert i (f i) (restrict f (toList is′))
37     ≡⟨ lemma-checkInsert-restrict f i (toList is′) ⟩
38   just (restrict f (toList (i ∷ is′))) ∎
39
40 lemma-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc (i ∷ is) (x ∷ xs) ≡ just h → lookupM i h ≡ just x
41 lemma-lookupM-assoc i is x xs h    p with assoc is xs
42 lemma-lookupM-assoc i is x xs h    () | nothing
43 lemma-lookupM-assoc i is x xs h    p | just h' = apply-checkInsertProof i x h' record
44   { same  = λ lookupM≡justx → begin
45       lookupM i h
46         ≡⟨ cong (lookupM i) (just-injective (trans (sym p) (lemma-checkInsert-same i x h' lookupM≡justx))) ⟩
47       lookupM i h'
48         ≡⟨ lookupM≡justx ⟩
49       just x ∎
50   ; new   = λ lookupM≡nothing → begin
51       lookupM i h
52         ≡⟨ cong (lookupM i) (just-injective (trans (sym p) (lemma-checkInsert-new i x h' lookupM≡nothing))) ⟩
53       lookupM i (insert i x h')
54         ≡⟨ lemma-lookupM-insert i x h' ⟩
55       just x ∎
56   ; wrong = λ x' x≢x' lookupM≡justx' → lemma-just≢nothing (trans (sym p) (lemma-checkInsert-wrong i x h' x' x≢x' lookupM≡justx'))
57   }
58
59 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
60 lemma-∉-lookupM-assoc i []         []         h ph i∉is = begin
61   lookupM i h
62     ≡⟨ cong (lookupM i) (sym (just-injective ph)) ⟩
63   lookupM i empty
64     ≡⟨ lemma-lookupM-empty i ⟩
65   nothing ∎
66 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
67 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
68 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = apply-checkInsertProof i' x' h' record {
69     same = λ lookupM-i'-h'≡just-x' → begin
70       lookupM i h
71         ≡⟨ cong (lookupM i) (just-injective (trans (sym ph) (lemma-checkInsert-same i' x' h' lookupM-i'-h'≡just-x'))) ⟩
72       lookupM i h'
73         ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
74       nothing ∎
75   ; new = λ lookupM-i'-h'≡nothing → begin
76       lookupM i h
77         ≡⟨ cong (lookupM i)  (just-injective (trans (sym ph) (lemma-checkInsert-new i' x' h' lookupM-i'-h'≡nothing))) ⟩
78       lookupM i (insert i' x' h')
79         ≡⟨ sym (lemma-lookupM-insert-other i i' x' h' (i∉is ∘ here)) ⟩
80       lookupM i h'
81         ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
82       nothing ∎
83   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
84   }
85
86 _in-domain-of_ : {n : ℕ} {A : Set} → (is : List (Fin n)) → (FinMapMaybe n A) → Set
87 _in-domain-of_ is h = All (λ i → ∃ λ x → lookupM i h ≡ just x) is
88
89 lemma-assoc-domain : {m n : ℕ} → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (toList is) in-domain-of h
90 lemma-assoc-domain []         []         h ph = Data.List.All.[]
91 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph with assoc is' xs' | inspect (assoc is') xs'
92 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h () | nothing | [ ph' ]
93 lemma-assoc-domain (i' ∷ is') (x' ∷ xs') h ph | just h' | [ ph' ] = apply-checkInsertProof i' x' h' record {
94     same = λ lookupM-i'-h'≡just-x' → Data.List.All._∷_
95       (x' , (trans (cong (lookupM i') (just-injective (trans (sym ph) (lemma-checkInsert-same i' x' h' lookupM-i'-h'≡just-x')))) lookupM-i'-h'≡just-x'))
96       (lemma-assoc-domain is' xs' h (trans ph' (trans (sym (lemma-checkInsert-same i' x' h' lookupM-i'-h'≡just-x')) ph)))
97   ; new  = λ lookupM-i'-h'≡nothing → Data.List.All._∷_
98       (x' , (trans (cong (lookupM i') (just-injective (trans (sym ph) (lemma-checkInsert-new i' x' h' lookupM-i'-h'≡nothing)))) (lemma-lookupM-insert i' x' h')))
99       (Data.List.All.map
100         (λ {i} p → proj₁ p , lemma-lookupM-checkInsert i i' (proj₁ p) x' h' h (proj₂ p) ph)
101         (lemma-assoc-domain is' xs' h' ph'))
102   ; wrong = λ x'' x'≢x'' lookupM-i'-h'≡just-x'' → lemma-just≢nothing (trans (sym ph) (lemma-checkInsert-wrong i' x' h' x'' x'≢x'' lookupM-i'-h'≡just-x''))
103   }
104
105 lemma-map-lookupM-insert : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (h : FinMapMaybe n Carrier) → i ∉ (toList is) → map (flip lookupM (insert i x h)) is ≡ map (flip lookupM h) is
106 lemma-map-lookupM-insert i []         x h i∉is = refl
107 lemma-map-lookupM-insert i (i' ∷ is') x h i∉is = begin
108   lookupM i' (insert i x h) ∷ map (flip lookupM (insert i x h)) is'
109     ≡⟨ cong (flip _∷_ (map (flip lookupM (insert i x h)) is')) (sym (lemma-lookupM-insert-other i' i x h (i∉is ∘ here ∘ sym))) ⟩
110   lookupM i' h ∷ map (flip lookupM (insert i x h)) is'
111     ≡⟨ cong (_∷_ (lookupM i' h)) (lemma-map-lookupM-insert i is' x h (i∉is ∘ there)) ⟩
112   lookupM i' h ∷ map (flip lookupM h) is' ∎
113
114 lemma-map-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (x : Carrier) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → (h' : FinMapMaybe n Carrier) → assoc is xs ≡ just h' → checkInsert i x h' ≡ just h → map (flip lookupM h) is ≡ map (flip lookupM h') is
115 lemma-map-lookupM-assoc i is x xs h h' ph' ph with any (_≟_ i) (toList is)
116 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p with Data.List.All.lookup (lemma-assoc-domain is xs h' ph') p
117 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p | (x'' , p') with lookupM i h' 
118 lemma-map-lookupM-assoc i is x xs h h' ph' ph | yes p | (x'' , refl) | .(just x'') with deq x x''
119 lemma-map-lookupM-assoc i is x xs h .h ph' refl | yes p | (.x , refl) | .(just x)  | yes refl = refl
120 lemma-map-lookupM-assoc i is x xs h h' ph' () | yes p | (x'' , refl) | .(just x'') | no p
121 lemma-map-lookupM-assoc i is x xs h h' ph' ph | no ¬p rewrite lemma-∉-lookupM-assoc i is xs h' ph' ¬p = begin
122   map (flip lookupM h) is
123     ≡⟨ map-cong (λ i'' → cong (lookupM i'') (just-injective (sym ph))) is ⟩
124   map (flip lookupM (insert i x h')) is
125     ≡⟨ lemma-map-lookupM-insert i is x h' ¬p ⟩
126   map (flip lookupM h') is ∎
127
128 lemma-2 : {m n : ℕ} → (is : Vec (Fin n) m) → (v : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is v ≡ just h → map (flip lookupM h) is ≡ map just v
129 lemma-2 []       []       h p = refl
130 lemma-2 (i ∷ is) (x ∷ xs) h p with assoc is xs | inspect (assoc is) xs
131 lemma-2 (i ∷ is) (x ∷ xs) h () | nothing | _
132 lemma-2 (i ∷ is) (x ∷ xs) h p | just h' | [ ir ] = begin
133   lookupM i h ∷ map (flip lookupM h) is
134     ≡⟨ cong (flip _∷_ (map (flip lookupM h) is)) (lemma-lookupM-assoc i is x xs h (begin
135       assoc (i ∷ is) (x ∷ xs)
136         ≡⟨ cong (flip _>>=_ (checkInsert i x)) ir ⟩
137       checkInsert i x h'
138         ≡⟨ p ⟩
139       just h ∎) ) ⟩
140   just x ∷ map (flip lookupM h) is
141     ≡⟨  cong (_∷_ (just x)) (lemma-map-lookupM-assoc i is x xs h h' ir p) ⟩
142   just x ∷ map (flip lookupM h') is
143     ≡⟨ cong (_∷_ (just x)) (lemma-2 is xs h' ir) ⟩
144   just x ∷ map just xs ∎
145
146 lemma-map-denumerate-enumerate : {m : ℕ} → (as : Vec Carrier m) → map (denumerate as) (enumerate as) ≡ as
147 lemma-map-denumerate-enumerate []       = refl
148 lemma-map-denumerate-enumerate (a ∷ as) = cong (_∷_ a) (begin
149   map (flip lookupVec (a ∷ as)) (tabulate Fin.suc)
150     ≡⟨ cong (map (flip lookupVec (a ∷ as))) (tabulate-∘ Fin.suc id) ⟩
151   map (flip lookupVec (a ∷ as)) (map Fin.suc (tabulate id))
152     ≡⟨ refl ⟩
153   map (flip lookupVec (a ∷ as)) (map Fin.suc (enumerate as))
154     ≡⟨ sym (map-∘ _ _ (enumerate as)) ⟩
155   map (flip lookupVec (a ∷ as) ∘ Fin.suc) (enumerate as)
156     ≡⟨ refl ⟩
157   map (denumerate as) (enumerate as)
158     ≡⟨ lemma-map-denumerate-enumerate as ⟩
159   as ∎)
160
161 theorem-1 : {getlen : ℕ → ℕ} → (get : get-type getlen) → {m : ℕ} → (s : Vec Carrier m) → bff get s (get s) ≡ just s
162 theorem-1 get s = begin
163   bff get s (get s)
164     ≡⟨ cong (bff get s ∘ get) (sym (lemma-map-denumerate-enumerate s)) ⟩
165   bff get s (get (map (denumerate s) (enumerate s)))
166     ≡⟨ cong (bff get s) (free-theorem get (denumerate s) (enumerate s)) ⟩
167   bff get s (map (denumerate s) (get (enumerate s)))
168     ≡⟨ refl ⟩
169   (h′↦r ∘ h↦h′) (assoc (get (enumerate s)) (map (denumerate s) (get (enumerate s))))
170     ≡⟨ cong (h′↦r ∘ h↦h′) (lemma-1 (denumerate s) (get (enumerate s))) ⟩
171   (h′↦r ∘ h↦h′ ∘ just) (restrict (denumerate s) (toList (get (enumerate s))))
172     ≡⟨ refl ⟩
173   (h′↦r ∘ just) (union (restrict (denumerate s) (toList (get (enumerate s)))) (fromFunc (denumerate s)))
174     ≡⟨ cong (h′↦r ∘ just) (lemma-union-restrict (denumerate s) (toList (get (enumerate s)))) ⟩
175   (h′↦r ∘ just) (fromFunc (denumerate s))
176     ≡⟨ refl ⟩
177   just (map (flip lookup (fromFunc (denumerate s))) (enumerate s))
178     ≡⟨ cong just (map-cong (lookup∘tabulate (denumerate s)) (enumerate s)) ⟩
179   just (map (denumerate s) (enumerate s))
180     ≡⟨ cong just (lemma-map-denumerate-enumerate s) ⟩
181   just s ∎
182     where h↦h′ = fmap (flip union (fromFunc (denumerate s)))
183           h′↦r = fmap (flip map (enumerate s) ∘ flip lookupVec)
184
185 lemma-fmap-just : {A B : Set} {f : A → B} {b : B} {ma : Maybe A} → fmap f ma ≡ just b → ∃ λ a → ma ≡ just a
186 lemma-fmap-just {ma = just x}  fmap-f-ma≡just-b = x , refl
187 lemma-fmap-just {ma = nothing} ()
188
189 ∷-injective : {A : Set} {n : ℕ} {x y : A} {xs ys : Vec A n} → (x ∷ xs) ≡ (y ∷ ys) → x ≡ y × xs ≡ ys
190 ∷-injective refl = refl , refl
191
192 map-just-injective : {A : Set} {n : ℕ} {xs ys : Vec A n} → map Maybe.just xs ≡ map Maybe.just ys → xs ≡ ys
193 map-just-injective {xs = []}      {ys = []}       p  = refl
194 map-just-injective {xs = x ∷ xs'} {ys = y ∷ ys'}  p with ∷-injective p
195 map-just-injective {xs = x ∷ xs'} {ys = .x ∷ ys'} p | refl , p' = cong (_∷_ x) (map-just-injective p')
196
197 lemma-union-not-used : {m n : ℕ} {A : Set} (h : FinMapMaybe n A) → (h' : FinMap n A) → (is : Vec (Fin n) m) → (toList is) in-domain-of h → map just (map (flip lookup (union h h')) is) ≡ map (flip lookupM h) is
198 lemma-union-not-used h h' []        p = refl
199 lemma-union-not-used h h' (i ∷ is') p with Data.List.All.head p
200 lemma-union-not-used h h' (i ∷ is') p | x , lookupM-i-h≡just-x = begin
201   just (lookup i (union h h')) ∷ map just (map (flip lookup (union h h')) is')
202     ≡⟨ cong (flip _∷_ (map just (map (flip lookup (union h h')) is'))) (begin
203       just (lookup i (union h h'))
204         ≡⟨ cong just (lookup∘tabulate (λ j → maybe′ id (lookup j h') (lookupM j h)) i) ⟩
205       just (maybe′ id (lookup i h') (lookupM i h))
206         ≡⟨ cong just (cong (maybe′ id (lookup i h')) lookupM-i-h≡just-x) ⟩
207       just (maybe′ id (lookup i h') (just x))
208         ≡⟨ refl ⟩
209       just x
210         ≡⟨ sym lookupM-i-h≡just-x ⟩
211       lookupM i h ∎) ⟩
212   lookupM i h ∷ map just (map (flip lookup (union h h')) is')
213     ≡⟨ cong (_∷_ (lookupM i h)) (lemma-union-not-used h h' is' (Data.List.All.tail p)) ⟩
214   lookupM i h ∷ map (flip lookupM h) is' ∎
215
216 theorem-2 : {getlen : ℕ → ℕ} (get : get-type getlen) → {m : ℕ} → (v : Vec Carrier (getlen m)) → (s u : Vec Carrier m) → bff get s v ≡ just u → get u ≡ v
217 theorem-2 get v s u p with lemma-fmap-just (proj₂ (lemma-fmap-just p))
218 theorem-2 get v s u p | h , ph = begin
219   get u
220     ≡⟨ just-injective (begin
221       fmap get (just u)
222         ≡⟨ cong (fmap get) (sym p) ⟩
223       fmap get (bff get s v)
224         ≡⟨ cong (fmap get ∘ fmap h′↦r ∘ fmap h↦h′) ph ⟩
225       fmap get (fmap h′↦r (fmap h↦h′ (just h))) ∎) ⟩
226   get (map (flip lookup (h↦h′ h)) s′)
227     ≡⟨ free-theorem get (flip lookup (h↦h′ h)) s′ ⟩
228   map (flip lookup (h↦h′ h)) (get s′)
229      ≡⟨ map-just-injective (begin
230        map just (map (flip lookup (union h g)) (get s′))
231          ≡⟨ lemma-union-not-used h g (get s′) (lemma-assoc-domain (get s′) v h ph) ⟩
232        map (flip lookupM h) (get s′)
233          ≡⟨ lemma-2 (get s′) v h ph ⟩
234        map just v
235          ∎) ⟩
236   v ∎
237     where s′   = enumerate s
238           g    = fromFunc (denumerate s)
239           h↦h′ = flip union g
240           h′↦r = flip map s′ ∘ flip lookupVec