47af215627bf0adcaf62237b164e738210f18edb
[~helmut/bidiragda.git] / CheckInsert.agda
1 open import Level using () renaming (zero to ℓ₀)
2 open import Relation.Binary using (DecSetoid)
3
4 module CheckInsert (A : DecSetoid ℓ₀ ℓ₀) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin)
8 open import Data.Fin.Props using (_≟_)
9 open import Data.Maybe using (Maybe ; nothing ; just) renaming (setoid to MaybeSetoid ; Eq to MaybeEq)
10 open import Data.List using (List ; [] ; _∷_)
11 open import Data.Vec using () renaming (_∷_ to _∷V_)
12 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
13 open import Relation.Nullary using (Dec ; yes ; no ; _)
14 open import Relation.Nullary.Negation using (contradiction)
15 open import Relation.Binary using (Setoid ; IsPreorder ; module DecSetoid)
16 open import Relation.Binary.Core using (refl ; _≡_ ; _≢_)
17 import Relation.Binary.EqReasoning as EqR
18 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; trans)
19
20 open import FinMap
21 open import Generic using (vecIsSetoid)
22
23 private
24   open module A = DecSetoid A using (Carrier ; _≈_) renaming (_≟_ to deq)
25
26 checkInsert : {n : ℕ} → Fin n → Carrier → FinMapMaybe n Carrier → Maybe (FinMapMaybe n Carrier)
27 checkInsert i b m with lookupM i m
28 ...               | nothing = just (insert i b m)
29 ...               | just c with deq b c
30 ...                         | yes b≈c = just m
31 ...                         | no b≉c  = nothing
32
33 data InsertionResult {n : ℕ} (i : Fin n) (x : Carrier) (h : FinMapMaybe n Carrier) : Maybe (FinMapMaybe n Carrier) → Set where
34   same : (x' : Carrier) → x ≈ x' → lookupM i h ≡ just x' → InsertionResult i x h (just h)
35   new : lookupM i h ≡ nothing → InsertionResult i x h (just (insert i x h))
36   wrong : (x' : Carrier) → ¬ (x ≈ x') → lookupM i h ≡ just x' → InsertionResult i x h nothing
37
38 insertionresult : {n : ℕ} → (i : Fin n) → (x : Carrier) → (h : FinMapMaybe n Carrier) → InsertionResult i x h (checkInsert i x h)
39 insertionresult i x h with lookupM i h | inspect (lookupM i) h
40 insertionresult i x h | just x' | _ with deq x x'
41 insertionresult i x h | just x' | [ il ] | yes x≈x' = same x' x≈x' il
42 insertionresult i x h | just x' | [ il ] | no x≉x' = wrong x' x≉x' il
43 insertionresult i x h | nothing | [ il ] = new il
44
45 lemma-checkInsert-same : {n : ℕ} → (i : Fin n) → (x : Carrier) → (m : FinMapMaybe n Carrier) → lookupM i m ≡ just x → checkInsert i x m ≡ just m
46 lemma-checkInsert-same i x m p with lookupM i m
47 lemma-checkInsert-same i x m refl | .(just x) with deq x x
48 lemma-checkInsert-same i x m refl | .(just x) | yes x≈x = refl
49 lemma-checkInsert-same i x m refl | .(just x) | no x≉x = contradiction A.refl x≉x
50
51 lemma-checkInsert-new : {n : ℕ} → (i : Fin n) → (x : Carrier) → (m : FinMapMaybe n Carrier) → lookupM i m ≡ nothing → checkInsert i x m ≡ just (insert i x m)
52 lemma-checkInsert-new i x m p with lookupM i m
53 lemma-checkInsert-new i x m refl | .nothing = refl
54
55 lemma-checkInsert-wrong : {n : ℕ} → (i : Fin n) → (x : Carrier) → (m : FinMapMaybe n Carrier) → (x' : Carrier) → ¬ (x ≈ x') → lookupM i m ≡ just x' → checkInsert i x m ≡ nothing
56 lemma-checkInsert-wrong i x m x' d p with lookupM i m
57 lemma-checkInsert-wrong i x m x' d refl | .(just x') with deq x x'
58 lemma-checkInsert-wrong i x m x' d refl | .(just x') | yes q = contradiction q d
59 lemma-checkInsert-wrong i x m x' d refl | .(just x') | no q = refl
60
61 lemma-checkInsert-restrict : {n : ℕ} → (f : Fin n → Carrier) → (i : Fin n) → (is : List (Fin n)) → checkInsert i (f i) (restrict f is) ≡ just (restrict f (i ∷ is))
62 lemma-checkInsert-restrict f i is with checkInsert i (f i) (restrict f is) | insertionresult i (f i) (restrict f is)
63 lemma-checkInsert-restrict f i is | ._ | same x fi≈x p = cong just (lemma-insert-same _ i (f i) (trans p (cong just (sym (lemma-lookupM-restrict i f is x p)))))
64 lemma-checkInsert-restrict f i is | ._ | new _ = refl
65 lemma-checkInsert-restrict f i is | ._ | wrong x fi≉x p = contradiction (IsPreorder.reflexive (Setoid.isPreorder A.setoid) (lemma-lookupM-restrict i f is x p)) fi≉x
66
67 lemma-lookupM-checkInsert : {n : ℕ} → (i j : Fin n) → (x y : Carrier) → (h h' : FinMapMaybe n Carrier) → lookupM i h ≡ just x → checkInsert j y h ≡ just h' → lookupM i h' ≡ just x
68 lemma-lookupM-checkInsert i j x y h h' pl ph' with checkInsert j y h | insertionresult j y h
69 lemma-lookupM-checkInsert i j x y h .h pl refl | ._ | same _ _ _ = pl
70 lemma-lookupM-checkInsert i j x y h h' pl ph'  | ._ | new _ with i ≟ j
71 lemma-lookupM-checkInsert i .i x y h h' pl ph' | ._ | new pl' | yes refl = lemma-just≢nothing pl pl'
72 lemma-lookupM-checkInsert i j x y h .(insert j y h) pl refl | ._ | new _ | no i≢j = begin
73   lookupM i (insert j y h)
74     ≡⟨ sym (lemma-lookupM-insert-other i j y h i≢j) ⟩
75   lookupM i h
76     ≡⟨ pl ⟩
77   just x ∎
78   where open Relation.Binary.PropositionalEquality.≡-Reasoning
79
80 lemma-lookupM-checkInsert i j x y h h' pl () | ._ | wrong _ _ _
81
82 lemma-lookupM-checkInsert-other : {n : ℕ} → (i j : Fin n) → i ≢ j → (x : Carrier) → (h h' : FinMapMaybe n Carrier) → checkInsert j x h ≡ just h' → lookupM i h ≡ lookupM i h'
83 lemma-lookupM-checkInsert-other i j i≢j x h h' ph' with lookupM j h
84 lemma-lookupM-checkInsert-other i j i≢j x h h' ph' | just y with deq x y
85 lemma-lookupM-checkInsert-other i j i≢j x h .h refl | just y | yes x≈y = refl
86 lemma-lookupM-checkInsert-other i j i≢j x h h' () | just y | no x≉y
87 lemma-lookupM-checkInsert-other i j i≢j x h .(insert j x h) refl | nothing = lemma-lookupM-insert-other i j x h i≢j