generalize lemma-insert-same to arbitrary Setoids
[~helmut/bidiragda.git] / CheckInsert.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module CheckInsert (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.Maybe using (Maybe ; nothing ; just) renaming (setoid to MaybeEq)
9 open import Data.List using (List ; [] ; _∷_)
10 open import Data.Vec using () renaming (_∷_ to _∷V_)
11 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
12 open import Relation.Nullary using (Dec ; yes ; no)
13 open import Relation.Nullary.Negation using (contradiction)
14 open import Relation.Binary using (Setoid)
15 open import Relation.Binary.Core using (refl ; _≢_)
16 open import Relation.Binary.PropositionalEquality using (cong ; sym ; inspect ; [_] ; trans) renaming (setoid to PropEq)
17 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
18
19 open import FinMap
20 open import Generic using (maybeEq-from-≡ ; vecIsSetoid)
21
22 checkInsert : {n : ℕ} → Fin n → Carrier → FinMapMaybe n Carrier → Maybe (FinMapMaybe n Carrier)
23 checkInsert i b m with lookupM i m
24 ...               | nothing = just (insert i b m)
25 ...               | just c with deq b c
26 ...                         | yes b≡c = just m
27 ...                         | no b≢c  = nothing
28
29 data InsertionResult {n : ℕ} (i : Fin n) (x : Carrier) (h : FinMapMaybe n Carrier) : Maybe (FinMapMaybe n Carrier) → Set where
30   same : lookupM i h ≡ just x → InsertionResult i x h (just h)
31   new : lookupM i h ≡ nothing → InsertionResult i x h (just (insert i x h))
32   wrong : (x' : Carrier) → x ≢ x' → lookupM i h ≡ just x' → InsertionResult i x h nothing
33
34 insertionresult : {n : ℕ} → (i : Fin n) → (x : Carrier) → (h : FinMapMaybe n Carrier) → InsertionResult i x h (checkInsert i x h)
35 insertionresult i x h with lookupM i h | inspect (lookupM i) h
36 insertionresult i x h | just x' | _ with deq x x'
37 insertionresult i x h | just .x | [ il ] | yes refl = same il
38 insertionresult i x h | just x' | [ il ] | no x≢x' = wrong x' x≢x' il
39 insertionresult i x h | nothing | [ il ] = new il
40
41 lemma-checkInsert-same : {n : ℕ} → (i : Fin n) → (x : Carrier) → (m : FinMapMaybe n Carrier) → lookupM i m ≡ just x → checkInsert i x m ≡ just m
42 lemma-checkInsert-same i x m p with lookupM i m
43 lemma-checkInsert-same i x m refl | .(just x) with deq x x
44 lemma-checkInsert-same i x m refl | .(just x) | yes refl = refl
45 lemma-checkInsert-same i x m refl | .(just x) | no x≢x = contradiction refl x≢x
46
47 lemma-checkInsert-new : {n : ℕ} → (i : Fin n) → (x : Carrier) → (m : FinMapMaybe n Carrier) → lookupM i m ≡ nothing → checkInsert i x m ≡ just (insert i x m)
48 lemma-checkInsert-new i x m p with lookupM i m
49 lemma-checkInsert-new i x m refl | .nothing = refl
50
51 lemma-checkInsert-wrong : {n : ℕ} → (i : Fin n) → (x : Carrier) → (m : FinMapMaybe n Carrier) → (x' : Carrier) → x ≢ x' → lookupM i m ≡ just x' → checkInsert i x m ≡ nothing
52 lemma-checkInsert-wrong i x m x' d p with lookupM i m
53 lemma-checkInsert-wrong i x m x' d refl | .(just x') with deq x x'
54 lemma-checkInsert-wrong i x m x' d refl | .(just x') | yes q = contradiction q d
55 lemma-checkInsert-wrong i x m x' d refl | .(just x') | no q = refl
56
57 vecSetoidToProp : {A : Set} {n : ℕ} {x y : Setoid.Carrier (vecIsSetoid (MaybeEq (PropEq A)) n)} → Setoid._≈_ (vecIsSetoid (MaybeEq (PropEq A)) n) x y → x ≡ y
58 vecSetoidToProp VecEq.[]-cong              = refl
59 vecSetoidToProp (just refl VecEq.∷-cong p) = cong (_∷V_ _) (vecSetoidToProp p)
60 vecSetoidToProp (nothing VecEq.∷-cong p)   = cong (_∷V_ _) (vecSetoidToProp p)
61
62 lemma-checkInsert-restrict : {n : ℕ} → (f : Fin n → Carrier) → (i : Fin n) → (is : List (Fin n)) → checkInsert i (f i) (restrict f is) ≡ just (restrict f (i ∷ is))
63 lemma-checkInsert-restrict f i is with checkInsert i (f i) (restrict f is) | insertionresult i (f i) (restrict f is)
64 lemma-checkInsert-restrict f i is | ._ | same p = cong just (vecSetoidToProp (lemma-insert-same _ i (f i) (maybeEq-from-≡ p)))
65 lemma-checkInsert-restrict f i is | ._ | new _ = refl
66 lemma-checkInsert-restrict f i is | ._ | wrong x fi≢x p = contradiction (lemma-lookupM-restrict i f is x p) fi≢x
67
68 lemma-lookupM-checkInsert : {n : ℕ} → (i j : Fin n) → (x y : Carrier) → (h h' : FinMapMaybe n Carrier) → lookupM i h ≡ just x → checkInsert j y h ≡ just h' → lookupM i h' ≡ just x
69 lemma-lookupM-checkInsert i j x y h h' pl ph' with checkInsert j y h | insertionresult j y h
70 lemma-lookupM-checkInsert i j x y h .h pl refl | ._ | same _ = pl
71 lemma-lookupM-checkInsert i j x y h h' pl ph'  | ._ | new _ with i ≟ j
72 lemma-lookupM-checkInsert i .i x y h h' pl ph' | ._ | new pl' | yes refl = lemma-just≢nothing pl pl'
73 lemma-lookupM-checkInsert i j x y h .(insert j y h) pl refl | ._ | new _ | no i≢j = begin
74   lookupM i (insert j y h)
75     ≡⟨ sym (lemma-lookupM-insert-other i j y h i≢j) ⟩
76   lookupM i h
77     ≡⟨ pl ⟩
78   just x ∎
79 lemma-lookupM-checkInsert i j x y h h' pl () | ._ | wrong _ _ _
80
81 lemma-lookupM-checkInsert-other : {n : ℕ} → (i j : Fin n) → i ≢ j → (x : Carrier) → (h h' : FinMapMaybe n Carrier) → checkInsert j x h ≡ just h' → lookupM i h ≡ lookupM i h'
82 lemma-lookupM-checkInsert-other i j i≢j x h h' ph' with lookupM j h
83 lemma-lookupM-checkInsert-other i j i≢j x h h' ph' | just y with deq x y
84 lemma-lookupM-checkInsert-other i j i≢j x h .h refl | just .x | yes refl = refl
85 lemma-lookupM-checkInsert-other i j i≢j x h h' () | just y | no x≢y
86 lemma-lookupM-checkInsert-other i j i≢j x h .(insert j x h) refl | nothing = lemma-lookupM-insert-other i j x h i≢j