drop-suc is cong pred
[~helmut/bidiragda.git] / Examples.agda
1 module Examples where
2
3 open import Data.Nat using (ℕ ; zero ; suc ; _+_ ; ⌈_/2⌉ ; pred)
4 open import Data.Nat.Properties using (cancel-+-left)
5 import Algebra.Structures
6 open Algebra.Structures.IsCommutativeSemiring Data.Nat.Properties.isCommutativeSemiring using (+-isCommutativeMonoid)
7 open Algebra.Structures.IsCommutativeMonoid +-isCommutativeMonoid using () renaming (comm to +-comm)
8 open import Data.List using (List ; length) renaming ([] to []L ; _∷_ to _∷L_)
9 open import Data.Vec using (Vec ; [] ; _∷_ ; reverse ; _++_ ; tail ; take ; drop)
10 open import Function using (id)
11 open import Function.Injection using () renaming (Injection to _↪_ ; id to id↪)
12 open import Relation.Binary.PropositionalEquality using (_≡_ ; refl ; cong) renaming (setoid to EqSetoid)
13
14 open import Generic using (≡-to-Π)
15 open import Structures using (Shaped)
16 import GetTypes
17 import FreeTheorems
18
19 open GetTypes.PartialVecVec using (Get)
20 open FreeTheorems.PartialVecVec using (assume-get)
21
22 reverse' : Get
23 reverse' = assume-get id↪ (≡-to-Π id) reverse
24
25 double' : Get
26 double' = assume-get id↪ (≡-to-Π g) f
27   where g : ℕ → ℕ
28         g zero = zero
29         g (suc n) = suc (suc (g n))
30         f : {A : Set} {n : ℕ} → Vec A n → Vec A (g n)
31         f []      = []
32         f (x ∷ v) = x ∷ x ∷ f v
33
34 double'' : Get
35 double'' = assume-get id↪ (≡-to-Π _) (λ v → v ++ v)
36
37 suc-injection : EqSetoid ℕ ↪ EqSetoid ℕ
38 suc-injection = record { to = ≡-to-Π suc; injective = cong pred }
39
40 tail' : Get
41 tail' = assume-get suc-injection (≡-to-Π id) tail
42
43 n+-injection : ℕ → EqSetoid ℕ ↪ EqSetoid ℕ
44 n+-injection n = record { to = ≡-to-Π (_+_ n); injective = cancel-+-left n }
45
46 take' : ℕ → Get
47 take' n = assume-get (n+-injection n) (≡-to-Π _) (take n)
48
49 drop' : ℕ → Get
50 drop' n = assume-get (n+-injection n) (≡-to-Π _) (drop n)
51
52 sieve' : Get
53 sieve' = assume-get id↪ (≡-to-Π _) f
54   where f : {A : Set} {n : ℕ} → Vec A n → Vec A ⌈ n /2⌉
55         f []           = []
56         f (x ∷ [])     = x ∷ []
57         f (x ∷ _ ∷ xs) = x ∷ f xs
58
59 intersperse-len : ℕ → ℕ
60 intersperse-len zero          = zero
61 intersperse-len (suc zero)    = suc zero
62 intersperse-len (suc (suc n)) = suc (suc (intersperse-len (suc n)))
63
64 intersperse : {A : Set} {n : ℕ} → A → Vec A n → Vec A (intersperse-len n)
65 intersperse s []          = []
66 intersperse s (x ∷ [])    = x ∷ []
67 intersperse s (x ∷ y ∷ v) = x ∷ s ∷ intersperse s (y ∷ v)
68
69 intersperse' : Get
70 intersperse' = assume-get suc-injection (≡-to-Π intersperse-len) f
71   where f : {A : Set} {n : ℕ} → Vec A (suc n) → Vec A (intersperse-len n)
72         f (s ∷ v)        = intersperse s v
73
74 data PairVec (α : Set) (β : Set) : List α → Set where
75   []P : PairVec α β []L
76   _,_∷P_ : (x : α) → β → {l : List α} → PairVec α β l → PairVec α β (x ∷L l)
77
78 PairVecFirstShaped : (α : Set) → Shaped (List α) (PairVec α)
79 PairVecFirstShaped α = record
80   { arity = length
81   ; content = content
82   ; fill = fill
83   ; isShaped = record
84     { content-fill = content-fill
85     ; fill-content = fill-content
86     } }
87   where content : {β : Set} {s : List α} → PairVec α β s → Vec β (length s)
88         content []P          = []
89         content (a , b ∷P p) = b ∷ content p
90
91         fill : {β : Set} → (s : List α) → Vec β (length s) → PairVec α β s
92         fill []L      v       = []P
93         fill (a ∷L s) (b ∷ v) = a , b ∷P fill s v
94
95         content-fill : {β : Set} {s : List α} → (p : PairVec α β s) → fill s (content p) ≡ p
96         content-fill []P          = refl
97         content-fill (a , b ∷P p) = cong (_,_∷P_ a b) (content-fill p)
98
99         fill-content : {β : Set} → (s : List α) → (v : Vec β (length s)) → content (fill s v) ≡ v
100         fill-content []L      []      = refl
101         fill-content (a ∷L s) (b ∷ v) = cong (_∷_ b) (fill-content s v)