fix compilation against agda stdlib 0.9
[~helmut/bidiragda.git] / Examples.agda
1 module Examples where
2
3 open import Data.Nat using (ℕ ; zero ; suc ; _+_ ; ⌈_/2⌉)
4 open import Data.Nat.Properties using (cancel-+-left)
5 import Algebra.Structures
6 open import Data.List using (List ; length) renaming ([] to []L ; _∷_ to _∷L_)
7 open import Data.Vec using (Vec ; [] ; _∷_ ; reverse ; _++_ ; tail ; take ; drop)
8 open import Function using (id)
9 open import Relation.Binary.PropositionalEquality using (_≡_ ; refl ; cong) renaming (setoid to EqSetoid)
10
11 open import Generic using (≡-to-Π)
12 open import Structures using (Shaped)
13 import GetTypes
14 import FreeTheorems
15
16 open GetTypes.PartialVecVec using (Get)
17 open FreeTheorems.PartialVecVec using (assume-get)
18
19 reverse' : Get
20 reverse' = assume-get (≡-to-Π id) (≡-to-Π id) reverse
21
22 double' : Get
23 double' = assume-get (≡-to-Π id) (≡-to-Π g) f
24   where g : ℕ → ℕ
25         g zero = zero
26         g (suc n) = suc (suc (g n))
27         f : {A : Set} {n : ℕ} → Vec A n → Vec A (g n)
28         f []      = []
29         f (x ∷ v) = x ∷ x ∷ f v
30
31 double'' : Get
32 double'' = assume-get (≡-to-Π id) (≡-to-Π _) (λ v → v ++ v)
33
34 tail' : Get
35 tail' = assume-get (≡-to-Π suc) (≡-to-Π id) tail
36
37 take' : ℕ → Get
38 take' n = assume-get (≡-to-Π (_+_ n)) (≡-to-Π _) (take n)
39
40 drop' : ℕ → Get
41 drop' n = assume-get (≡-to-Π (_+_ n)) (≡-to-Π _) (drop n)
42
43 sieve' : Get
44 sieve' = assume-get (≡-to-Π id) (≡-to-Π _) f
45   where f : {A : Set} {n : ℕ} → Vec A n → Vec A ⌈ n /2⌉
46         f []           = []
47         f (x ∷ [])     = x ∷ []
48         f (x ∷ _ ∷ xs) = x ∷ f xs
49
50 intersperse-len : ℕ → ℕ
51 intersperse-len zero          = zero
52 intersperse-len (suc zero)    = suc zero
53 intersperse-len (suc (suc n)) = suc (suc (intersperse-len (suc n)))
54
55 intersperse : {A : Set} {n : ℕ} → A → Vec A n → Vec A (intersperse-len n)
56 intersperse s []          = []
57 intersperse s (x ∷ [])    = x ∷ []
58 intersperse s (x ∷ y ∷ v) = x ∷ s ∷ intersperse s (y ∷ v)
59
60 intersperse' : Get
61 intersperse' = assume-get (≡-to-Π suc) (≡-to-Π intersperse-len) f
62   where f : {A : Set} {n : ℕ} → Vec A (suc n) → Vec A (intersperse-len n)
63         f (s ∷ v)        = intersperse s v
64
65 data PairVec (α : Set) (β : Set) : List α → Set where
66   []P : PairVec α β []L
67   _,_∷P_ : (x : α) → β → {l : List α} → PairVec α β l → PairVec α β (x ∷L l)
68
69 PairVecFirstShaped : (α : Set) → Shaped (List α) (PairVec α)
70 PairVecFirstShaped α = record
71   { arity = length
72   ; content = content
73   ; fill = fill
74   ; isShaped = record
75     { content-fill = content-fill
76     ; fill-content = fill-content
77     } }
78   where content : {β : Set} {s : List α} → PairVec α β s → Vec β (length s)
79         content []P          = []
80         content (a , b ∷P p) = b ∷ content p
81
82         fill : {β : Set} → (s : List α) → Vec β (length s) → PairVec α β s
83         fill []L      v       = []P
84         fill (a ∷L s) (b ∷ v) = a , b ∷P fill s v
85
86         content-fill : {β : Set} {s : List α} → (p : PairVec α β s) → fill s (content p) ≡ p
87         content-fill []P          = refl
88         content-fill (a , b ∷P p) = cong (_,_∷P_ a b) (content-fill p)
89
90         fill-content : {β : Set} → (s : List α) → (v : Vec β (length s)) → content (fill s v) ≡ v
91         fill-content []L      []      = refl
92         fill-content (a ∷L s) (b ∷ v) = cong (_∷_ b) (fill-content s v)