remove lemma-lookupM-insert in favour of lookup∘update
[~helmut/bidiragda.git] / FinMap.agda
1 module FinMap where
2
3 open import Level using () renaming (zero to ℓ₀)
4 open import Data.Nat using (ℕ ; zero ; suc)
5 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Properties using (_≟_)
8 open import Data.Vec using (Vec ; [] ; _∷_ ; _[_]≔_ ; replicate ; tabulate ; foldr ; zip ; toList) renaming (lookup to lookupVec ; map to mapV)
9 open import Data.Vec.Equality using ()
10 open import Data.Vec.Properties using (lookup∘update)
11 open import Data.Product using (__ ; _,_)
12 open import Data.List.All as All using (All)
13 import Data.List.All.Properties as AllP
14 import Data.List.Any as Any
15 import Data.List.Any.Membership.Propositional
16 open import Function using (id ; _∘_ ; flip ; const)
17 open import Function.Equality using (module Π)
18 open import Function.Surjection using (module Surjection)
19 open import Relation.Nullary using (yes ; no)
20 open import Relation.Nullary.Negation using (contradiction)
21 open import Relation.Binary.Core using (_≡_ ; refl ; _≢_ ; Decidable)
22 open import Relation.Binary.PropositionalEquality as P using (cong ; sym ; _≗_ ; trans ; cong₂)
23 open P.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
24
25 open import Generic using (just-injective)
26
27 _∈_ : {A : Set} {n : ℕ} → A → Vec A n → Set
28 _∈_ {A} x xs = x Data.List.Any.Membership.Propositional.∈ (toList xs)
29
30 _∉_ : {A : Set} {n : ℕ} → A → Vec A n → Set
31 _∉_ {A} x xs = All (_≢_ x) (toList xs)
32
33 data Dec∈ {A : Set} {n : ℕ} (x : A) (xs : Vec A n) : Set where
34   yes-∈ : x ∈ xs → Dec∈ x xs
35   no-∉ : x ∉ xs → Dec∈ x xs
36
37 is-∈ : {A : Set} {n : ℕ} → Decidable (_≡_ {A = A}) → (x : A) → (xs : Vec A n) → Dec∈ x xs
38 is-∈ eq? x xs with Any.any (eq? x) (toList xs)
39 ...     | yes x∈xs = yes-∈ x∈xs
40 ...     | no  x∉xs = no-∉ (Π._⟨$⟩_ (Surjection.to AllP.¬Any↠All¬) x∉xs)
41
42 FinMapMaybe : ℕ → Set → Set
43 FinMapMaybe n A = Vec (Maybe A) n
44
45 lookupM : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → Maybe A
46 lookupM = lookupVec
47
48 insert : {A : Set} {n : ℕ} → Fin n → A → FinMapMaybe n A → FinMapMaybe n A
49 insert f a m = m [ f ]≔ (just a)
50
51 empty : {A : Set} {n : ℕ} → FinMapMaybe n A
52 empty = replicate nothing
53
54 fromAscList : {A : Set} {n m : ℕ} → Vec (Fin n × A) m → FinMapMaybe n A
55 fromAscList []             = empty
56 fromAscList ((f , a) ∷ xs) = insert f a (fromAscList xs)
57
58 fromFunc : {A : Set} {n : ℕ} → (Fin n → A) → FinMapMaybe n A
59 fromFunc = tabulate ∘ _∘_ Maybe.just
60
61 reshape : {n : ℕ} {A : Set} → FinMapMaybe n A → (l : ℕ) → FinMapMaybe l A
62 reshape m        zero    = []
63 reshape []       (suc l) = nothing ∷ (reshape [] l)
64 reshape (x ∷ xs) (suc l) = x ∷ (reshape xs l)
65
66 union : {A : Set} {n : ℕ} → FinMapMaybe n A → FinMapMaybe n A → FinMapMaybe n A
67 union m1 m2 = tabulate (λ f → maybe′ just (lookupM f m2) (lookupM f m1))
68
69 restrict : {A : Set} {n m : ℕ} → (Fin n → A) → Vec (Fin n) m → FinMapMaybe n A
70 restrict f is = fromAscList (zip is (mapV f is))
71
72 delete : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → FinMapMaybe n A
73 delete i m = m [ i ]≔ nothing
74
75 delete-many : {A : Set} {n m : ℕ} → Vec (Fin n) m → FinMapMaybe n A → FinMapMaybe n A
76 delete-many = flip (foldr (const _) delete)
77
78 lemma-insert-same : {n : ℕ} {A : Set} → (m : FinMapMaybe n A) → (f : Fin n) → {a : A} → lookupM f m ≡ just a → m ≡ insert f a m
79 lemma-insert-same         []       ()      p
80 lemma-insert-same {suc n} (x ∷ xs) zero    p = cong (flip _∷_ xs) p
81 lemma-insert-same         (x ∷ xs) (suc i) p = cong (_∷_ x) (lemma-insert-same xs i p)
82
83 lemma-lookupM-empty : {A : Set} {n : ℕ} → (i : Fin n) → lookupM {A} i empty ≡ nothing
84 lemma-lookupM-empty zero    = refl
85 lemma-lookupM-empty (suc i) = lemma-lookupM-empty i
86
87 lemma-lookupM-insert-other : {A : Set} {n : ℕ} → (i j : Fin n) → (a : A) → (m : FinMapMaybe n A) → i ≢ j → lookupM i (insert j a m) ≡ lookupM i m
88 lemma-lookupM-insert-other zero    zero    a m        p = contradiction refl p
89 lemma-lookupM-insert-other zero    (suc j) a (x ∷ xs) p = refl
90 lemma-lookupM-insert-other (suc i) zero    a (x ∷ xs) p = refl
91 lemma-lookupM-insert-other (suc i) (suc j) a (x ∷ xs) p = lemma-lookupM-insert-other i j a xs (p ∘ cong suc)
92
93 lemma-lookupM-restrict : {A : Set} {n m : ℕ} → (i : Fin n) → (f : Fin n → A) → (is : Vec (Fin n) m) → {a : A} → lookupM i (restrict f is) ≡ just a → f i ≡ a
94 lemma-lookupM-restrict i f []            p = contradiction (trans (sym p) (lemma-lookupM-empty i)) (λ ())
95 lemma-lookupM-restrict i f (i' ∷ is)     p with i ≟ i'
96 lemma-lookupM-restrict i f (.i ∷ is) {a} p | yes refl = just-injective (begin
97    just (f i)
98      ≡⟨ sym (lookup∘update i (restrict f is) (just (f i))) ⟩
99    lookupM i (insert i (f i) (restrict f is))
100      ≡⟨ p ⟩
101    just a ∎)
102 lemma-lookupM-restrict i f (i' ∷ is) {a} p | no i≢i' = lemma-lookupM-restrict i f is (begin
103   lookupM i (restrict f is)
104     ≡⟨ sym (lemma-lookupM-insert-other i i' (f i') (restrict f is) i≢i') ⟩
105   lookupM i (insert i' (f i') (restrict f is))
106     ≡⟨ p ⟩
107   just a ∎)
108 lemma-lookupM-restrict-∈ : {A : Set} {n m : ℕ} → (i : Fin n) → (f : Fin n → A) → (js : Vec (Fin n) m) → i ∈ js → lookupM i (restrict f js) ≡ just (f i)
109 lemma-lookupM-restrict-∈ i f [] ()
110 lemma-lookupM-restrict-∈ i f (j ∷ js)  p             with i ≟ j
111 lemma-lookupM-restrict-∈ i f (.i ∷ js) p             | yes refl = lookup∘update i (restrict f js) (just (f i))
112 lemma-lookupM-restrict-∈ i f (j ∷ js) (Any.here i≡j) | no i≢j = contradiction i≡j i≢j
113 lemma-lookupM-restrict-∈ i f (j ∷ js) (Any.there p)  | no i≢j =
114   trans (lemma-lookupM-insert-other i j (f j) (restrict f js) i≢j)
115         (lemma-lookupM-restrict-∈ i f js p)
116
117 lemma-lookupM-restrict-∉ : {A : Set} {n m : ℕ} → (i : Fin n) → (f : Fin n → A) → (js : Vec (Fin n) m) → i ∉ js → lookupM i (restrict f js) ≡ nothing
118 lemma-lookupM-restrict-∉ i f []       i∉[]  = lemma-lookupM-empty i
119 lemma-lookupM-restrict-∉ i f (j ∷ js) i∉jjs =
120   trans (lemma-lookupM-insert-other i j (f j) (restrict f js) (All.head i∉jjs))
121         (lemma-lookupM-restrict-∉ i f js (All.tail i∉jjs))
122
123 lemma-tabulate-∘ : {n : ℕ} {A : Set} → {f g : Fin n → A} → f ≗ g → tabulate f ≡ tabulate g
124 lemma-tabulate-∘ {zero}  {_} {f} {g} f≗g = refl
125 lemma-tabulate-∘ {suc n} {_} {f} {g} f≗g = cong₂ _∷_ (f≗g zero) (lemma-tabulate-∘ (f≗g ∘ suc))
126
127 lemma-lookupM-fromFunc : {n : ℕ} {A : Set} → (f : Fin n → A) → flip lookupM (fromFunc f) ≗ Maybe.just ∘ f
128 lemma-lookupM-fromFunc f zero = refl
129 lemma-lookupM-fromFunc f (suc i) = lemma-lookupM-fromFunc (f ∘ suc) i
130
131 lemma-lookupM-delete : {n : ℕ} {A : Set} {i j : Fin n} → (f : FinMapMaybe n A) → i ≢ j → lookupM i (delete j f) ≡ lookupM i f
132 lemma-lookupM-delete {i = zero}  {j = zero}  (_ ∷ _)  p = contradiction refl p
133 lemma-lookupM-delete {i = zero}  {j = suc j} (_ ∷ _)  p = refl
134 lemma-lookupM-delete {i = suc i} {j = zero}  (x ∷ xs) p = refl
135 lemma-lookupM-delete {i = suc i} {j = suc j} (x ∷ xs) p = lemma-lookupM-delete xs (p ∘ cong suc)
136
137 lemma-lookupM-delete-many : {n m : ℕ} {A : Set} (h : FinMapMaybe n A) → (i : Fin n) → (js : Vec (Fin n) m) → i ∉ js → lookupM i (delete-many js h) ≡ lookupM i h
138 lemma-lookupM-delete-many {n} h i []       i∉[]  = refl
139 lemma-lookupM-delete-many {n} h i (j ∷ js) i∉jjs =
140   trans (lemma-lookupM-delete (delete-many js h) (All.head i∉jjs))
141         (lemma-lookupM-delete-many h i js (All.tail i∉jjs))
142
143 lemma-reshape-id : {n : ℕ} {A : Set} → (m : FinMapMaybe n A) → reshape m n ≡ m
144 lemma-reshape-id []       = refl
145 lemma-reshape-id (x ∷ xs) = cong (_∷_ x) (lemma-reshape-id xs)
146
147 lemma-disjoint-union : {n m : ℕ} {A : Set} → (f : Fin n → A) → (t : Vec (Fin n) m) → union (restrict f t) (delete-many t (fromFunc f)) ≡ fromFunc f
148 lemma-disjoint-union {n} f t = lemma-tabulate-∘ inner
149   where inner : (x : Fin n) → maybe′ just (lookupM x (delete-many t (fromFunc f))) (lookupM x (restrict f t)) ≡ just (f x)
150         inner x with is-∈ _≟_ x t
151         inner x | yes-∈ x∈t = cong (maybe′ just (lookupM x (delete-many t (fromFunc f)))) (lemma-lookupM-restrict-∈ x f t x∈t)
152         inner x | no-∉ x∉t = begin
153           maybe′ just (lookupM x (delete-many t (fromFunc f))) (lookupM x (restrict f t))
154             ≡⟨ cong₂ (maybe′ just) (lemma-lookupM-delete-many (fromFunc f) x t x∉t) (lemma-lookupM-restrict-∉ x f t x∉t) ⟩
155           maybe′ just (lookupM x (fromFunc f)) nothing
156             ≡⟨ lemma-lookupM-fromFunc f x ⟩
157           just (f x) ∎
158
159 lemma-exchange-maps : {n m : ℕ} → {A : Set} → {h h′ : FinMapMaybe n A} → {P : Fin n → Set} → (∀ j → P j → lookupM j h ≡ lookupM j h′) → {is : Vec (Fin n) m} → All P (toList is) → mapV (flip lookupM h) is ≡ mapV (flip lookupM h′) is
160 lemma-exchange-maps h≈h′ {[]}     All.[]         = refl
161 lemma-exchange-maps h≈h′ {i ∷ is} (pi All.∷ pis) = cong₂ _∷_ (h≈h′ i pi) (lemma-exchange-maps h≈h′ pis)