FinMap.lemma-lookupM-fromFunc is almost Data.Vec.Properties.lookup∘tabulate
[~helmut/bidiragda.git] / FinMap.agda
1 module FinMap where
2
3 open import Level using () renaming (zero to ℓ₀)
4 open import Data.Nat using (ℕ ; zero ; suc)
5 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Properties using (_≟_)
8 open import Data.Vec using (Vec ; [] ; _∷_ ; _[_]≔_ ; replicate ; tabulate ; foldr ; zip ; toList) renaming (lookup to lookupVec ; map to mapV)
9 open import Data.Vec.Properties using (lookup∘update ; lookup∘update′ ; lookup-replicate ; tabulate-cong ; lookup∘tabulate)
10 open import Data.Product using (__ ; _,_)
11 open import Data.List.All as All using (All)
12 import Data.List.All.Properties as AllP
13 import Data.List.Any as Any
14 import Data.List.Membership.Setoid
15 open import Function using (id ; _∘_ ; flip ; const)
16 open import Function.Equality using (module Π)
17 open import Function.Surjection using (module Surjection)
18 open import Relation.Nullary using (yes ; no)
19 open import Relation.Nullary.Negation using (contradiction)
20 open import Relation.Binary.Core using (Decidable)
21 open import Relation.Binary.PropositionalEquality as P using (_≡_ ; _≢_ ; _≗_)
22 open P.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
23
24 open import Generic using (just-injective)
25
26 _∈_ : {A : Set} {n : ℕ} → A → Vec A n → Set
27 _∈_ {A} x xs = Data.List.Membership.Setoid._∈_ (P.setoid A) x (toList xs)
28
29 _∉_ : {A : Set} {n : ℕ} → A → Vec A n → Set
30 _∉_ {A} x xs = All (_≢_ x) (toList xs)
31
32 data Dec∈ {A : Set} {n : ℕ} (x : A) (xs : Vec A n) : Set where
33   yes-∈ : x ∈ xs → Dec∈ x xs
34   no-∉ : x ∉ xs → Dec∈ x xs
35
36 is-∈ : {A : Set} {n : ℕ} → Decidable (_≡_ {A = A}) → (x : A) → (xs : Vec A n) → Dec∈ x xs
37 is-∈ eq? x xs with Any.any (eq? x) (toList xs)
38 ...     | yes x∈xs = yes-∈ x∈xs
39 ...     | no  x∉xs = no-∉ (Π._⟨$⟩_ (Surjection.to AllP.¬Any↠All¬) x∉xs)
40
41 FinMapMaybe : ℕ → Set → Set
42 FinMapMaybe n A = Vec (Maybe A) n
43
44 lookupM : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → Maybe A
45 lookupM = lookupVec
46
47 insert : {A : Set} {n : ℕ} → Fin n → A → FinMapMaybe n A → FinMapMaybe n A
48 insert f a m = m [ f ]≔ (just a)
49
50 empty : {A : Set} {n : ℕ} → FinMapMaybe n A
51 empty = replicate nothing
52
53 fromAscList : {A : Set} {n m : ℕ} → Vec (Fin n × A) m → FinMapMaybe n A
54 fromAscList []             = empty
55 fromAscList ((f , a) ∷ xs) = insert f a (fromAscList xs)
56
57 fromFunc : {A : Set} {n : ℕ} → (Fin n → A) → FinMapMaybe n A
58 fromFunc = tabulate ∘ _∘_ Maybe.just
59
60 reshape : {n : ℕ} {A : Set} → FinMapMaybe n A → (l : ℕ) → FinMapMaybe l A
61 reshape m        zero    = []
62 reshape []       (suc l) = nothing ∷ (reshape [] l)
63 reshape (x ∷ xs) (suc l) = x ∷ (reshape xs l)
64
65 union : {A : Set} {n : ℕ} → FinMapMaybe n A → FinMapMaybe n A → FinMapMaybe n A
66 union m1 m2 = tabulate (λ f → maybe′ just (lookupM f m2) (lookupM f m1))
67
68 restrict : {A : Set} {n m : ℕ} → (Fin n → A) → Vec (Fin n) m → FinMapMaybe n A
69 restrict f is = fromAscList (zip is (mapV f is))
70
71 delete : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → FinMapMaybe n A
72 delete i m = m [ i ]≔ nothing
73
74 delete-many : {A : Set} {n m : ℕ} → Vec (Fin n) m → FinMapMaybe n A → FinMapMaybe n A
75 delete-many = flip (foldr (const _) delete)
76
77 lemma-insert-same : {n : ℕ} {A : Set} → (m : FinMapMaybe n A) → (f : Fin n) → {a : A} → lookupM f m ≡ just a → m ≡ insert f a m
78 lemma-insert-same         []       ()      p
79 lemma-insert-same {suc n} (x ∷ xs) zero    p = P.cong (flip _∷_ xs) p
80 lemma-insert-same         (x ∷ xs) (suc i) p = P.cong (_∷_ x) (lemma-insert-same xs i p)
81
82 lemma-lookupM-restrict : {A : Set} {n m : ℕ} → (i : Fin n) → (f : Fin n → A) → (is : Vec (Fin n) m) → {a : A} → lookupM i (restrict f is) ≡ just a → f i ≡ a
83 lemma-lookupM-restrict i f []            p = contradiction (P.trans (P.sym p) (lookup-replicate i nothing)) (λ ())
84 lemma-lookupM-restrict i f (i' ∷ is)     p with i ≟ i'
85 lemma-lookupM-restrict i f (.i ∷ is) {a} p | yes P.refl = just-injective (begin
86    just (f i)
87      ≡⟨ P.sym (lookup∘update i (restrict f is) (just (f i))) ⟩
88    lookupM i (insert i (f i) (restrict f is))
89      ≡⟨ p ⟩
90    just a ∎)
91 lemma-lookupM-restrict i f (i' ∷ is) {a} p | no i≢i' = lemma-lookupM-restrict i f is (begin
92   lookupM i (restrict f is)
93     ≡⟨ P.sym (lookup∘update′ i≢i' (restrict f is) (just (f i'))) ⟩
94   lookupM i (insert i' (f i') (restrict f is))
95     ≡⟨ p ⟩
96   just a ∎)
97 lemma-lookupM-restrict-∈ : {A : Set} {n m : ℕ} → (i : Fin n) → (f : Fin n → A) → (js : Vec (Fin n) m) → i ∈ js → lookupM i (restrict f js) ≡ just (f i)
98 lemma-lookupM-restrict-∈ i f [] ()
99 lemma-lookupM-restrict-∈ i f (j ∷ js)  p             with i ≟ j
100 lemma-lookupM-restrict-∈ i f (.i ∷ js) p             | yes P.refl = lookup∘update i (restrict f js) (just (f i))
101 lemma-lookupM-restrict-∈ i f (j ∷ js) (Any.here i≡j) | no i≢j = contradiction i≡j i≢j
102 lemma-lookupM-restrict-∈ i f (j ∷ js) (Any.there p)  | no i≢j =
103   P.trans (lookup∘update′ i≢j (restrict f js) (just (f j)))
104           (lemma-lookupM-restrict-∈ i f js p)
105
106 lemma-lookupM-restrict-∉ : {A : Set} {n m : ℕ} → (i : Fin n) → (f : Fin n → A) → (js : Vec (Fin n) m) → i ∉ js → lookupM i (restrict f js) ≡ nothing
107 lemma-lookupM-restrict-∉ i f []       i∉[]  = lookup-replicate i nothing
108 lemma-lookupM-restrict-∉ i f (j ∷ js) i∉jjs =
109   P.trans (lookup∘update′ (All.head i∉jjs) (restrict f js) (just (f j)))
110           (lemma-lookupM-restrict-∉ i f js (All.tail i∉jjs))
111
112 lemma-lookupM-delete : {n : ℕ} {A : Set} {i j : Fin n} → (f : FinMapMaybe n A) → i ≢ j → lookupM i (delete j f) ≡ lookupM i f
113 lemma-lookupM-delete {i = zero}  {j = zero}  (_ ∷ _)  p = contradiction P.refl p
114 lemma-lookupM-delete {i = zero}  {j = suc j} (_ ∷ _)  p = P.refl
115 lemma-lookupM-delete {i = suc i} {j = zero}  (x ∷ xs) p = P.refl
116 lemma-lookupM-delete {i = suc i} {j = suc j} (x ∷ xs) p = lemma-lookupM-delete xs (p ∘ P.cong suc)
117
118 lemma-lookupM-delete-many : {n m : ℕ} {A : Set} (h : FinMapMaybe n A) → (i : Fin n) → (js : Vec (Fin n) m) → i ∉ js → lookupM i (delete-many js h) ≡ lookupM i h
119 lemma-lookupM-delete-many {n} h i []       i∉[]  = P.refl
120 lemma-lookupM-delete-many {n} h i (j ∷ js) i∉jjs =
121   P.trans (lemma-lookupM-delete (delete-many js h) (All.head i∉jjs))
122           (lemma-lookupM-delete-many h i js (All.tail i∉jjs))
123
124 lemma-reshape-id : {n : ℕ} {A : Set} → (m : FinMapMaybe n A) → reshape m n ≡ m
125 lemma-reshape-id []       = P.refl
126 lemma-reshape-id (x ∷ xs) = P.cong (_∷_ x) (lemma-reshape-id xs)
127
128 lemma-disjoint-union : {n m : ℕ} {A : Set} → (f : Fin n → A) → (t : Vec (Fin n) m) → union (restrict f t) (delete-many t (fromFunc f)) ≡ fromFunc f
129 lemma-disjoint-union {n} f t = tabulate-cong inner
130   where inner : (x : Fin n) → maybe′ just (lookupM x (delete-many t (fromFunc f))) (lookupM x (restrict f t)) ≡ just (f x)
131         inner x with is-∈ _≟_ x t
132         inner x | yes-∈ x∈t = P.cong (maybe′ just (lookupM x (delete-many t (fromFunc f)))) (lemma-lookupM-restrict-∈ x f t x∈t)
133         inner x | no-∉ x∉t = begin
134           maybe′ just (lookupM x (delete-many t (fromFunc f))) (lookupM x (restrict f t))
135             ≡⟨ P.cong₂ (maybe′ just) (lemma-lookupM-delete-many (fromFunc f) x t x∉t) (lemma-lookupM-restrict-∉ x f t x∉t) ⟩
136           maybe′ just (lookupM x (fromFunc f)) nothing
137             ≡⟨ P.cong (flip (maybe′ just) nothing) (lookup∘tabulate (just ∘ f) x) ⟩
138           just (f x) ∎
139
140 lemma-exchange-maps : {n m : ℕ} → {A : Set} → {h h′ : FinMapMaybe n A} → {P : Fin n → Set} → (∀ j → P j → lookupM j h ≡ lookupM j h′) → {is : Vec (Fin n) m} → All P (toList is) → mapV (flip lookupM h) is ≡ mapV (flip lookupM h′) is
141 lemma-exchange-maps h≈h′ {[]}     All.[]         = P.refl
142 lemma-exchange-maps h≈h′ {i ∷ is} (pi All.∷ pis) = P.cong₂ _∷_ (h≈h′ i pi) (lemma-exchange-maps h≈h′ pis)