FinMap.agda

   1 module FinMap where
   2
   3 open import Data.Nat using (ℕ ; zero ; suc)
   4 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
   5 open import Data.Fin using (Fin ; zero ; suc)
   6 open import Data.Fin.Props using (_≟_)
   7 open import Data.Vec using (Vec ; [] ; _∷_ ; _[_]≔_ ; replicate ; tabulate ; foldr ; toList) renaming (lookup to lookupVec ; map to mapV)
   8 open import Data.Vec.Properties using (lookup∘tabulate)
   9 open import Data.List using (List ; [] ; _∷_ ; map ; zip)
  10 open import Data.Product using (_�_ ; _,_)
  11 open import Function using (id ; _∘_ ; flip ; const)
  12 open import Relation.Nullary using (yes ; no)
  13 open import Relation.Nullary.Negation using (contradiction)
  14 open import Relation.Binary.Core using (_≡_ ; refl ; _≢_)
  15 open import Relation.Binary.PropositionalEquality using (cong ; sym ; _≗_ ; trans ; cong₂)
  16 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
  17
  18 open import Generic using (just-injective)
  19
  20 FinMapMaybe : ℕ → Set → Set
  21 FinMapMaybe n A = Vec (Maybe A) n
  22
  23 lookupM : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → Maybe A
  24 lookupM = lookupVec
  25
  26 insert : {A : Set} {n : ℕ} → Fin n → A → FinMapMaybe n A → FinMapMaybe n A
  27 insert f a m = m [ f ]≔ (just a)
  28
  29 empty : {A : Set} {n : ℕ} → FinMapMaybe n A
  30 empty = replicate nothing
  31
  32 fromAscList : {A : Set} {n : ℕ} → List (Fin n × A) → FinMapMaybe n A
  33 fromAscList []             = empty
  34 fromAscList ((f , a) ∷ xs) = insert f a (fromAscList xs)
  35
  36 FinMap : ℕ → Set → Set
  37 FinMap n A = Vec A n
  38
  39 lookup : {A : Set} {n : ℕ} → Fin n → FinMap n A → A
  40 lookup = lookupVec
  41
  42 fromFunc : {A : Set} {n : ℕ} → (Fin n → A) → FinMap n A
  43 fromFunc = tabulate
  44
  45 union : {A : Set} {n : ℕ} → FinMapMaybe n A → FinMapMaybe n A → FinMapMaybe n A
  46 union m1 m2 = fromFunc (λ f → maybe′ just (lookupM f m2) (lookupM f m1))
  47
  48 restrict : {A : Set} {n : ℕ} → (Fin n → A) → List (Fin n) → FinMapMaybe n A
  49 restrict f is = fromAscList (zip is (map f is))
  50
  51 delete : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → FinMapMaybe n A
  52 delete i m = m [ i ]≔ nothing
  53
  54 delete-many : {A : Set} {n m : ℕ} → Vec (Fin n) m → FinMapMaybe n A → FinMapMaybe n A
  55 delete-many = flip (foldr (const _) delete)
  56
  57 partialize : {A : Set} {n : ℕ} → FinMap n A → FinMapMaybe n A
  58 partialize = mapV just
  59
  60 lemma-just≢nothing : {A Whatever : Set} {a : A} {ma : Maybe A} → ma ≡ just a → ma ≡ nothing  → Whatever
  61 lemma-just≢nothing refl ()
  62
  63 lemma-insert-same : {τ : Set} {n : ℕ} → (m : FinMapMaybe n τ) → (f : Fin n) → (a : τ) → lookupM f m ≡ just a → m ≡ insert f a m
  64 lemma-insert-same []               ()      a p
  65 lemma-insert-same (.(just a) ∷ xs) zero    a refl = refl
  66 lemma-insert-same (x ∷ xs)         (suc i) a p    = cong (_∷_ x) (lemma-insert-same xs i a p)
  67
  68 lemma-lookupM-empty : {A : Set} {n : ℕ} → (i : Fin n) → lookupM {A} i empty ≡ nothing
  69 lemma-lookupM-empty zero    = refl
  70 lemma-lookupM-empty (suc i) = lemma-lookupM-empty i
  71
  72 lemma-lookupM-insert : {A : Set} {n : ℕ} → (i : Fin n) → (a : A) → (m : FinMapMaybe n A) → lookupM i (insert i a m) ≡ just a
  73 lemma-lookupM-insert zero    a (x ∷ xs) = refl
  74 lemma-lookupM-insert (suc i) a (x ∷ xs) = lemma-lookupM-insert i a xs
  75
  76 lemma-lookupM-insert-other : {A : Set} {n : ℕ} → (i j : Fin n) → (a : A) → (m : FinMapMaybe n A) → i ≢ j → lookupM i m ≡ lookupM i (insert j a m)
  77 lemma-lookupM-insert-other zero    zero    a m        p = contradiction refl p
  78 lemma-lookupM-insert-other zero    (suc j) a (x ∷ xs) p = refl
  79 lemma-lookupM-insert-other (suc i) zero    a (x ∷ xs) p = refl
  80 lemma-lookupM-insert-other (suc i) (suc j) a (x ∷ xs) p = lemma-lookupM-insert-other i j a xs (p ∘ cong suc)
  81
  82 lemma-lookupM-restrict : {A : Set} {n : ℕ} → (i : Fin n) → (f : Fin n → A) → (is : List (Fin n)) → (a : A) → lookupM i (restrict f is) ≡ just a → f i ≡ a
  83 lemma-lookupM-restrict i f []        a p = lemma-just≢nothing p (lemma-lookupM-empty i)
  84 lemma-lookupM-restrict i f (i' ∷ is) a p with i ≟ i'
  85 lemma-lookupM-restrict i f (.i ∷ is) a p | yes refl = just-injective (begin
  86    just (f i)
  87      ≡⟨ sym (lemma-lookupM-insert i (f i) (restrict f is)) ⟩
  88    lookupM i (insert i (f i) (restrict f is))
  89      ≡⟨ p ⟩
  90    just a ∎)
  91 lemma-lookupM-restrict i f (i' ∷ is) a p | no i≢i' = lemma-lookupM-restrict i f is a (begin
  92   lookupM i (restrict f is)
  93     ≡⟨ lemma-lookupM-insert-other i i' (f i') (restrict f is) i≢i' ⟩
  94   lookupM i (insert i' (f i') (restrict f is))
  95     ≡⟨ p ⟩
  96   just a ∎)
  97
  98 lemma-tabulate-∘ : {n : ℕ} {A : Set} → {f g : Fin n → A} → f ≗ g → tabulate f ≡ tabulate g
  99 lemma-tabulate-∘ {zero}  {_} {f} {g} f≗g = refl
 100 lemma-tabulate-∘ {suc n} {_} {f} {g} f≗g = cong₂ _∷_ (f≗g zero) (lemma-tabulate-∘ (f≗g ∘ suc))
 101
 102 lemma-partialize-fromFunc : {n : ℕ} {A : Set} → (f : Fin n → A) → partialize (fromFunc f) ≡ fromFunc (just ∘ f)
 103 lemma-partialize-fromFunc {zero}  f = refl
 104 lemma-partialize-fromFunc {suc _} f = cong (_∷_ (just (f zero))) (lemma-partialize-fromFunc (f ∘ suc))
 105
 106 lemma-lookupM-delete : {n : ℕ} {A : Set} {i j : Fin n} → (f : FinMapMaybe n A) → i ≢ j → lookupM i (delete j f) ≡ lookupM i f
 107 lemma-lookupM-delete {i = zero}  {j = zero}  (_ ∷ _)  p with p refl
 108 ...                                                      | ()
 109 lemma-lookupM-delete {i = zero}  {j = suc j} (_ ∷ _)  p = refl
 110 lemma-lookupM-delete {i = suc i} {j = zero}  (x ∷ xs) p = refl
 111 lemma-lookupM-delete {i = suc i} {j = suc j} (x ∷ xs) p = lemma-lookupM-delete xs (p ∘ cong suc)
 112
 113 lemma-disjoint-union : {n m : ℕ} {A : Set} → (f : Fin n → A) → (t : Vec (Fin n) m) → union (restrict f (toList t)) (delete-many t (partialize (fromFunc f))) ≡ partialize (fromFunc f)
 114 lemma-disjoint-union {n} {m} f t = trans (lemma-tabulate-∘ (lemma-inner t)) (sym (lemma-partialize-fromFunc f))
 115     where lemma-inner : {m : ℕ} → (t : Vec (Fin n) m) → (x : Fin n) → maybe′ just (lookupM x (delete-many t (partialize (fromFunc f)))) (lookupM x (restrict f (toList t))) ≡ just (f x)
 116           lemma-inner [] x = begin
 117             maybe′ just (lookupM x (partialize (fromFunc f))) (lookupM x empty)
 118               ≡⟨ cong (maybe′ just (lookupM x (partialize (fromFunc f)))) (lemma-lookupM-empty x) ⟩
 119             lookupM x (partialize (fromFunc f))
 120               ≡⟨ cong (lookupM x) (lemma-partialize-fromFunc f) ⟩
 121             lookupM x (fromFunc (just ∘ f))
 122               ≡⟨ lookup∘tabulate (just ∘ f) x ⟩
 123             just (f x) ∎
 124           lemma-inner (t ∷ ts) x with x ≟ t
 125           lemma-inner (.x ∷ ts) x | yes refl = cong (maybe′ just (lookupM x (delete-many (x ∷ ts) (partialize (fromFunc f))))) (lemma-lookupM-insert x (f x) (restrict f (toList ts)))
 126           lemma-inner (t ∷ ts) x | no ¬p = begin
 127             maybe′ just (lookupM x (delete-many (t ∷ ts) (partialize (fromFunc f)))) (lookupM x (restrict f (toList (t ∷ ts))))
 128               ≡⟨ cong (maybe′ just (lookupM x (delete-many (t ∷ ts) (partialize (fromFunc f))))) (sym (lemma-lookupM-insert-other x t (f t) (restrict f (toList ts)) ¬p)) ⟩
 129             maybe′ just (lookupM x (delete-many (t ∷ ts) (partialize (fromFunc f)))) (lookupM x (restrict f (toList ts)))
 130               ≡⟨ cong (flip (maybe′ just) (lookupM x (restrict f (toList ts)))) (lemma-lookupM-delete (delete-many ts (partialize (fromFunc f))) ¬p) ⟩
 131             maybe′ just (lookupM x (delete-many ts (partialize (fromFunc f)))) (lookupM x (restrict f (toList ts)))
 132               ≡⟨ lemma-inner ts x ⟩
 133             just (f x) ∎