also show the other direction GetL-to-GetV
[~helmut/bidiragda.git] / FinMap.agda
1 module FinMap where
2
3 open import Level using () renaming (zero to ℓ₀)
4 open import Data.Nat using (ℕ ; zero ; suc)
5 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′) renaming (setoid to MaybeEq)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.Vec using (Vec ; [] ; _∷_ ; _[_]≔_ ; replicate ; tabulate ; foldr ; toList) renaming (lookup to lookupVec ; map to mapV)
9 open import Data.Vec.Equality using ()
10 open Data.Vec.Equality.Equality using (_∷-cong_)
11 open import Data.Vec.Properties using (lookup∘tabulate)
12 open import Data.List using (List ; [] ; _∷_ ; map ; zip)
13 open import Data.Product using (__ ; _,_)
14 open import Function using (id ; _∘_ ; flip ; const)
15 open import Relation.Nullary using (yes ; no)
16 open import Relation.Nullary.Negation using (contradiction)
17 open import Relation.Binary using (Setoid ; module Setoid)
18 open import Relation.Binary.Core using (_≡_ ; refl ; _≢_)
19 open import Relation.Binary.PropositionalEquality using (cong ; sym ; _≗_ ; trans ; cong₂)
20 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
21
22 open import Generic using (just-injective)
23
24 FinMapMaybe : ℕ → Set → Set
25 FinMapMaybe n A = Vec (Maybe A) n
26
27 lookupM : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → Maybe A
28 lookupM = lookupVec
29
30 insert : {A : Set} {n : ℕ} → Fin n → A → FinMapMaybe n A → FinMapMaybe n A
31 insert f a m = m [ f ]≔ (just a)
32
33 empty : {A : Set} {n : ℕ} → FinMapMaybe n A
34 empty = replicate nothing
35
36 fromAscList : {A : Set} {n : ℕ} → List (Fin n × A) → FinMapMaybe n A
37 fromAscList []             = empty
38 fromAscList ((f , a) ∷ xs) = insert f a (fromAscList xs)
39
40 fromFunc : {A : Set} {n : ℕ} → (Fin n → A) → FinMapMaybe n A
41 fromFunc = mapV just ∘ tabulate
42
43 union : {A : Set} {n : ℕ} → FinMapMaybe n A → FinMapMaybe n A → FinMapMaybe n A
44 union m1 m2 = tabulate (λ f → maybe′ just (lookupM f m2) (lookupM f m1))
45
46 restrict : {A : Set} {n : ℕ} → (Fin n → A) → List (Fin n) → FinMapMaybe n A
47 restrict f is = fromAscList (zip is (map f is))
48
49 delete : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → FinMapMaybe n A
50 delete i m = m [ i ]≔ nothing
51
52 delete-many : {A : Set} {n m : ℕ} → Vec (Fin n) m → FinMapMaybe n A → FinMapMaybe n A
53 delete-many = flip (foldr (const _) delete)
54
55 lemma-just≢nothing : {A Whatever : Set} {a : A} {ma : Maybe A} → ma ≡ just a → ma ≡ nothing  → Whatever
56 lemma-just≢nothing refl ()
57
58 lemma-insert-same : {n : ℕ} {A : Set} → (m : FinMapMaybe n A) → (f : Fin n) → (a : A) → lookupM f m ≡ just a → m ≡ insert f a m
59 lemma-insert-same         []       ()      a p
60 lemma-insert-same {suc n} (x ∷ xs) zero    a p = cong (flip _∷_ xs) p
61 lemma-insert-same         (x ∷ xs) (suc i) a p = cong (_∷_ x) (lemma-insert-same xs i a p)
62
63 lemma-lookupM-empty : {A : Set} {n : ℕ} → (i : Fin n) → lookupM {A} i empty ≡ nothing
64 lemma-lookupM-empty zero    = refl
65 lemma-lookupM-empty (suc i) = lemma-lookupM-empty i
66
67 lemma-lookupM-insert : {A : Set} {n : ℕ} → (i : Fin n) → (a : A) → (m : FinMapMaybe n A) → lookupM i (insert i a m) ≡ just a
68 lemma-lookupM-insert zero    a (x ∷ xs) = refl
69 lemma-lookupM-insert (suc i) a (x ∷ xs) = lemma-lookupM-insert i a xs
70
71 lemma-lookupM-insert-other : {A : Set} {n : ℕ} → (i j : Fin n) → (a : A) → (m : FinMapMaybe n A) → i ≢ j → lookupM i m ≡ lookupM i (insert j a m)
72 lemma-lookupM-insert-other zero    zero    a m        p = contradiction refl p
73 lemma-lookupM-insert-other zero    (suc j) a (x ∷ xs) p = refl
74 lemma-lookupM-insert-other (suc i) zero    a (x ∷ xs) p = refl
75 lemma-lookupM-insert-other (suc i) (suc j) a (x ∷ xs) p = lemma-lookupM-insert-other i j a xs (p ∘ cong suc)
76
77 lemma-lookupM-restrict : {A : Set} {n : ℕ} → (i : Fin n) → (f : Fin n → A) → (is : List (Fin n)) → (a : A) → lookupM i (restrict f is) ≡ just a → f i ≡ a
78 lemma-lookupM-restrict i f []        a p = lemma-just≢nothing p (lemma-lookupM-empty i)
79 lemma-lookupM-restrict i f (i' ∷ is) a p with i ≟ i'
80 lemma-lookupM-restrict i f (.i ∷ is) a p | yes refl = just-injective (begin
81    just (f i)
82      ≡⟨ sym (lemma-lookupM-insert i (f i) (restrict f is)) ⟩
83    lookupM i (insert i (f i) (restrict f is))
84      ≡⟨ p ⟩
85    just a ∎)
86 lemma-lookupM-restrict i f (i' ∷ is) a p | no i≢i' = lemma-lookupM-restrict i f is a (begin
87   lookupM i (restrict f is)
88     ≡⟨ lemma-lookupM-insert-other i i' (f i') (restrict f is) i≢i' ⟩
89   lookupM i (insert i' (f i') (restrict f is))
90     ≡⟨ p ⟩
91   just a ∎)
92
93 lemma-tabulate-∘ : {n : ℕ} {A : Set} → {f g : Fin n → A} → f ≗ g → tabulate f ≡ tabulate g
94 lemma-tabulate-∘ {zero}  {_} {f} {g} f≗g = refl
95 lemma-tabulate-∘ {suc n} {_} {f} {g} f≗g = cong₂ _∷_ (f≗g zero) (lemma-tabulate-∘ (f≗g ∘ suc))
96
97 lemma-fromFunc-tabulate : {n : ℕ} {A : Set} → (f : Fin n → A) → fromFunc f ≡ tabulate (just ∘ f)
98 lemma-fromFunc-tabulate {zero}  f = refl
99 lemma-fromFunc-tabulate {suc _} f = cong (_∷_ (just (f zero))) (lemma-fromFunc-tabulate (f ∘ suc))
100
101 lemma-lookupM-delete : {n : ℕ} {A : Set} {i j : Fin n} → (f : FinMapMaybe n A) → i ≢ j → lookupM i (delete j f) ≡ lookupM i f
102 lemma-lookupM-delete {i = zero}  {j = zero}  (_ ∷ _)  p with p refl
103 ...                                                      | ()
104 lemma-lookupM-delete {i = zero}  {j = suc j} (_ ∷ _)  p = refl
105 lemma-lookupM-delete {i = suc i} {j = zero}  (x ∷ xs) p = refl
106 lemma-lookupM-delete {i = suc i} {j = suc j} (x ∷ xs) p = lemma-lookupM-delete xs (p ∘ cong suc)
107
108 lemma-disjoint-union : {n m : ℕ} {A : Set} → (f : Fin n → A) → (t : Vec (Fin n) m) → union (restrict f (toList t)) (delete-many t (fromFunc f)) ≡ fromFunc f
109 lemma-disjoint-union {n} {m} f t = trans (lemma-tabulate-∘ (lemma-inner t)) (sym (lemma-fromFunc-tabulate f))
110     where lemma-inner : {m : ℕ} → (t : Vec (Fin n) m) → (x : Fin n) → maybe′ just (lookupM x (delete-many t (fromFunc f))) (lookupM x (restrict f (toList t))) ≡ just (f x)
111           lemma-inner [] x = begin
112             maybe′ just (lookupM x (fromFunc f)) (lookupM x empty)
113               ≡⟨ cong (maybe′ just (lookupM x (fromFunc f))) (lemma-lookupM-empty x) ⟩
114             lookupM x (fromFunc f)
115               ≡⟨ cong (lookupM x) (lemma-fromFunc-tabulate f) ⟩
116             lookupM x (tabulate (just ∘ f))
117               ≡⟨ lookup∘tabulate (just ∘ f) x ⟩
118             just (f x) ∎
119           lemma-inner (t ∷ ts) x with x ≟ t
120           lemma-inner (.x ∷ ts) x | yes refl = cong (maybe′ just (lookupM x (delete-many (x ∷ ts) (fromFunc f)))) (lemma-lookupM-insert x (f x) (restrict f (toList ts)))
121           lemma-inner (t ∷ ts) x | no ¬p = begin
122             maybe′ just (lookupM x (delete-many (t ∷ ts) (fromFunc f))) (lookupM x (restrict f (toList (t ∷ ts))))
123               ≡⟨ cong (maybe′ just (lookupM x (delete-many (t ∷ ts) (fromFunc f)))) (sym (lemma-lookupM-insert-other x t (f t) (restrict f (toList ts)) ¬p)) ⟩
124             maybe′ just (lookupM x (delete-many (t ∷ ts) (fromFunc f))) (lookupM x (restrict f (toList ts)))
125               ≡⟨ cong (flip (maybe′ just) (lookupM x (restrict f (toList ts)))) (lemma-lookupM-delete (delete-many ts (fromFunc f)) ¬p) ⟩
126             maybe′ just (lookupM x (delete-many ts (fromFunc f))) (lookupM x (restrict f (toList ts)))
127               ≡⟨ lemma-inner ts x ⟩
128             just (f x) ∎