FinMap.agda

   1 module FinMap where
   2
   3 open import Data.Nat using (ℕ ; zero ; suc)
   4 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′)
   5 open import Data.Fin using (Fin ; zero ; suc)
   6 open import Data.Fin.Props using (_≟_)
   7 open import Data.Vec using (Vec ; [] ; _∷_ ; _[_]≔_ ; replicate ; tabulate) renaming (lookup to lookupVec)
   8 open import Data.Vec.Properties using (lookup∘tabulate)
   9 open import Data.List using (List ; [] ; _∷_ ; map ; zip)
  10 open import Data.Product using (_�_ ; _,_)
  11 open import Function using (id ; _∘_ ; flip)
  12 open import Relation.Nullary using (�_ ; yes ; no)
  13 open import Relation.Nullary.Negation using (contradiction ; contraposition)
  14 open import Relation.Binary.Core using (_≡_ ; refl)
  15 open import Relation.Binary.PropositionalEquality using (cong ; sym ; _≗_ ; trans)
  16 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
  17
  18 FinMapMaybe : ℕ → Set → Set
  19 FinMapMaybe n A = Vec (Maybe A) n
  20
  21 lookupM : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → Maybe A
  22 lookupM = lookupVec
  23
  24 insert : {A : Set} {n : ℕ} → Fin n → A → FinMapMaybe n A → FinMapMaybe n A
  25 insert f a m = m [ f ]≔ (just a)
  26
  27 empty : {A : Set} {n : ℕ} → FinMapMaybe n A
  28 empty = replicate nothing
  29
  30 fromAscList : {A : Set} {n : ℕ} → List (Fin n × A) → FinMapMaybe n A
  31 fromAscList []             = empty
  32 fromAscList ((f , a) ∷ xs) = insert f a (fromAscList xs)
  33
  34 FinMap : ℕ → Set → Set
  35 FinMap n A = Vec A n
  36
  37 lookup : {A : Set} {n : ℕ} → Fin n → FinMap n A → A
  38 lookup = lookupVec
  39
  40 fromFunc : {A : Set} {n : ℕ} → (Fin n → A) → FinMap n A
  41 fromFunc = tabulate
  42
  43 union : {A : Set} {n : ℕ} → FinMapMaybe n A → FinMap n  A → FinMap n A
  44 union m1 m2 = fromFunc (λ f → maybe′ id (lookup f m2) (lookupM f m1))
  45
  46 restrict : {A : Set} {n : ℕ} → (Fin n → A) → List (Fin n) → FinMapMaybe n A
  47 restrict f is = fromAscList (zip is (map f is))
  48
  49 lemma-just≢nothing : {A Whatever : Set} {a : A} → _≡_ {_} {Maybe A} (just a) nothing → Whatever
  50 lemma-just≢nothing ()
  51
  52 lemma-insert-same : {τ : Set} {n : ℕ} → (m : FinMapMaybe n τ) → (f : Fin n) → (a : τ) → lookupM f m ≡ just a → m ≡ insert f a m
  53 lemma-insert-same []               ()      a p
  54 lemma-insert-same (.(just a) ∷ xs) zero    a refl = refl
  55 lemma-insert-same (x ∷ xs)         (suc i) a p    = cong (_∷_ x) (lemma-insert-same xs i a p)
  56
  57 lemma-lookupM-empty : {A : Set} {n : ℕ} → (i : Fin n) → lookupM {A} i empty ≡ nothing
  58 lemma-lookupM-empty zero    = refl
  59 lemma-lookupM-empty (suc i) = lemma-lookupM-empty i
  60
  61 lemma-lookupM-insert : {A : Set} {n : ℕ} → (i : Fin n) → (a : A) → (m : FinMapMaybe n A) → lookupM i (insert i a m) ≡ just a
  62 lemma-lookupM-insert zero    _ (_ ∷ _)  = refl
  63 lemma-lookupM-insert (suc i) a (_ ∷ xs) = lemma-lookupM-insert i a xs
  64
  65 lemma-lookupM-insert-other : {A : Set} {n : ℕ} → (i j : Fin n) → (a : A) → (m : FinMapMaybe n A) → ¬(i ≡ j) → lookupM i m ≡ lookupM i (insert j a m)
  66 lemma-lookupM-insert-other zero    zero    a m        p = contradiction refl p
  67 lemma-lookupM-insert-other zero    (suc j) a (x ∷ xs) p = refl
  68 lemma-lookupM-insert-other (suc i) zero    a (x ∷ xs) p = refl
  69 lemma-lookupM-insert-other (suc i) (suc j) a (x ∷ xs) p = lemma-lookupM-insert-other i j a xs (contraposition (cong suc) p)
  70
  71 lemma-from-just : {A : Set} → {x y : A} → _≡_ {_} {Maybe A} (just x) (just y) → x ≡ y
  72 lemma-from-just refl = refl
  73
  74 lemma-lookupM-restrict : {A : Set} {n : ℕ} → (i : Fin n) → (f : Fin n → A) → (is : List (Fin n)) → (a : A) → lookupM i (restrict f is) ≡ just a → f i ≡ a
  75 lemma-lookupM-restrict i f [] a p = lemma-just≢nothing (trans (sym p) (lemma-lookupM-empty i))
  76 lemma-lookupM-restrict i f (i' ∷ is) a p with i ≟ i'
  77 lemma-lookupM-restrict i f (.i ∷ is) a p | yes refl = lemma-from-just (begin
  78    just (f i)
  79      ≡⟨ sym (lemma-lookupM-insert i (f i) (restrict f is)) ⟩
  80    lookupM i (insert i (f i) (restrict f is))
  81      ≡⟨ refl ⟩
  82    lookupM i (restrict f (i ∷ is))
  83      ≡⟨ p ⟩
  84    just a ∎)
  85 lemma-lookupM-restrict i f (i' ∷ is) a p | no ¬p2 = lemma-lookupM-restrict i f is a (begin
  86   lookupM i (restrict f is)
  87     ≡⟨ lemma-lookupM-insert-other i i' (f i') (restrict f is) ¬p2 ⟩
  88   lookupM i (insert i' (f i') (restrict f is))
  89     ≡⟨ refl ⟩
  90   lookupM i (restrict f (i' ∷ is))
  91     ≡⟨ p ⟩
  92   just a ∎)
  93
  94 lemma-tabulate-∘ : {n : ℕ} {A : Set} → {f g : Fin n → A} → f ≗ g → tabulate f ≡ tabulate g
  95 lemma-tabulate-∘ {zero}  {_} {f} {g} f≗g = refl
  96 lemma-tabulate-∘ {suc n} {_} {f} {g} f≗g = begin
  97   f zero ∷ tabulate (f ∘ suc)
  98     ≡⟨ cong (flip Vec._∷_ (tabulate (f ∘ suc))) (f≗g zero) ⟩
  99   g zero ∷ tabulate (f ∘ suc)
 100     ≡⟨ cong (Vec._∷_ (g zero)) (lemma-tabulate-∘ (f≗g ∘ suc)) ⟩
 101   g zero ∷ tabulate (g ∘ suc) ∎
 102
 103 lemma-union-restrict : {n : ℕ} {A : Set} → (f : Fin n → A) → (is : List (Fin n)) → union (restrict f is) (fromFunc f) ≡ fromFunc f
 104 lemma-union-restrict f is = begin
 105   union (restrict f is) (fromFunc f)
 106     ≡⟨ refl ⟩
 107   tabulate (λ j → maybe′ id (lookup j (fromFunc f)) (lookupM j (restrict f is)))
 108     ≡⟨ lemma-tabulate-∘ (lemma-inner f is) ⟩
 109   tabulate f ∎
 110     where lemma-inner : {n : ℕ} {A : Set} (f : Fin n → A) → (is : List (Fin n)) → (j : Fin n) → maybe′ id (lookup j (fromFunc f)) (lookupM j (restrict f is)) ≡ f j
 111           lemma-inner f []       j = begin
 112             maybe′ id (lookup j (fromFunc f)) (lookupM j empty)
 113               ≡⟨ cong (maybe′ id (lookup j (fromFunc f))) (lemma-lookupM-empty j) ⟩
 114             maybe′ id (lookup j (fromFunc f)) nothing
 115               ≡⟨ refl ⟩
 116             lookup j (fromFunc f)
 117               ≡⟨ lookup∘tabulate f j ⟩
 118             f j ∎
 119           lemma-inner f (i ∷ is)  j with j ≟ i
 120           lemma-inner f (.j ∷ is) j | yes refl = cong (maybe′ id (lookup j (fromFunc f))) (lemma-lookupM-insert j (f j) (restrict f is))
 121           lemma-inner f (i ∷ is)  j | no j≢i = begin
 122             maybe′ id (lookup j (fromFunc f)) (lookupM j (insert i (f i) (restrict f is)))
 123               ≡⟨ cong (maybe′ id (lookup j (fromFunc f))) (sym (lemma-lookupM-insert-other j i (f i) (restrict f is) j≢i)) ⟩
 124             maybe′ id (lookup j (fromFunc f)) (lookupM j (restrict f is))
 125               ≡⟨ lemma-inner f is j ⟩
 126             f j ∎