make more parameters implicit
[~helmut/bidiragda.git] / FinMap.agda
1 module FinMap where
2
3 open import Level using () renaming (zero to ℓ₀)
4 open import Data.Nat using (ℕ ; zero ; suc)
5 open import Data.Maybe using (Maybe ; just ; nothing ; maybe′) renaming (setoid to MaybeEq)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.Vec using (Vec ; [] ; _∷_ ; _[_]≔_ ; replicate ; tabulate ; foldr ; zip) renaming (lookup to lookupVec ; map to mapV)
9 open import Data.Vec.Equality using ()
10 open Data.Vec.Equality.Equality using (_∷-cong_)
11 open import Data.Vec.Properties using (lookup∘tabulate)
12 open import Data.Product using (__ ; _,_)
13 open import Function using (id ; _∘_ ; flip ; const)
14 open import Relation.Nullary using (yes ; no)
15 open import Relation.Nullary.Negation using (contradiction)
16 open import Relation.Binary using (Setoid ; module Setoid)
17 open import Relation.Binary.Core using (_≡_ ; refl ; _≢_)
18 open import Relation.Binary.PropositionalEquality using (cong ; sym ; _≗_ ; trans ; cong₂)
19 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
20
21 open import Generic using (just-injective)
22
23 FinMapMaybe : ℕ → Set → Set
24 FinMapMaybe n A = Vec (Maybe A) n
25
26 lookupM : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → Maybe A
27 lookupM = lookupVec
28
29 insert : {A : Set} {n : ℕ} → Fin n → A → FinMapMaybe n A → FinMapMaybe n A
30 insert f a m = m [ f ]≔ (just a)
31
32 empty : {A : Set} {n : ℕ} → FinMapMaybe n A
33 empty = replicate nothing
34
35 fromAscList : {A : Set} {n m : ℕ} → Vec (Fin n × A) m → FinMapMaybe n A
36 fromAscList []             = empty
37 fromAscList ((f , a) ∷ xs) = insert f a (fromAscList xs)
38
39 fromFunc : {A : Set} {n : ℕ} → (Fin n → A) → FinMapMaybe n A
40 fromFunc = tabulate ∘ _∘_ Maybe.just
41
42 reshape : {n : ℕ} {A : Set} → FinMapMaybe n A → (l : ℕ) → FinMapMaybe l A
43 reshape m        zero    = []
44 reshape []       (suc l) = nothing ∷ (reshape [] l)
45 reshape (x ∷ xs) (suc l) = x ∷ (reshape xs l)
46
47 union : {A : Set} {n : ℕ} → FinMapMaybe n A → FinMapMaybe n A → FinMapMaybe n A
48 union m1 m2 = tabulate (λ f → maybe′ just (lookupM f m2) (lookupM f m1))
49
50 restrict : {A : Set} {n m : ℕ} → (Fin n → A) → Vec (Fin n) m → FinMapMaybe n A
51 restrict f is = fromAscList (zip is (mapV f is))
52
53 delete : {A : Set} {n : ℕ} → Fin n → FinMapMaybe n A → FinMapMaybe n A
54 delete i m = m [ i ]≔ nothing
55
56 delete-many : {A : Set} {n m : ℕ} → Vec (Fin n) m → FinMapMaybe n A → FinMapMaybe n A
57 delete-many = flip (foldr (const _) delete)
58
59 lemma-insert-same : {n : ℕ} {A : Set} → (m : FinMapMaybe n A) → (f : Fin n) → {a : A} → lookupM f m ≡ just a → m ≡ insert f a m
60 lemma-insert-same         []       ()      p
61 lemma-insert-same {suc n} (x ∷ xs) zero    p = cong (flip _∷_ xs) p
62 lemma-insert-same         (x ∷ xs) (suc i) p = cong (_∷_ x) (lemma-insert-same xs i p)
63
64 lemma-lookupM-empty : {A : Set} {n : ℕ} → (i : Fin n) → lookupM {A} i empty ≡ nothing
65 lemma-lookupM-empty zero    = refl
66 lemma-lookupM-empty (suc i) = lemma-lookupM-empty i
67
68 lemma-lookupM-insert : {A : Set} {n : ℕ} → (i : Fin n) → (a : A) → (m : FinMapMaybe n A) → lookupM i (insert i a m) ≡ just a
69 lemma-lookupM-insert zero    a (x ∷ xs) = refl
70 lemma-lookupM-insert (suc i) a (x ∷ xs) = lemma-lookupM-insert i a xs
71
72 lemma-lookupM-insert-other : {A : Set} {n : ℕ} → (i j : Fin n) → (a : A) → (m : FinMapMaybe n A) → i ≢ j → lookupM i (insert j a m) ≡ lookupM i m
73 lemma-lookupM-insert-other zero    zero    a m        p = contradiction refl p
74 lemma-lookupM-insert-other zero    (suc j) a (x ∷ xs) p = refl
75 lemma-lookupM-insert-other (suc i) zero    a (x ∷ xs) p = refl
76 lemma-lookupM-insert-other (suc i) (suc j) a (x ∷ xs) p = lemma-lookupM-insert-other i j a xs (p ∘ cong suc)
77
78 lemma-lookupM-restrict : {A : Set} {n m : ℕ} → (i : Fin n) → (f : Fin n → A) → (is : Vec (Fin n) m) → {a : A} → lookupM i (restrict f is) ≡ just a → f i ≡ a
79 lemma-lookupM-restrict i f []            p = contradiction (trans (sym p) (lemma-lookupM-empty i)) (λ ())
80 lemma-lookupM-restrict i f (i' ∷ is)     p with i ≟ i'
81 lemma-lookupM-restrict i f (.i ∷ is) {a} p | yes refl = just-injective (begin
82    just (f i)
83      ≡⟨ sym (lemma-lookupM-insert i (f i) (restrict f is)) ⟩
84    lookupM i (insert i (f i) (restrict f is))
85      ≡⟨ p ⟩
86    just a ∎)
87 lemma-lookupM-restrict i f (i' ∷ is) {a} p | no i≢i' = lemma-lookupM-restrict i f is (begin
88   lookupM i (restrict f is)
89     ≡⟨ sym (lemma-lookupM-insert-other i i' (f i') (restrict f is) i≢i') ⟩
90   lookupM i (insert i' (f i') (restrict f is))
91     ≡⟨ p ⟩
92   just a ∎)
93
94 lemma-tabulate-∘ : {n : ℕ} {A : Set} → {f g : Fin n → A} → f ≗ g → tabulate f ≡ tabulate g
95 lemma-tabulate-∘ {zero}  {_} {f} {g} f≗g = refl
96 lemma-tabulate-∘ {suc n} {_} {f} {g} f≗g = cong₂ _∷_ (f≗g zero) (lemma-tabulate-∘ (f≗g ∘ suc))
97
98 lemma-lookupM-fromFunc : {n : ℕ} {A : Set} → (f : Fin n → A) → flip lookupM (fromFunc f) ≗ Maybe.just ∘ f
99 lemma-lookupM-fromFunc f zero = refl
100 lemma-lookupM-fromFunc f (suc i) = lemma-lookupM-fromFunc (f ∘ suc) i
101
102 lemma-lookupM-delete : {n : ℕ} {A : Set} {i j : Fin n} → (f : FinMapMaybe n A) → i ≢ j → lookupM i (delete j f) ≡ lookupM i f
103 lemma-lookupM-delete {i = zero}  {j = zero}  (_ ∷ _)  p = contradiction refl p
104 lemma-lookupM-delete {i = zero}  {j = suc j} (_ ∷ _)  p = refl
105 lemma-lookupM-delete {i = suc i} {j = zero}  (x ∷ xs) p = refl
106 lemma-lookupM-delete {i = suc i} {j = suc j} (x ∷ xs) p = lemma-lookupM-delete xs (p ∘ cong suc)
107
108 lemma-reshape-id : {n : ℕ} {A : Set} → (m : FinMapMaybe n A) → reshape m n ≡ m
109 lemma-reshape-id []       = refl
110 lemma-reshape-id (x ∷ xs) = cong (_∷_ x) (lemma-reshape-id xs)
111
112 lemma-disjoint-union : {n m : ℕ} {A : Set} → (f : Fin n → A) → (t : Vec (Fin n) m) → union (restrict f t) (delete-many t (fromFunc f)) ≡ fromFunc f
113 lemma-disjoint-union {n} {m} f t = lemma-tabulate-∘ (lemma-inner t)
114     where lemma-inner : {m : ℕ} → (t : Vec (Fin n) m) → (x : Fin n) → maybe′ just (lookupM x (delete-many t (fromFunc f))) (lookupM x (restrict f t)) ≡ just (f x)
115           lemma-inner [] x = begin
116             maybe′ just (lookupM x (fromFunc f)) (lookupM x empty)
117               ≡⟨ cong (maybe′ just (lookupM x (fromFunc f))) (lemma-lookupM-empty x) ⟩
118             lookupM x (fromFunc f)
119               ≡⟨ lemma-lookupM-fromFunc f x ⟩
120             just (f x) ∎
121           lemma-inner (t ∷ ts) x with x ≟ t
122           lemma-inner (.x ∷ ts) x | yes refl = cong (maybe′ just (lookupM x (delete-many (x ∷ ts) (fromFunc f)))) (lemma-lookupM-insert x (f x) (restrict f ts))
123           lemma-inner (t ∷ ts) x | no ¬p = begin
124             maybe′ just (lookupM x (delete-many (t ∷ ts) (fromFunc f))) (lookupM x (restrict f (t ∷ ts)))
125               ≡⟨ cong (maybe′ just (lookupM x (delete-many (t ∷ ts) (fromFunc f)))) (lemma-lookupM-insert-other x t (f t) (restrict f ts) ¬p) ⟩
126             maybe′ just (lookupM x (delete-many (t ∷ ts) (fromFunc f))) (lookupM x (restrict f ts))
127               ≡⟨ cong (flip (maybe′ just) (lookupM x (restrict f ts))) (lemma-lookupM-delete (delete-many ts (fromFunc f)) ¬p) ⟩
128             maybe′ just (lookupM x (delete-many ts (fromFunc f))) (lookupM x (restrict f ts))
129               ≡⟨ lemma-inner ts x ⟩
130             just (f x) ∎