improve readability using _∋_≈_ instead of Setoid._≈_
[~helmut/bidiragda.git] / Generic.agda
1 module Generic where
2
3 import Category.Functor
4 import Category.Monad
5 open import Data.List using (List ; length ; replicate) renaming ([] to []L ; _∷_ to _∷L_)
6 open import Data.Maybe using (Maybe ; just ; nothing) renaming (setoid to MaybeEq)
7 open import Data.Nat using (ℕ ; zero ; suc)
8 open import Data.Product using (__ ; _,_)
9 open import Data.Vec using (Vec ; toList ; fromList ; map) renaming ([] to []V ; _∷_ to _∷V_)
10 open import Data.Vec.Equality using () renaming (module Equality to VecEq)
11 open import Function using (_∘_ ; id)
12 open import Level using () renaming (zero to ℓ₀)
13 open import Relation.Binary using (Setoid ; module Setoid)
14 open import Relation.Binary.Core using (_≡_ ; refl)
15 open import Relation.Binary.Indexed using (_at_) renaming (Setoid to ISetoid)
16 open import Relation.Binary.PropositionalEquality using (_≗_ ; cong ; subst ; trans) renaming (setoid to PropEq)
17
18 open Setoid using () renaming (_≈_ to _∋_≈_)
19 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
20 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
21
22 just-injective : {A : Set} → {x y : A} → Maybe.just x ≡ Maybe.just y → x ≡ y
23 just-injective refl = refl
24
25 length-replicate : {A : Set} {a : A} → (n : ℕ) → length (replicate n a) ≡ n
26 length-replicate zero    = refl
27 length-replicate (suc n) = cong suc (length-replicate n)
28
29 mapMV : {A B : Set} {n : ℕ} → (A → Maybe B) → Vec A n → Maybe (Vec B n)
30 mapMV f []V = just []V
31 mapMV f (x ∷V xs) = (f x) >>= (λ y → (_∷V_ y) <$> (mapMV f xs))
32
33 mapMV-cong : {A B : Set} {f g : A → Maybe B} → f ≗ g → {n : ℕ} → mapMV {n = n} f ≗ mapMV g
34 mapMV-cong f≗g []V = refl
35 mapMV-cong {f = f} {g = g} f≗g (x ∷V xs) with f x | g x | f≗g x
36 mapMV-cong f≗g (x ∷V xs) | just y | .(just y) | refl = cong (_<$>_ (_∷V_ y)) (mapMV-cong f≗g xs)
37 mapMV-cong f≗g (x ∷V xs) | nothing | .nothing | refl = refl
38
39 mapMV-purity : {A B : Set} {n : ℕ} → (f : A → B) → (v : Vec A n) → mapMV (just ∘ f) v ≡ just (map f v)
40 mapMV-purity f []V = refl
41 mapMV-purity f (x ∷V xs) rewrite mapMV-purity f xs = refl
42
43 maybeEq-from-≡ : {A : Set} {a b : Maybe A} → a ≡ b → MaybeEq (PropEq A) ∋ a ≈ b
44 maybeEq-from-≡ {a = just x}  {b = .(just x)} refl = just refl
45 maybeEq-from-≡ {a = nothing} {b = .nothing}  refl = nothing
46
47 maybeEq-to-≡ : {A : Set} {a b : Maybe A} → MaybeEq (PropEq A) ∋ a ≈ b → a ≡ b
48 maybeEq-to-≡ (just refl) = refl
49 maybeEq-to-≡ nothing     = refl
50
51 sequenceV : {A : Set} {n : ℕ} → Vec (Maybe A) n → Maybe (Vec A n)
52 sequenceV = mapMV id
53
54 sequence-map : {A B : Set} {n : ℕ} → (f : A → Maybe B) → sequenceV {n = n} ∘ map f ≗ mapMV f
55 sequence-map f []V = refl
56 sequence-map f (x ∷V xs) with f x
57 sequence-map f (x ∷V xs) | just y = cong (_<$>_ (_∷V_ y)) (sequence-map f xs)
58 sequence-map f (x ∷V xs) | nothing = refl
59
60 subst-cong : {A : Set} → (T : A → Set) → {g : A → A} → {a b : A} → (f : {c : A} → T c → T (g c)) → (p : a ≡ b) →
61              f ∘ subst T p ≗ subst T (cong g p) ∘ f
62 subst-cong T f refl _ = refl
63
64 subst-fromList : {A : Set} {x y : List A} → (p : y ≡ x) →
65                  subst (Vec A) (cong length p) (fromList y) ≡ fromList x
66 subst-fromList refl = refl
67
68 subst-subst : {A : Set} (T : A → Set) {a b c : A} → (p : a ≡ b) → (p′ : b ≡ c) → (x : T a) →
69               subst T p′ (subst T p x) ≡ subst T (trans p p′) x
70 subst-subst T refl p′ x = refl
71
72 toList-fromList : {A : Set} → (l : List A) → toList (fromList l) ≡ l
73 toList-fromList []L       = refl
74 toList-fromList (x ∷L xs) = cong (_∷L_ x) (toList-fromList xs)
75
76 toList-subst : {A : Set} → {n m : ℕ} (v : Vec A n) → (p : n ≡ m) →
77                toList (subst (Vec A) p v) ≡ toList v
78 toList-subst v refl = refl
79
80 VecISetoid : Setoid ℓ₀ ℓ₀ → ISetoid ℕ ℓ₀ ℓ₀
81 VecISetoid S = record
82   { Carrier = Vec (Setoid.Carrier S)
83   ; _≈_ = λ x → S VecEq.≈ x
84   ; isEquivalence = record
85     { refl = VecEq.refl S _
86     ; sym = VecEq.sym S
87     ; trans = VecEq.trans S }
88   }