reorganize equality imports
[~helmut/bidiragda.git] / LiftGet.agda
1 module LiftGet where
2
3 open import Data.Unit using (⊤ ; tt)
4 open import Data.Nat using (ℕ ; suc)
5 open import Data.Vec using (Vec ; toList ; fromList) renaming ([] to []V ; _∷_ to _∷V_ ; map to mapV)
6 open import Data.List using (List ; [] ; _∷_ ; length ; replicate ; map)
7 open import Data.List.Properties using (length-map ; length-replicate)
8 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
9 open import Function using (_∘_ ; flip ; const)
10 open import Relation.Binary.PropositionalEquality as P using (_≡_ ; _≗_ ; proof-irrelevance ; module ≡-Reasoning)
11 open import Relation.Binary.HeterogeneousEquality as H using (module ≅-Reasoning ; _≅_ ; ≅-to-≡ ; ≡-to-≅ ; ≡-subst-removable)
12
13 import FreeTheorems
14 open import Generic using (toList-fromList ; toList-subst)
15 open FreeTheorems.ListList using (get-type) renaming (free-theorem to free-theoremL ; Get to GetL ; module Get to GetL)
16 open FreeTheorems.VecVec using () renaming (get-type to getV-type ; Get to GetV ; module Get to GetV)
17
18 getVec-to-getList : {getlen : ℕ → ℕ} → (getV-type getlen) → get-type
19 getVec-to-getList get = toList ∘ get ∘ fromList
20
21 fromList∘map : {α β : Set} → (f : α → β) → (l : List α) → fromList (map f l) ≅ mapV f (fromList l)
22 fromList∘map f []       = H.refl
23 fromList∘map f (x ∷ xs) = H.cong₂ (λ n → _∷V_ {n = n} (f x)) (H.reflexive (length-map f xs)) (fromList∘map f xs)
24
25 toList∘map : {α β : Set} {n : ℕ} → (f : α → β) → (v : Vec α n) → toList (mapV f v) ≡ map f (toList v)
26 toList∘map f []V       = P.refl
27 toList∘map f (x ∷V xs) = P.cong (_∷_ (f x)) (toList∘map f xs)
28
29 GetV-to-GetL : GetV → GetL
30 GetV-to-GetL getrecord = record { get = toList ∘ get ∘ fromList; free-theorem = ft }
31   where open GetV getrecord
32         open ≡-Reasoning
33         ft : {α β : Set} → (f : α → β) → (xs : List α) → toList (get (fromList (map f xs))) ≡ map f (toList (get (fromList xs)))
34         ft f xs = begin
35           toList (get (fromList (map f xs)))
36             ≅⟨ H.cong₂ {B = Vec _} (λ n → toList ∘ get) (H.reflexive (length-map f xs)) (fromList∘map f xs) ⟩
37           toList (get (mapV f (fromList xs)))
38             ≡⟨ P.cong toList (free-theorem f (fromList xs)) ⟩
39           toList (mapV f (get (fromList xs)))
40             ≡⟨ toList∘map f (get (fromList xs)) ⟩
41           map f (toList (get (fromList xs))) ∎
42
43 getList-to-getlen : get-type → ℕ → ℕ
44 getList-to-getlen get = length ∘ get ∘ flip replicate tt
45
46 replicate-length : {A : Set} → (l : List A) → map (const tt) l ≡ replicate (length l) tt
47 replicate-length []      = P.refl
48 replicate-length (_ ∷ l) = P.cong (_∷_ tt) (replicate-length l)
49
50 getList-length : (get : get-type) → {B : Set} → (l : List B) → length (get l) ≡ getList-to-getlen get (length l)
51 getList-length get l = begin
52   length (get l)
53     ≡⟨ P.sym (length-map (const tt) (get l)) ⟩
54   length (map (const tt) (get l))
55     ≡⟨ P.cong length (P.sym (free-theoremL get (const tt) l)) ⟩
56   length (get (map (const tt) l))
57     ≡⟨ P.cong (length ∘ get) (replicate-length l) ⟩
58   length (get (replicate (length l) tt)) ∎
59   where open ≡-Reasoning
60
61 length-toList : {A : Set} {n : ℕ} → (v : Vec A n) → length (toList v) ≡ n
62 length-toList []V       = P.refl
63 length-toList (x ∷V xs) = P.cong suc (length-toList xs) 
64
65 getList-to-getVec-length-property : (get : get-type) → {C : Set} → {m : ℕ} → (v : Vec C m) → length (get (toList v)) ≡ length (get (replicate m tt))
66 getList-to-getVec-length-property get {_} {m} v = begin
67     length (get (toList v))
68       ≡⟨ getList-length get (toList v) ⟩
69     length (get (replicate (length (toList v)) tt))
70       ≡⟨ P.cong (length ∘ get ∘ flip replicate tt) (length-toList v) ⟩
71     length (get (replicate m tt)) ∎
72     where open ≡-Reasoning
73
74 getList-to-getVec : get-type → ∃ λ (getlen : ℕ → ℕ) → (getV-type getlen)
75 getList-to-getVec get = getlen , get'
76   where getlen : ℕ → ℕ
77         getlen = getList-to-getlen get
78         get' : {C : Set} {m : ℕ} → Vec C m → Vec C (getlen m)
79         get' {C} v = P.subst (Vec C) (getList-to-getVec-length-property get v) (fromList (get (toList v)))
80
81 private
82   module GetV-Implementation (getrecord : GetL) where
83
84     open GetL getrecord
85
86     getlen = length ∘ get ∘ flip replicate tt
87
88
89     length-property : {C : Set} {m : ℕ} → (s : Vec C m) → length (get (toList s)) ≡ getlen m
90     length-property = getList-to-getVec-length-property get
91
92     getV : {C : Set} {m : ℕ} → Vec C m → Vec C (getlen m)
93     getV s = P.subst (Vec _) (length-property s) (fromList (get (toList s)))
94
95     ft : {α β : Set} (f : α → β) {n : ℕ} (v : Vec α n) → getV (mapV f v) ≡ mapV f (getV v)
96     ft f v = ≅-to-≡ (begin
97       P.subst (Vec _) (length-property (mapV f v)) (fromList (get (toList (mapV f v))))
98         ≅⟨ ≡-subst-removable (Vec _) (length-property (mapV f v)) (fromList (get (toList (mapV f v)))) ⟩
99       fromList (get (toList (mapV f v)))
100         ≅⟨ H.cong (fromList ∘ get) (H.reflexive (toList∘map f v)) ⟩
101       fromList (get (map f (toList v)))
102         ≅⟨ H.cong fromList (H.reflexive (free-theorem f (toList v))) ⟩
103       fromList (map f (get (toList v)))
104         ≅⟨ fromList∘map f (get (toList v)) ⟩
105       mapV f (fromList (get (toList v)))
106         ≅⟨ H.cong₂ (λ n → mapV {n = n} f) (H.reflexive (length-property v)) (H.sym (≡-subst-removable (Vec _) (length-property v) (fromList (get (toList v))))) ⟩
107       mapV f (P.subst (Vec _) (length-property v) (fromList (get (toList v)))) ∎)
108       where open ≅-Reasoning
109
110 GetL-to-GetV : GetL → GetV
111 GetL-to-GetV getrecord = record { getlen = getlen; get = getV; free-theorem = ft }
112   where open GetV-Implementation getrecord
113
114 get-commut-1-≅ : (get : get-type) {A : Set} → (l : List A) → fromList (get l) ≅ proj₂ (getList-to-getVec get) (fromList l)
115 get-commut-1-≅ get l = begin
116   fromList (get l)
117     ≅⟨ H.cong (fromList ∘ get) (≡-to-≅ (P.sym (toList-fromList l))) ⟩
118   fromList (get (toList (fromList l)))
119     ≅⟨ H.sym (≡-subst-removable (Vec _) (getList-to-getVec-length-property get (fromList l)) (fromList (get (toList (fromList l))))) ⟩
120   P.subst (Vec _) (getList-to-getVec-length-property get (fromList l)) (fromList (get (toList (fromList l)))) ∎
121   where open ≅-Reasoning
122
123 get-commut-1 : (get : get-type) {A : Set} → (l : List A) → fromList (get l) ≡ P.subst (Vec A) (P.sym (getList-length get l)) (proj₂ (getList-to-getVec get) (fromList l))
124 get-commut-1 get {A} l = ≅-to-≡ (begin
125   fromList (get l)
126     ≅⟨ get-commut-1-≅ get l ⟩
127   proj₂ (getList-to-getVec get) (fromList l)
128     ≅⟨ H.sym (≡-subst-removable (Vec _) (P.sym (getList-length get l)) (proj₂ (getList-to-getVec get) (fromList l))) ⟩
129   P.subst (Vec _) (P.sym (getList-length get l)) (proj₂ (getList-to-getVec get) (fromList l)) ∎)
130   where open ≅-Reasoning
131
132 get-trafo-1 : (get : get-type) → {B : Set} → getVec-to-getList (proj₂ (getList-to-getVec get)) {B} ≗ get {B}
133 get-trafo-1 get {B} l = begin
134   getVec-to-getList (proj₂ (getList-to-getVec get)) l
135     ≡⟨ P.refl ⟩
136   toList (proj₂ (getList-to-getVec get) (fromList l))
137     ≡⟨ P.refl ⟩
138   toList (P.subst (Vec B) (getList-to-getVec-length-property get (fromList l)) (fromList (get (toList (fromList l)))))
139     ≡⟨ toList-subst (fromList (get (toList (fromList l)))) (getList-to-getVec-length-property get (fromList l)) ⟩
140   toList (fromList (get (toList (fromList l))))
141     ≡⟨ toList-fromList (get (toList (fromList l))) ⟩
142   get (toList (fromList l))
143     ≡⟨ P.cong get (toList-fromList l) ⟩
144   get l ∎
145   where open ≡-Reasoning
146
147 GetLVL-identity : (G : GetL) → {A : Set} → GetL.get (GetV-to-GetL (GetL-to-GetV G)) ≗ GetL.get G {A}
148 GetLVL-identity G = get-trafo-1 (GetL.get G)
149
150 vec-len : {A : Set} {n : ℕ} → Vec A n → ℕ
151 vec-len {_} {n} _ = n
152
153 fromList-toList : {A : Set} {n : ℕ} → (v : Vec A n) → fromList (toList v) ≅ v
154 fromList-toList []V       = H.refl
155 fromList-toList (x ∷V xs) = H.cong₂ (λ n → _∷V_ {n = n} x) (H.reflexive (length-toList xs)) (fromList-toList xs)
156
157 get-commut-2 : {getlen : ℕ → ℕ} → (get : getV-type getlen) → {B : Set} {n : ℕ} → (toList ∘ get {B} {n}) ≗ (getVec-to-getList get) ∘ toList
158 get-commut-2 get {B} v = P.sym (≅-to-≡ (H.cong₂ (λ n → toList ∘ get {n = n}) (H.reflexive (length-toList v)) (fromList-toList v)))
159
160 get-trafo-2-getlen : {getlen : ℕ → ℕ} → (get : getV-type getlen) → proj₁ (getList-to-getVec (getVec-to-getList get)) ≗ getlen
161 get-trafo-2-getlen {getlen} get n = begin
162   proj₁ (getList-to-getVec (getVec-to-getList get)) n
163     ≡⟨ P.refl ⟩
164   length (toList (get (fromList (replicate n tt))))
165     ≡⟨ length-toList (get (fromList (replicate n tt))) ⟩
166   vec-len (get (fromList (replicate n tt)))
167     ≡⟨ P.cong getlen (length-replicate n) ⟩
168   getlen n ∎
169   where open ≡-Reasoning
170
171 get-trafo-2-get-≅ : {getlen : ℕ → ℕ} → (get : getV-type getlen) → {B : Set} {n : ℕ} → (v : Vec B n) → proj₂ (getList-to-getVec (getVec-to-getList get)) v ≅ get v
172 get-trafo-2-get-≅ {getlen} get v = begin
173   P.subst (Vec _) (getList-to-getVec-length-property (getVec-to-getList get) v) (fromList (toList (get (fromList (toList v)))))
174     ≅⟨ ≡-subst-removable (Vec _) (getList-to-getVec-length-property (getVec-to-getList get) v) (fromList (toList (get (fromList (toList v))))) ⟩
175   fromList (toList (get (fromList (toList v))))
176     ≅⟨ fromList-toList (get (fromList (toList v))) ⟩
177   get (fromList (toList v))
178     ≅⟨ H.cong₂ (λ n → get {n = n}) (H.reflexive (length-toList v)) (fromList-toList v) ⟩
179   get v ∎
180   where open ≅-Reasoning
181
182 get-trafo-2-get : {getlen : ℕ → ℕ} → (get : getV-type getlen) → {B : Set} {n : ℕ} → proj₂ (getList-to-getVec (getVec-to-getList get)) ≗ P.subst (Vec B) (P.sym (get-trafo-2-getlen get n)) ∘ get
183 get-trafo-2-get get v = ≅-to-≡ (begin
184   proj₂ (getList-to-getVec (getVec-to-getList get)) v
185     ≅⟨ get-trafo-2-get-≅ get v ⟩
186   get v
187     ≅⟨ H.sym (≡-subst-removable (Vec _) (P.sym (get-trafo-2-getlen get (vec-len v))) (get v)) ⟩
188   P.subst (Vec _) (P.sym (get-trafo-2-getlen get (vec-len v))) (get v) ∎)
189   where open ≅-Reasoning