prove LiftGet.get-trafo-2-getlen
[~helmut/bidiragda.git] / LiftGet.agda
1 module LiftGet where
2
3 open import Data.Unit using (⊤ ; tt)
4 open import Data.Nat using (ℕ ; suc)
5 open import Data.Vec using (Vec ; toList ; fromList) renaming ([] to []V ; _∷_ to _∷V_)
6 open import Data.List using (List ; [] ; _∷_ ; length ; replicate ; map)
7 open import Data.List.Properties using (length-map)
8 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
9 open import Function using (_∘_ ; flip ; const)
10 open import Relation.Binary.Core using (_≡_)
11 open import Relation.Binary.PropositionalEquality using (_≗_ ; sym ; cong ; refl)
12 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
13
14 get-type : Set₁
15 get-type = {A : Set} → List A → List A
16
17 getV-type : (ℕ → ℕ) → Set₁
18 getV-type getlen = {A : Set} {n : ℕ} → Vec A n → Vec A (getlen n)
19
20 getVec-to-getList : {getlen : ℕ → ℕ} → (getV-type getlen) → get-type
21 getVec-to-getList get = toList ∘ get ∘ fromList
22
23 getList-to-getlen : get-type → ℕ → ℕ
24 getList-to-getlen get = length ∘ get ∘ flip replicate tt
25
26 postulate
27   free-theorem-list-list : {β γ : Set} → (get : get-type) → (f : β → γ) → get ∘ map f ≗ map f ∘ get
28
29 replicate-length : {A : Set} → (l : List A) → map (const tt) l ≡ replicate (length l) tt
30 replicate-length [] = refl
31 replicate-length (_ ∷ l) = cong (_∷_ tt) (replicate-length l)
32
33 getList-length : (get : get-type) → {B : Set} → (l : List B) → length (get l) ≡ getList-to-getlen get (length l)
34 getList-length get l = begin
35   length (get l)
36     ≡⟨ sym (length-map (const tt) (get l)) ⟩
37   length (map (const tt) (get l))
38     ≡⟨ cong length (sym (free-theorem-list-list get (const tt) l)) ⟩
39   length (get (map (const tt) l))
40     ≡⟨ cong (length ∘ get) (replicate-length l) ⟩
41   length (get (replicate (length l) tt)) ∎
42
43 length-toList : {A : Set} {n : ℕ} → (v : Vec A n) → length (toList v) ≡ n
44 length-toList []V = refl
45 length-toList (x ∷V xs) = cong suc (length-toList xs) 
46
47 vec-length : {A : Set} {n m : ℕ} → n ≡ m → Vec A n → Vec A m
48 vec-length refl v = v
49
50 toList-fromList : {A : Set} → (l : List A) → toList (fromList l) ≡ l
51 toList-fromList []       = refl
52 toList-fromList (x ∷ xs) = cong (_∷_ x) (toList-fromList xs)
53
54 vec-length-same : {A : Set} → (l : List A) → {n : ℕ} → (p : length l ≡ n) → toList (vec-length p (fromList l)) ≡ l
55 vec-length-same l refl = toList-fromList l
56
57 getList-to-getVec-length-property : (get : get-type) → {C : Set} → {m : ℕ} → (v : Vec C m) → length (get (toList v)) ≡ length (get (replicate m tt))
58 getList-to-getVec-length-property get {_} {m} v = begin
59     length (get (toList v))
60       ≡⟨ getList-length get (toList v) ⟩
61     length (get (replicate (length (toList v)) tt))
62       ≡⟨ cong (length ∘ get ∘ flip replicate tt) (length-toList v) ⟩
63     length (get (replicate m tt)) ∎
64
65 getList-to-getVec : get-type → ∃ λ (getlen : ℕ → ℕ) → (getV-type getlen)
66 getList-to-getVec get = getlen , get'
67   where getlen : ℕ → ℕ
68         getlen = getList-to-getlen get
69         get' : {C : Set} {m : ℕ} → Vec C m → Vec C (getlen m)
70         get' v = vec-length (getList-to-getVec-length-property get v) (fromList (get (toList v)))
71
72 get-trafo-1 : (get : get-type) → {B : Set} → getVec-to-getList (proj₂ (getList-to-getVec get)) {B} ≗ get {B}
73 get-trafo-1 get l = begin
74   getVec-to-getList (proj₂ (getList-to-getVec get)) l
75     ≡⟨ refl ⟩
76   toList (proj₂ (getList-to-getVec get) (fromList l))
77     ≡⟨ refl ⟩
78   toList (vec-length (getList-to-getVec-length-property get (fromList l)) (fromList (get (toList (fromList l)))))
79     ≡⟨ vec-length-same (get (toList (fromList l))) (getList-to-getVec-length-property get (fromList l)) ⟩
80   get (toList (fromList l))
81     ≡⟨ cong get (toList-fromList l) ⟩
82   get l ∎
83
84 vec-len : {A : Set} {n : ℕ} → Vec A n → ℕ
85 vec-len {_} {n} _ = n
86
87 vec-len-via-list : {A : Set} {n : ℕ} → (v : Vec A n) → length (toList v) ≡ vec-len v
88 vec-len-via-list []V       = refl
89 vec-len-via-list (x ∷V xs) = cong suc (vec-len-via-list xs)
90
91 length-replicate : {A : Set} {a : A} → (n : ℕ) → length (replicate n a) ≡ n
92 length-replicate 0       = refl
93 length-replicate (suc n) = cong suc (length-replicate n)
94
95 get-trafo-2-getlen : (getlen : ℕ → ℕ) → (get : getV-type getlen) → proj₁ (getList-to-getVec (getVec-to-getList get)) ≗ getlen
96 get-trafo-2-getlen getlen get n = begin
97   proj₁ (getList-to-getVec (getVec-to-getList get)) n
98     ≡⟨ refl ⟩
99   length (toList (get (fromList (replicate n tt))))
100     ≡⟨ vec-len-via-list (get (fromList (replicate n tt))) ⟩
101   vec-len (get (fromList (replicate n tt)))
102     ≡⟨ cong getlen (length-replicate n) ⟩
103   getlen n ∎
104
105 getVec-getlen : {getlen₁ getlen₂ : ℕ → ℕ} → (get : getV-type getlen₁) → getlen₁ ≗ getlen₂ → getV-type getlen₂
106 getVec-getlen get p {B} {n} v = vec-length (p n) (get v)
107
108 get-trafo-2-get : (getlen : ℕ → ℕ) → (get : getV-type getlen) → {B : Set} {n : ℕ} → proj₂ (getList-to-getVec (getVec-to-getList get)) {B} {n} ≗ getVec-getlen get (sym ∘ (get-trafo-2-getlen getlen get))
109 get-trafo-2-get getlen get v = {!!}