show fromList-toList in the subst form
[~helmut/bidiragda.git] / LiftGet.agda
1 module LiftGet where
2
3 open import Data.Unit using (⊤ ; tt)
4 open import Data.Nat using (ℕ ; suc)
5 open import Data.Vec using (Vec ; toList ; fromList) renaming ([] to []V ; _∷_ to _∷V_)
6 open import Data.List using (List ; [] ; _∷_ ; length ; replicate ; map)
7 open import Data.List.Properties using (length-map)
8 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
9 open import Function using (_∘_ ; flip ; const)
10 open import Relation.Binary.Core using (_≡_)
11 open import Relation.Binary.PropositionalEquality using (_≗_ ; sym ; cong ; refl ; subst ; proof-irrelevance)
12 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
13
14 get-type : Set₁
15 get-type = {A : Set} → List A → List A
16
17 getV-type : (ℕ → ℕ) → Set₁
18 getV-type getlen = {A : Set} {n : ℕ} → Vec A n → Vec A (getlen n)
19
20 getVec-to-getList : {getlen : ℕ → ℕ} → (getV-type getlen) → get-type
21 getVec-to-getList get = toList ∘ get ∘ fromList
22
23 getList-to-getlen : get-type → ℕ → ℕ
24 getList-to-getlen get = length ∘ get ∘ flip replicate tt
25
26 postulate
27   free-theorem-list-list : {β γ : Set} → (get : get-type) → (f : β → γ) → get ∘ map f ≗ map f ∘ get
28
29 replicate-length : {A : Set} → (l : List A) → map (const tt) l ≡ replicate (length l) tt
30 replicate-length [] = refl
31 replicate-length (_ ∷ l) = cong (_∷_ tt) (replicate-length l)
32
33 getList-length : (get : get-type) → {B : Set} → (l : List B) → length (get l) ≡ getList-to-getlen get (length l)
34 getList-length get l = begin
35   length (get l)
36     ≡⟨ sym (length-map (const tt) (get l)) ⟩
37   length (map (const tt) (get l))
38     ≡⟨ cong length (sym (free-theorem-list-list get (const tt) l)) ⟩
39   length (get (map (const tt) l))
40     ≡⟨ cong (length ∘ get) (replicate-length l) ⟩
41   length (get (replicate (length l) tt)) ∎
42
43 length-toList : {A : Set} {n : ℕ} → (v : Vec A n) → length (toList v) ≡ n
44 length-toList []V = refl
45 length-toList (x ∷V xs) = cong suc (length-toList xs) 
46
47 toList-fromList : {A : Set} → (l : List A) → toList (fromList l) ≡ l
48 toList-fromList []       = refl
49 toList-fromList (x ∷ xs) = cong (_∷_ x) (toList-fromList xs)
50
51 toList-subst : {A : Set} → {n m : ℕ} (v : Vec A n) → (p : n ≡ m) → toList (subst (Vec A) p v) ≡ toList v
52 toList-subst v refl = refl
53
54 getList-to-getVec-length-property : (get : get-type) → {C : Set} → {m : ℕ} → (v : Vec C m) → length (get (toList v)) ≡ length (get (replicate m tt))
55 getList-to-getVec-length-property get {_} {m} v = begin
56     length (get (toList v))
57       ≡⟨ getList-length get (toList v) ⟩
58     length (get (replicate (length (toList v)) tt))
59       ≡⟨ cong (length ∘ get ∘ flip replicate tt) (length-toList v) ⟩
60     length (get (replicate m tt)) ∎
61
62 getList-to-getVec : get-type → ∃ λ (getlen : ℕ → ℕ) → (getV-type getlen)
63 getList-to-getVec get = getlen , get'
64   where getlen : ℕ → ℕ
65         getlen = getList-to-getlen get
66         get' : {C : Set} {m : ℕ} → Vec C m → Vec C (getlen m)
67         get' {C} v = subst (Vec C) (getList-to-getVec-length-property get v) (fromList (get (toList v)))
68
69 {-
70 -- We cannot formulate the first commutation property, because the type of
71 -- fromList (get l) depends on the concrete l, more specifically its length.
72 get-commut-1 : (get : get-type) → (fromList ∘ get) ≗ (proj₂ (getList-to-getVec get)) ∘ fromList
73 get-commut-1 get l = ?
74 -}
75
76 get-trafo-1 : (get : get-type) → {B : Set} → getVec-to-getList (proj₂ (getList-to-getVec get)) {B} ≗ get {B}
77 get-trafo-1 get {B} l = begin
78   getVec-to-getList (proj₂ (getList-to-getVec get)) l
79     ≡⟨ refl ⟩
80   toList (proj₂ (getList-to-getVec get) (fromList l))
81     ≡⟨ refl ⟩
82   toList (subst (Vec B) (getList-to-getVec-length-property get (fromList l)) (fromList (get (toList (fromList l)))))
83     ≡⟨ toList-subst (fromList (get (toList (fromList l)))) (getList-to-getVec-length-property get (fromList l)) ⟩
84   toList (fromList (get (toList (fromList l))))
85     ≡⟨ toList-fromList (get (toList (fromList l))) ⟩
86   get (toList (fromList l))
87     ≡⟨ cong get (toList-fromList l) ⟩
88   get l ∎
89
90 vec-len : {A : Set} {n : ℕ} → Vec A n → ℕ
91 vec-len {_} {n} _ = n
92
93 vec-len-via-list : {A : Set} {n : ℕ} → (v : Vec A n) → length (toList v) ≡ vec-len v
94 vec-len-via-list []V       = refl
95 vec-len-via-list (x ∷V xs) = cong suc (vec-len-via-list xs)
96
97 length-replicate : {A : Set} {a : A} → (n : ℕ) → length (replicate n a) ≡ n
98 length-replicate 0       = refl
99 length-replicate (suc n) = cong suc (length-replicate n)
100
101 ∷-subst : {A : Set} {n m : ℕ} → (x : A) → (xs : Vec A n) → (p : n ≡ m) → x ∷V subst (Vec A) p xs ≡ subst (Vec A) (cong suc p) (x ∷V xs)
102 ∷-subst x xs refl = refl
103
104 fromList-toList : {A : Set} {n : ℕ} → (v : Vec A n) → fromList (toList v) ≡ subst (Vec A) (sym (length-toList v)) v
105 fromList-toList     []V       = refl
106 fromList-toList {A} (x ∷V xs) = begin
107   x ∷V fromList (toList xs)
108     ≡⟨ cong (_∷V_ x) (fromList-toList xs) ⟩
109   x ∷V subst (Vec A) (sym (length-toList xs)) xs
110     ≡⟨ ∷-subst x xs (sym (length-toList xs)) ⟩
111   subst (Vec A) (cong suc (sym (length-toList xs))) (x ∷V xs)
112     ≡⟨ cong (λ p →  subst (Vec A) p (x ∷V xs)) (proof-irrelevance (cong suc (sym (length-toList xs))) (sym (cong suc (length-toList xs)))) ⟩
113   subst (Vec A) (sym (length-toList (x ∷V xs))) (x ∷V xs) ∎
114
115 get-commut-2 : (getlen : ℕ → ℕ) → (get : getV-type getlen) → {B : Set} {n : ℕ} → (toList ∘ get {B} {n}) ≗ (getVec-to-getList get) ∘ toList
116 get-commut-2 getlen get v = {!!}
117
118 get-trafo-2-getlen : (getlen : ℕ → ℕ) → (get : getV-type getlen) → proj₁ (getList-to-getVec (getVec-to-getList get)) ≗ getlen
119 get-trafo-2-getlen getlen get n = begin
120   proj₁ (getList-to-getVec (getVec-to-getList get)) n
121     ≡⟨ refl ⟩
122   length (toList (get (fromList (replicate n tt))))
123     ≡⟨ vec-len-via-list (get (fromList (replicate n tt))) ⟩
124   vec-len (get (fromList (replicate n tt)))
125     ≡⟨ cong getlen (length-replicate n) ⟩
126   getlen n ∎
127
128 getVec-getlen : {getlen₁ getlen₂ : ℕ → ℕ} → (get : getV-type getlen₁) → getlen₁ ≗ getlen₂ → getV-type getlen₂
129 getVec-getlen get p {B} {n} v = subst (Vec B) (p n) (get v)
130
131 get-trafo-2-get : (getlen : ℕ → ℕ) → (get : getV-type getlen) → {B : Set} {n : ℕ} → proj₂ (getList-to-getVec (getVec-to-getList get)) {B} {n} ≗ getVec-getlen get (sym ∘ (get-trafo-2-getlen getlen get))
132 get-trafo-2-get getlen get {B} v = begin
133   proj₂ (getList-to-getVec (getVec-to-getList get)) v
134     ≡⟨ refl ⟩
135   subst (Vec B) (getList-to-getVec-length-property (getVec-to-getList get) v) (fromList (toList (get (fromList (toList v)))))
136     ≡⟨ {!!} ⟩
137   subst (Vec B) (sym (get-trafo-2-getlen getlen get (vec-len v))) (subst (Vec B) (cong getlen (length-toList v)) (get (fromList (toList v))))
138     ≡⟨ {!!} ⟩
139   subst (Vec B) (sym (get-trafo-2-getlen getlen get (vec-len v))) (get v)
140     ≡⟨ refl ⟩
141   getVec-getlen get (sym ∘ (get-trafo-2-getlen getlen get)) v ∎