give the type of different gets a name
[~helmut/bidiragda.git] / LiftGet.agda
1 module LiftGet where
2
3 open import Data.Unit using (⊤ ; tt)
4 open import Data.Nat using (ℕ ; suc)
5 open import Data.Vec using (Vec ; toList ; fromList) renaming ([] to []V ; _∷_ to _∷V_)
6 open import Data.List using (List ; [] ; _∷_ ; length ; replicate ; map)
7 open import Data.List.Properties using (length-map)
8 open import Data.Product using (∃ ; _,_ ; proj₂)
9 open import Function using (_∘_ ; flip ; const)
10 open import Relation.Binary.Core using (_≡_)
11 open import Relation.Binary.PropositionalEquality using (_≗_ ; sym ; cong ; refl)
12 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
13
14 get-type : Set₁
15 get-type = {A : Set} → List A → List A
16
17 getV-type : (ℕ → ℕ) → Set₁
18 getV-type getlen = {A : Set} {n : ℕ} → Vec A n → Vec A (getlen n)
19
20 getVec-to-getList : {getlen : ℕ → ℕ} → (getV-type getlen) → get-type
21 getVec-to-getList get = toList ∘ get ∘ fromList
22
23 getList-to-getlen : get-type → ℕ → ℕ
24 getList-to-getlen get = length ∘ get ∘ flip replicate tt
25
26 postulate
27   free-theorem-list-list : {β γ : Set} → (get : get-type) → (f : β → γ) → get ∘ map f ≗ map f ∘ get
28
29 replicate-length : {A : Set} → (l : List A) → map (const tt) l ≡ replicate (length l) tt
30 replicate-length [] = refl
31 replicate-length (_ ∷ l) = cong (_∷_ tt) (replicate-length l)
32
33 getList-length : (get : get-type) → {B : Set} → (l : List B) → length (get l) ≡ getList-to-getlen get (length l)
34 getList-length get l = begin
35   length (get l)
36     ≡⟨ sym (length-map (const tt) (get l)) ⟩
37   length (map (const tt) (get l))
38     ≡⟨ cong length (sym (free-theorem-list-list get (const tt) l)) ⟩
39   length (get (map (const tt) l))
40     ≡⟨ cong (length ∘ get) (replicate-length l) ⟩
41   length (get (replicate (length l) tt)) ∎
42
43 length-toList : {A : Set} {n : ℕ} → (v : Vec A n) → length (toList v) ≡ n
44 length-toList []V = refl
45 length-toList (x ∷V xs) = cong suc (length-toList xs) 
46
47 vec-length : {A : Set} {n m : ℕ} → n ≡ m → Vec A n → Vec A m
48 vec-length refl v = v
49
50 getList-to-getVec : get-type → ∃ λ (getlen : ℕ → ℕ) → (getV-type getlen)
51 getList-to-getVec get = getlen , get'
52   where getlen : ℕ → ℕ
53         getlen = getList-to-getlen get
54         length-prop : {C : Set} → (m : ℕ) → (v : Vec C m) → length (get (toList v)) ≡ length (get (replicate m tt))
55         length-prop m v = begin
56             length (get (toList v))
57               ≡⟨ getList-length get (toList v) ⟩
58             length (get (replicate (length (toList v)) tt))
59               ≡⟨ cong (length ∘ get ∘ flip replicate tt) (length-toList v) ⟩
60             length (get (replicate m tt)) ∎
61         get' : {C : Set} {m : ℕ} → Vec C m → Vec C (getlen m)
62         get' {_} {m} v = vec-length (length-prop m v) (fromList (get (toList v)))
63
64 get-trafo-1 : (get : get-type) → {B : Set} → getVec-to-getList (proj₂ (getList-to-getVec get)) {B} ≗ get {B}
65 get-trafo-1 get l = begin
66   getVec-to-getList (proj₂ (getList-to-getVec get)) l
67     ≡⟨ {!!} ⟩
68   get l ∎