attempt isomorphism between get on List and on Vec
[~helmut/bidiragda.git] / LiftGet.agda
1 module LiftGet where
2
3 open import Data.Unit using (⊤ ; tt)
4 open import Data.Nat using (ℕ ; suc)
5 open import Data.Vec using (Vec ; toList ; fromList) renaming ([] to []V ; _∷_ to _∷V_)
6 open import Data.List using (List ; [] ; _∷_ ; length ; replicate ; map)
7 open import Data.List.Properties using (length-map)
8 open import Data.Product using (∃ ; _,_ ; proj₂)
9 open import Function using (_∘_ ; flip ; const)
10 open import Relation.Binary.Core using (_≡_)
11 open import Relation.Binary.PropositionalEquality using (_≗_ ; sym ; cong ; refl)
12 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
13
14 getVec-to-getList : {getlen : ℕ → ℕ} → ({A : Set} {n : ℕ} → Vec A n → Vec A (getlen n)) → ({B : Set} → List B → List B)
15 getVec-to-getList get = toList ∘ get ∘ fromList
16
17 getList-to-getlen : ({A : Set} → List A → List A) → ℕ → ℕ
18 getList-to-getlen get = length ∘ get ∘ flip replicate tt
19
20 postulate
21   free-theorem-list-list : {β γ : Set} → (get : {α : Set} → List α → List α) → (f : β → γ) → get ∘ map f ≗ map f ∘ get
22
23 replicate-length : {A : Set} → (l : List A) → map (const tt) l ≡ replicate (length l) tt
24 replicate-length [] = refl
25 replicate-length (_ ∷ l) = cong (_∷_ tt) (replicate-length l)
26
27 getList-length : (get : {A : Set} → List A → List A) → {B : Set} → (l : List B) → length (get l) ≡ getList-to-getlen get (length l)
28 getList-length get l = begin
29   length (get l)
30     ≡⟨ sym (length-map (const tt) (get l)) ⟩
31   length (map (const tt) (get l))
32     ≡⟨ cong length (sym (free-theorem-list-list get (const tt) l)) ⟩
33   length (get (map (const tt) l))
34     ≡⟨ cong (length ∘ get) (replicate-length l) ⟩
35   length (get (replicate (length l) tt)) ∎
36
37 length-toList : {A : Set} {n : ℕ} → (v : Vec A n) → length (toList v) ≡ n
38 length-toList []V = refl
39 length-toList (x ∷V xs) = cong suc (length-toList xs) 
40
41 vec-length : {A : Set} {n m : ℕ} → n ≡ m → Vec A n → Vec A m
42 vec-length refl v = v
43
44 getList-to-getVec : ({A : Set} → List A → List A) → ∃ λ (getlen : ℕ → ℕ) → {B : Set} {n : ℕ} → Vec B n → Vec B (getlen n)
45 getList-to-getVec get = getlen , get'
46   where getlen : ℕ → ℕ
47         getlen = getList-to-getlen get
48         length-prop : {C : Set} → (m : ℕ) → (v : Vec C m) → length (get (toList v)) ≡ length (get (replicate m tt))
49         length-prop m v = begin
50             length (get (toList v))
51               ≡⟨ getList-length get (toList v) ⟩
52             length (get (replicate (length (toList v)) tt))
53               ≡⟨ cong (length ∘ get ∘ flip replicate tt) (length-toList v) ⟩
54             length (get (replicate m tt)) ∎
55         get' : {C : Set} {m : ℕ} → Vec C m → Vec C (getlen m)
56         get' {_} {m} v = vec-length (length-prop m v) (fromList (get (toList v)))
57
58 get-trafo-1 : (get : {A : Set} → List A → List A) → {B : Set} → getVec-to-getList (proj₂ (getList-to-getVec get)) {B} ≗ get {B}
59 get-trafo-1 get l = begin
60   getVec-to-getList (proj₂ (getList-to-getVec get)) l
61     ≡⟨ {!!} ⟩
62   get l ∎