3a487577dfbe7056356ffb100b0fd13c9f52c96e
[~helmut/bidiragda.git] / Precond.agda
1 open import Relation.Binary.Core using (Decidable ; _≡_)
2
3 module Precond (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
4
5 open import Data.Nat using (ℕ)
6 open import Data.Fin using (Fin ; zero ; suc)
7 open import Data.Fin.Props using (_≟_)
8 open import Data.List using (List ; [] ; _∷_)
9 open import Level using () renaming (zero to ℓ₀)
10 import Category.Monad
11 import Category.Functor
12 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
13 open Category.Monad.RawMonad {Level.zero} Data.Maybe.monad using (_>>=_)
14 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.functor using (_<$>_)
15 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList ; tabulate)
16 open import Data.Vec.Properties using (map-cong ; map-∘ ; tabulate-∘)
17 import Data.List.All
18 open import Data.List.Any using (here ; there)
19 open Data.List.Any.Membership-≡ using (_∉_)
20 open import Data.Maybe using (just)
21 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
22 open import Function using (flip ; _∘_ ; id)
23 open import Relation.Binary using (Setoid)
24 open import Relation.Binary.PropositionalEquality using (refl ; cong ; inspect ; [_] ; sym ; decSetoid)
25 open Relation.Binary.PropositionalEquality.≡-Reasoning using (begin_ ; _≡⟨_⟩_ ; _∎)
26 open import Relation.Nullary using (yes ; no)
27
28 open import Generic using (mapMV ; sequenceV)
29 open import FinMap using (FinMapMaybe ; lookupM ; union ; fromFunc ; empty ; insert ; lemma-lookupM-empty ; delete-many ; lemma-tabulate-∘ ; delete ; lemma-lookupM-delete ; lemma-lookupM-fromFunc ; reshape ; lemma-reshape-id)
30 import CheckInsert
31 open CheckInsert (decSetoid deq) using (checkInsert ; lemma-checkInsert-new ; lemma-lookupM-checkInsert-other)
32 import BFF
33 import Bidir
34 open Bidir (decSetoid deq) using (_in-domain-of_ ; lemma-assoc-domain ; lemma-just-sequence)
35 import GetTypes
36 open GetTypes.PartialVecVec using (Get ; module Get)
37 open BFF.PartialVecBFF (decSetoid deq) using (assoc ; enumerate ; denumerate ; bff ; enumeratel)
38
39 lemma-maybe-just : {A : Set} → (a : A) → (ma : Maybe A) → maybe′ Maybe.just (just a) ma ≡ Maybe.just (maybe′ id a ma)
40 lemma-maybe-just a (just x) = refl
41 lemma-maybe-just a nothing = refl
42
43 lemma-union-delete-fromFunc : {m n : ℕ} {A : Set} {is : Vec (Fin n) m} {h : FinMapMaybe n A} {g : Fin n → A} → (toList is) in-domain-of h → ∃ λ v → union h (delete-many is (fromFunc g)) ≡ fromFunc v
44 lemma-union-delete-fromFunc {is = []} {h = h} {g = g} p = _ , (lemma-tabulate-∘ (λ f → begin
45       maybe′ just (lookupM f (fromFunc g)) (lookupM f h)
46         ≡⟨ cong (flip (maybe′ just) (lookupM f h)) (lemma-lookupM-fromFunc g f) ⟩
47       maybe′ just (just (g f)) (lookupM f h)
48         ≡⟨ lemma-maybe-just (g f) (lookupM f h) ⟩
49       just (maybe′ id (g f) (lookupM f h)) ∎))
50 lemma-union-delete-fromFunc {n = n} {is = i ∷ is} {h = h} {g = g} (Data.List.All._∷_ (x , px) ps) = _ , (begin
51   union h (delete i (delete-many is (fromFunc g)))
52     ≡⟨ lemma-tabulate-∘ inner ⟩
53   union h (delete-many is (fromFunc g))
54     ≡⟨ proj₂ (lemma-union-delete-fromFunc ps) ⟩
55   _ ∎)
56   where inner : (f : Fin n) → maybe′ just (lookupM f (delete i (delete-many is (fromFunc g)))) (lookup f h) ≡ maybe′ just (lookupM f (delete-many is (fromFunc g))) (lookup f h)
57         inner f with f ≟ i
58         inner .i | yes refl = begin
59           maybe′ just (lookupM i (delete i (delete-many is (fromFunc g)))) (lookup i h)
60             ≡⟨ cong (maybe′ just _) px ⟩
61           just x
62             ≡⟨ cong (maybe′ just _) (sym px) ⟩
63           maybe′ just (lookupM i (delete-many is (fromFunc g))) (lookup i h) ∎
64         inner f | no f≢i = cong (flip (maybe′ just) (lookup f h)) (lemma-lookupM-delete (delete-many is (fromFunc g)) f≢i)
65
66 assoc-enough : (G : Get) → {i : Get.|I| G} → (s : Vec Carrier (Get.|gl₁| G i)) → (v : Vec Carrier (Get.|gl₂| G i)) → ∃ (λ h → assoc (Get.get G (enumerate s)) v ≡ just h) → ∃ λ u → bff G i s v ≡ just u
67 assoc-enough G {i} s v (h , p) = _ , (begin
68   bff G i s v
69     ≡⟨ cong (flip _>>=_ (flip mapMV t ∘ flip lookupM) ∘ _<$>_ (flip union (reshape g′ (Get.|gl₁| G i)))) p ⟩
70   mapMV (flip lookupM (union h (reshape g′ (Get.|gl₁| G i)))) t
71     ≡⟨ refl ⟩
72   sequenceV (map (flip lookupM (union h (reshape g′ (Get.|gl₁| G i)))) t)
73     ≡⟨ cong (sequenceV ∘ flip map t ∘ flip lookupM ∘ union h) (lemma-reshape-id g′) ⟩
74   sequenceV (map (flip lookupM (union h g′)) t)
75     ≡⟨ cong (sequenceV ∘ flip map t ∘ flip lookupM) (proj₂ wp) ⟩
76   sequenceV (map (flip lookupM (fromFunc (proj₁ wp))) t)
77     ≡⟨ cong sequenceV (map-cong (lemma-lookupM-fromFunc (proj₁ wp)) t) ⟩
78   sequenceV (map (Maybe.just ∘ proj₁ wp) t)
79     ≡⟨ cong sequenceV (map-∘ just (proj₁ wp) t) ⟩
80   sequenceV (map Maybe.just (map (proj₁ wp) t))
81     ≡⟨ lemma-just-sequence (map (proj₁ wp) t) ⟩
82   just (map (proj₁ wp) t) ∎)
83   where open Get G
84         s′ = enumerate s
85         g  = fromFunc (denumerate s)
86         g′ = delete-many (get s′) g
87         t  = enumeratel (Get.|gl₁| G i)
88         wp = lemma-union-delete-fromFunc (lemma-assoc-domain (get t) v h p)
89
90 data All-different {A : Set} : List A → Set where
91   different-[] : All-different []
92   different-∷  : {x : A} {xs : List A} → x ∉ xs → All-different xs → All-different (x ∷ xs)
93
94 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → (h : FinMapMaybe n Carrier) → assoc is xs ≡ just h → (i ∉ toList is) → lookupM i h ≡ nothing
95 lemma-∉-lookupM-assoc i []         []         .empty refl i∉is = lemma-lookupM-empty i
96 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is with assoc is' xs' | inspect (assoc is') xs'
97 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h () i∉is | nothing | [ ph' ]
98 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') h ph i∉is | just h' | [ ph' ] = begin
99   lookupM i h
100     ≡⟨ sym (lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' h ph) ⟩
101   lookupM i h'
102     ≡⟨ lemma-∉-lookupM-assoc i is' xs' h' ph' (i∉is ∘ there) ⟩
103   nothing ∎
104
105 different-assoc : {m n : ℕ} → (u : Vec (Fin n) m) → (v : Vec Carrier m) → All-different (toList u) → ∃ λ h → assoc u v ≡ just h
106 different-assoc []       []       p = empty , refl
107 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) with different-assoc us vs diff-us
108 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) | h , p' = insert u v h , (begin
109   assoc (u ∷ us) (v ∷ vs)
110     ≡⟨ refl ⟩
111   (assoc us vs >>= checkInsert u v)
112     ≡⟨ cong (flip _>>=_ (checkInsert u v)) p' ⟩
113   checkInsert u v h
114     ≡⟨ lemma-checkInsert-new u v h (lemma-∉-lookupM-assoc u us vs h p' u∉us) ⟩
115   just (insert u v h) ∎)