individually open ≡-Reasoning
[~helmut/bidiragda.git] / Precond.agda
1 open import Relation.Binary.Core using (Decidable)
2 open import Relation.Binary.PropositionalEquality using (_≡_)
3
4 module Precond (Carrier : Set) (deq : Decidable {A = Carrier} _≡_) where
5
6 open import Data.Nat using (ℕ)
7 open import Data.Fin using (Fin ; zero ; suc)
8 open import Data.Fin.Properties using (_≟_)
9 open import Data.List using (List ; [] ; _∷_)
10 open import Level using () renaming (zero to ℓ₀)
11 import Category.Monad
12 import Category.Functor
13 open import Data.Maybe using (Maybe ; nothing ; just ; maybe′)
14 import Data.Maybe.Categorical
15 open Category.Monad.RawMonad {Level.zero} Data.Maybe.Categorical.monad using (_>>=_)
16 open Category.Functor.RawFunctor {Level.zero} Data.Maybe.Categorical.functor using (_<$>_)
17 open import Data.Vec using (Vec ; [] ; _∷_ ; map ; lookup ; toList)
18 open import Data.Vec.Properties using (map-cong ; map-∘ ; tabulate-∘ ; lookup-replicate ; tabulate-cong ; lookup∘tabulate ; lookup∘update′)
19 import Data.List.All
20 open import Data.List.Any using (here ; there)
21 open import Data.List.Membership.Setoid using (_∉_)
22 open import Data.Maybe using (just)
23 open import Data.Product using (∃ ; _,_ ; proj₁ ; proj₂)
24 open import Function using (flip ; _∘_ ; id)
25 open import Relation.Binary using (Setoid)
26 open import Relation.Binary.PropositionalEquality as P using (inspect ; [_] ; module ≡-Reasoning)
27 open import Relation.Nullary using (yes ; no)
28
29 open import Structures using (IsFunctor ; module Shaped ; Shaped)
30 open import FinMap using (FinMapMaybe ; lookupM ; union ; fromFunc ; empty ; insert ; delete-many ; delete ; reshape ; lemma-reshape-id)
31 import CheckInsert
32 open CheckInsert (P.decSetoid deq) using (checkInsert ; lemma-checkInsert-new ; lemma-lookupM-checkInsert-other)
33 import BFF
34 import Bidir
35 open Bidir (P.decSetoid deq) using (_in-domain-of_ ; lemma-assoc-domain)
36 import GetTypes
37 open GetTypes.PartialShapeShape using (Get ; module Get)
38 open BFF.PartialShapeBFF (P.decSetoid deq) using (assoc ; enumerate ; denumerate ; bff)
39
40 lemma-maybe-just : {A : Set} → (a : A) → (ma : Maybe A) → maybe′ Maybe.just (just a) ma ≡ Maybe.just (maybe′ id a ma)
41 lemma-maybe-just a (just x) = P.refl
42 lemma-maybe-just a nothing  = P.refl
43
44 lemma-union-delete-fromFunc : {m n : ℕ} {A : Set} {is : Vec (Fin n) m} (h : FinMapMaybe n A) {g : Fin n → A} → is in-domain-of h → ∃ λ v → union h (delete-many is (fromFunc g)) ≡ fromFunc v
45 lemma-union-delete-fromFunc {is = []} h {g = g} p = _ , (tabulate-cong (λ f → begin
46       maybe′ just (lookupM f (fromFunc g)) (lookupM f h)
47         ≡⟨ P.cong (flip (maybe′ just) (lookupM f h)) (lookup∘tabulate (just ∘ g) f) ⟩
48       maybe′ just (just (g f)) (lookupM f h)
49         ≡⟨ lemma-maybe-just (g f) (lookupM f h) ⟩
50       just (maybe′ id (g f) (lookupM f h)) ∎))
51   where open ≡-Reasoning
52 lemma-union-delete-fromFunc {n = n} {is = i ∷ is} h {g = g} (Data.List.All._∷_ (x , px) ps) = _ , (begin
53   union h (delete i (delete-many is (fromFunc g)))
54     ≡⟨ tabulate-cong inner ⟩
55   union h (delete-many is (fromFunc g))
56     ≡⟨ proj₂ (lemma-union-delete-fromFunc h ps) ⟩
57   _ ∎)
58   where open ≡-Reasoning
59         inner : (f : Fin n) → maybe′ just (lookupM f (delete i (delete-many is (fromFunc g)))) (lookup h f) ≡ maybe′ just (lookupM f (delete-many is (fromFunc g))) (lookup h f)
60         inner f with f ≟ i
61         inner .i | yes P.refl = begin
62           maybe′ just (lookupM i (delete i (delete-many is (fromFunc g)))) (lookup h i)
63             ≡⟨ P.cong (maybe′ just _) px ⟩
64           just x
65             ≡⟨ P.cong (maybe′ just _) (P.sym px) ⟩
66           maybe′ just (lookupM i (delete-many is (fromFunc g))) (lookup h i) ∎
67         inner f | no f≢i = P.cong (flip (maybe′ just) (lookup h f)) (lookup∘update′ f≢i (delete-many is (fromFunc g)) nothing)
68
69 module _ (G : Get) where
70   open Get G
71   open Shaped ViewShapeT using () renaming (content to contentV)
72
73   assoc-enough : {i : I} → (j : I) → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ j)) → ∃ (λ h → assoc (contentV (get (enumerate SourceShapeT (gl₁ j)))) (contentV v) ≡ just h) → ∃ λ u → bff G j s v ≡ just u
74   assoc-enough {i} j s v (h , p) = _ , P.cong (_<$>_ ((λ f → fmapS f t) ∘ flip lookupM) ∘ _<$>_ (flip union (reshape g′ (Shaped.arity SourceShapeT (gl₁ j))))) p
75     where g′ = delete-many (contentV (get (enumerate SourceShapeT (gl₁ i)))) (fromFunc (denumerate SourceShapeT s))
76           t  = enumerate SourceShapeT (gl₁ j)
77
78 module _ (G : Get) where
79   open Get G
80   open Shaped ViewShapeT using () renaming (content to contentV)
81
82   assoc-enough′ : {i : I} → (s : SourceContainer Carrier (gl₁ i)) → (v : ViewContainer Carrier (gl₂ i)) → ∃ (λ h → assoc (contentV (get (enumerate SourceShapeT (gl₁ i)))) (contentV v) ≡ just h) → ∃ λ u → bff G i s v ≡ just (fmapS just u)
83   assoc-enough′ {i} s v (h , p) = _ , (begin
84     bff G i s v
85       ≡⟨ proj₂ (assoc-enough G i s v (h , p)) ⟩
86     just (fmapS (flip lookupM (union h (reshape g′ (Shaped.arity SourceShapeT (gl₁ i))))) t)
87       ≡⟨ P.cong just (begin _
88           ≡⟨ P.cong ((λ f → fmapS f t) ∘ flip lookupM ∘ union h) (lemma-reshape-id g′) ⟩
89         fmapS (flip lookupM (union h g′)) t
90           ≡⟨ P.cong ((λ f → fmapS f t) ∘ flip lookupM) (proj₂ wp) ⟩
91         fmapS (flip lookupM (fromFunc (proj₁ wp))) t
92           ≡⟨ IsFunctor.cong (Shaped.isFunctor SourceShapeT (gl₁ i)) (lookup∘tabulate (just ∘ proj₁ wp)) t ⟩
93         fmapS (Maybe.just ∘ proj₁ wp) t
94           ≡⟨ IsFunctor.composition (Shaped.isFunctor SourceShapeT (gl₁ i)) just (proj₁ wp) t ⟩
95         fmapS Maybe.just (fmapS (proj₁ wp) t) ∎) ⟩ _ ∎)
96     where open ≡-Reasoning
97           s′ = enumerate SourceShapeT (gl₁ i)
98           g  = fromFunc (denumerate SourceShapeT s)
99           g′ = delete-many (contentV (get s′)) g
100           t  = enumerate SourceShapeT (gl₁ i)
101           wp = lemma-union-delete-fromFunc h (lemma-assoc-domain (contentV (get t)) (contentV v) p)
102
103 data All-different {A : Set} : List A → Set where
104   different-[] : All-different []
105   different-∷  : {x : A} {xs : List A} → _∉_ (P.setoid A) x xs → All-different xs → All-different (x ∷ xs)
106
107 lemma-∉-lookupM-assoc : {m n : ℕ} → (i : Fin n) → (is : Vec (Fin n) m) → (xs : Vec Carrier m) → {h : FinMapMaybe n Carrier} → assoc is xs ≡ just h → _∉_ (P.setoid (Fin n)) i (toList is) → lookupM i h ≡ nothing
108 lemma-∉-lookupM-assoc i []         []         P.refl i∉is = lookup-replicate i nothing
109 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs')     ph i∉is with assoc is' xs' | inspect (assoc is') xs'
110 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs')     () i∉is | nothing | [ ph' ]
111 lemma-∉-lookupM-assoc i (i' ∷ is') (x' ∷ xs') {h} ph i∉is | just h' | [ ph' ] = begin
112     lookupM i h
113       ≡⟨ lemma-lookupM-checkInsert-other i i' (i∉is ∘ here) x' h' ph ⟩
114     lookupM i h'
115       ≡⟨ lemma-∉-lookupM-assoc i is' xs' ph' (i∉is ∘ there) ⟩
116     nothing ∎
117   where open ≡-Reasoning
118
119 different-assoc : {m n : ℕ} → (u : Vec (Fin n) m) → (v : Vec Carrier m) → All-different (toList u) → ∃ λ h → assoc u v ≡ just h
120 different-assoc []       []       p = empty , P.refl
121 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) with different-assoc us vs diff-us
122 different-assoc (u ∷ us) (v ∷ vs) (different-∷ u∉us diff-us) | h , p' = insert u v h , (begin
123     assoc (u ∷ us) (v ∷ vs)
124       ≡⟨ P.refl ⟩
125     (assoc us vs >>= checkInsert u v)
126       ≡⟨ P.cong (flip _>>=_ (checkInsert u v)) p' ⟩
127     checkInsert u v h
128       ≡⟨ lemma-checkInsert-new u v h (lemma-∉-lookupM-assoc u us vs p' u∉us) ⟩
129     just (insert u v h) ∎)
130   where open ≡-Reasoning